【NOI2008】 设计路线

设计路线
【问题描述】
Z 国坐落于遥远而又神奇的东方半岛上,在小 Z 的统治时代公路成为这里主
要的交通手段。Z 国共有 n 座城市,一些城市之间由双向的公路所连接。非常神
奇的是 Z 国的每个城市所处的经度都不相同,并且最多只和一个位于它东边的
城市直接通过公路相连。 国的首都是 Z 国政治经济文化旅游的中心,每天都有
Z
成千上万的人从 Z 国的其他城市涌向首都。
为了使 Z 国的交通更加便利顺畅, Z 决定在 Z 国的公路系统中确定若干条
小
规划路线,将其中的公路全部改建为铁路。
我们定义每条规划路线为一个长度大于 1 的城市序列,每个城市在该序列中
最多出现一次,序列中相邻的城市之间由公路直接相连(待改建为铁路)。并且,
每个城市最多只能出现在一条规划路线中,
也就是说,
任意两条规划路线不能有
公共部分。
当然在一般情况下是不可能将所有的公路修建为铁路的,因此从有些城市出
发去往首都依然需要通过乘坐长途汽车,
而长途汽车只往返于公路连接的相邻的
城市之间,
因此从某个城市出发可能需要不断地换乘长途汽车和火车才能到达首
都。
我们定义一个城市的“不便利值”为从它出发到首都需要乘坐的长途汽车的
次数,而 Z 国的交通系统的“不便利值”为所有城市的不便利值的最大值,很明
显首都的“不便利值”为 0。小 Z 想知道如何确定规划路线修建铁路使得 Z 国的
交通系统的
“不便利值”
最小,
以及有多少种不同的规划路线的选择方案使得
“不
便利值”达到最小。当然方案总数可能非常大,小 Z 只关心这个天文数字 mod Q
后的值。
注意:规划路线 1-2-3 和规划路线 3-2-1 是等价的,即将一条规划路线翻转
依然认为是等价的。
两个方案不同当且仅当其中一个方案中存在一条规划路线不
属于另一个方案。
【输入格式】
输入文件 design.in 第一行包含三个正整数 N、M、Q,其中 N 表示城市个数,
M 表示公路总数,N 个城市从 1~N 编号,其中编号为 1 的是首都。Q 表示上文
提到的设计路线的方法总数的模数。
接下来 M 行,
每行两个不同的正数 ai、 i (1≤
b
ai , bi ≤ N)表示有一条公路连接城市 ai 和城市 bi。 输入数据保证一条公路只出现
一次。
【输出格式】
输出文件 design.out 应包含两行。第一行为一个整数,表示最小的“不便利
值” 第二行为一个整数,表示使“不便利值”达到最小时不同的设计路线的方
。
法总数 mod Q 的值。
如果某个城市无法到达首都,则输出两行-1。
【输入样例】
5 4 100
12
45
13
41
【输出样例】
1
10
【样例说明】
以下样例中是 10 种设计路线的方法:
(1)
4-5
(2)
1-4-5
(3)
4-5, 1-2
(4)
4-5, 1-3
(5)
4-5, 2-1-3
(6)
2-1-4-5
(7)
3-1-4-5
(8)
1-4
(9)
2-1-4
(10)
3-1-4
【数据规模和约定】
对于 20%的数据,满足 N,M ≤ 10。
对于 50%的数据,满足 N,M ≤ 200。
对于 60%的数据,满足 N,M ≤ 5000。
对于 100%的数据,满足 1 ≤ N,M ≤ 100000,1 ≤ Q ≤ 120000000。
【评分方式】
每个测试点单独评分。对于每个测试点,第一行错则该测试点得零分,否则
若第二行错则该测试点得到 40%的分数。如果两问都答对,该测试点得到 100%
的分数。

 

题解

 

(*
    *Problem:    NOI2008 设计路线
    *Author :    Chen Yang
    *Time   :    2012.5.18
    *State  :    AC
    *Memo    :    树形DP
*)
program design;
const maxn=100200;
type
  ty1=^ty2;
  ty2=record
    x:longint;
    next:ty1;
  end;
var
  n,m,q,i,x,y:longint;
  first:array[0..maxn] of ty1;
  f:array[0..maxn,0..20,0..3] of int64;
//====================
procedure insert(x,y:longint);
var
  p:ty1;
begin
  new(p);
  p^.x:=y; p^.next:=first[x]; first[x]:=p;
end;
//====================
procedure modx(var x:int64);
begin
  if (x mod q=0)and(x>0) then x:=q else x:=x mod q;
end;
//====================
procedure find(x,fa:longint);
var
  f1,f2:int64;
  p:ty1;
begin
  f[x,i,0]:=1;
  p:=first[x];
  while p<>nil do
  begin
    if p^.x<>fa then
    begin
      find(p^.x,x);
      f1:=f[p^.x,i,0]+f[p^.x,i,1];                    modx(f1);
      f2:=f[p^.x,i-1,0]+f[p^.x,i-1,1]+f[p^.x,i-1,2];  modx(f2);
      f[x,i,2]:=f[x,i,2]*f2+f[x,i,1]*f1;              modx(f[x,i,2]);
      f[x,i,1]:=f[x,i,1]*f2+f[x,i,0]*f1;              modx(f[x,i,1]);
      f[x,i,0]:=f[x,i,0]*f2;                          modx(f[x,i,0]);
    end;
    p:=p^.next;
  end;
end;
//====================
begin
  assign(input,'design.in'); reset(input);
  assign(output,'design.out'); rewrite(output);
  read(n,m,q);
  if m<>n-1 then
  begin
    writeln(-1); writeln(-1);
    close(input); close(output);
    halt;
  end;
  for i:=1 to m do
  begin
    read(x,y);
    insert(x,y); insert(y,x);
  end;
  i:=0;
  while true do
  begin
    find(1,0);
    if f[1,i,0]+f[1,i,1]+f[1,i,2]>0 then
    begin
      writeln(i);
      writeln((f[1,i,0]+f[1,i,1]+f[1,i,2]) mod q);
      break;
    end;
    inc(i);
  end;
  close(input); close(output);
end.

 

(*
    *Problem:    NOI2008 设计路线
    *Author :    Chen Yang
    *Time   :    2012.5.18
    *State  :    50分
    *Memo    :    朴素树形DP
*)
program design;
const maxn=100100;
type
  ty1=^ty2;
  ty2=record
    x:longint;
    next:ty1;
  end;
  ty3=array[0..maxn] of ty1;
var
  n,m,q:longint;
  first,son:ty3;
  get:array[0..maxn] of boolean;
  f,g:array[0..maxn,0..20] of int64;
  v1,v2:array[0..maxn,0..20] of boolean;
  sson:array[0..maxn] of longint;
//==================
procedure insert(x,y:longint; var a:ty3);      inline;
var
  p:ty1;
begin
  new(p);
  p^.x:=y; p^.next:=a[x]; a[x]:=p;
end;
//==================
procedure built(x:longint);
var
  p:ty1;
begin
  get[x]:=true;
  p:=first[x];
  while p<>nil do
  begin
    if not get[p^.x] then
    begin
      insert(x,p^.x,son);
      inc(sson[x]); built(p^.x);
    end;
    p:=p^.next;
  end;
end;
//==================
procedure get_inf;
var
  i,x,y:longint;
begin
  read(n,m,q);
  for i:=1 to m do
  begin
    read(x,y);
    insert(x,y,first); insert(y,x,first);
  end;
  built(1);
  for i:=1 to n do
  if not get[i] then
  begin
    writeln(-1); writeln(-1);
    close(input); close(output);
    halt;
  end;
end;
//==================
procedure find(i,b:longint); forward;
//==================
procedure dp1(x,b:longint);
var
  t,s:int64;
  v:boolean;
  i,j,k:ty1;
begin
  t:=0; i:=son[x];
  while i<>nil do
  begin
    find(i^.x,b); j:=i^.next;
    while j<>nil do
    begin
      if j^.x<>i^.x then
      begin
        find(j^.x,b); k:=son[x]; s:=1; v:=true;
        while k<>nil do
        begin
          if (k^.x<>i^.x)and(k^.x<>j^.x) then
          begin
            find(k^.x,b-1);
            s:=(s*(f[k^.x,b-1]+g[k^.x,b-1])) mod q;
            if (not v1[k^.x,b-1]) and (not v2[k^.x,b-1]) then v:=false;
          end;
          k:=k^.next;
        end;
        t:=(t+(g[i^.x,b]*g[j^.x,b]*s) mod q) mod q;
        if v and v2[i^.x,b] and v2[j^.x,b] then v1[x,b]:=true;
      end;
      j:=j^.next;
    end;
    i:=i^.next;
  end;
  f[x,b]:=t;
end;
//==================
procedure dp2(x,b:longint);
var
  t,s,p:int64;
  v,vx:boolean;
  i,j:ty1;
begin
  t:=0; i:=son[x]; p:=1; v:=true;
  while i<>nil do
  begin
    find(i^.x,b); j:=son[x]; s:=1; vx:=true;
    while j<>nil do
    begin
      if j^.x<>i^.x then
      begin
        find(j^.x,b-1);
        s:=(s*(f[j^.x,b-1]+g[j^.x,b-1])) mod q;
        if not v1[j^.x,b-1] and not v2[j^.x,b-1] then vx:=false;
      end;
      j:=j^.next;
    end;
    t:=(t+g[i^.x,b]*s) mod q;
    if vx and v2[i^.x,b] then v2[x,b]:=true;
    find(i^.x,b-1);
    p:=(p*(f[i^.x,b-1]+g[i^.x,b-1])) mod q;
    if not v1[i^.x,b-1] and not v2[i^.x,b-1] then v:=false;
    i:=i^.next;
  end;
  g[x,b]:=(t+p) mod q;
  v2[x,b]:=v2[x,b] or v;
end;
//==================
procedure dp3(x,b:longint);    inline;
var
  i,j:ty1;
begin
  i:=son[x]; j:=i^.next;
  find(i^.x,b); find(j^.x,b);
  f[x,b]:=(g[i^.x,b]*g[j^.x,b]) mod q;
  if (f[x,b]>0)or(v2[i^.x,b] and v2[j^.x,b]) then v1[x,b]:=true;
end;
//==================
procedure dp4(x,b:longint);    inline;
begin
  find(son[x]^.x,b);
  g[x,b]:=g[son[x]^.x,b];
  v2[x,b]:=v2[son[x]^.x,b];
end;
//==================
procedure find(i,b:longint);
begin
  if f[i,b]>-1 then exit;
  if b>0 then
  begin
    if sson[i]<2 then f[i,b]:=0 else dp1(i,b);
    if sson[i]=0 then begin g[i,b]:=1; v2[i,b]:=true; end else dp2(i,b);
  end else
  begin
    if sson[i]<>2 then f[i,b]:=0 else dp3(i,b);
    if sson[i]=0 then begin g[i,b]:=1; v2[i,b]:=true; end else
    if sson[i]=1 then dp4(i,b) else g[i,b]:=0;
  end;
end;
//==================
procedure main;
var
  i:longint;
begin
  fillchar(f,sizeof(f),255);
  fillchar(g,sizeof(g),255);
  i:=0;
  while true do
  begin
    find(1,i);
    if v1[1,i] or v2[1,i] then
    begin
      writeln(i); writeln((f[1,i]+g[1,i]) mod q);
      break;
    end;
    inc(i);
  end;
  //for i:=1 to n do
  //writeln(f[i,0],' ',f[i,1],' ',g[i,0],' ',g[i,1]);
end;
//==================
begin
  assign(input,'design.in'); reset(input);
  assign(output,'design.out'); rewrite(output);
  get_inf;
  main;
  close(input); close(output);
end.

 

(*
    *Problem:    NOI2008 设计路线
    *Author :    Chen Yang
    *Time   :    2012.5.18
    *State  :    AC
    *Memo    :    优化树形DP
*)
program design;
const maxn=100100;
type
  ty1=^ty2;
  ty2=record
    x:longint;
    next:ty1;
  end;
var
  n,m,q,tot:longint;
  first:array[0..maxn] of ty1;
  get,vp,vs,vc:array[0..maxn] of boolean;
  f,g:array[0..maxn,0..10] of int64;
  pre,suf,c:array[0..maxn] of int64;
  v1,v2:array[0..maxn,0..10] of boolean;
  sson,fr,en,son:array[0..maxn] of longint;
//==================
procedure insert(x,y:longint);      inline;
var
  p:ty1;
begin
  new(p);
  p^.x:=y; p^.next:=first[x]; first[x]:=p;
end;
//==================
procedure built(x:longint);
var
  p:ty1;
begin
  get[x]:=true; fr[x]:=tot+1;
  p:=first[x];
  while p<>nil do
  begin
    if not get[p^.x] then
    begin
      inc(tot); son[tot]:=p^.x;
      inc(sson[x]);
    end;
    p:=p^.next;
  end;
  en[x]:=tot; p:=first[x];
  while p<>nil do
  begin
    if not get[p^.x] then built(p^.x);
    p:=p^.next;
  end;
end;
//==================
procedure get_inf;
var
  i,x,y:longint;
begin
  read(n,m,q);
  for i:=1 to m do
  begin
    read(x,y);
    insert(x,y); insert(y,x);
  end;
  built(1);
  for i:=1 to n do
  if not get[i] then
  begin
    writeln(-1); writeln(-1);
    close(input); close(output);
    halt;
  end;
end;
//==================
procedure find(i,b:longint); forward;
//==================
procedure prepare(x,b:longint);
var
  i:longint;
begin
  for i:=fr[x] to en[x] do
  begin
    find(son[i],b); find(son[i],b-1);
  end;
  pre[fr[x]-1]:=1; vp[fr[x]-1]:=true;
  for i:=fr[x] to en[x] do
  begin
    pre[i]:=(pre[i-1]*(f[son[i],b-1]+g[son[i],b-1])) mod q;
    if not v1[son[i],b-1] and not v2[son[i],b-1] then vp[i]:=false
    else vp[i]:=vp[i-1];
  end;
  suf[en[x]+1]:=1; vs[en[x]+1]:=true;
  for i:=en[x] downto fr[x] do
  begin
    suf[i]:=(suf[i+1]*(f[son[i],b-1]+g[son[i],b-1])) mod q;
    if not v1[son[i],b-1] and not v2[son[i],b-1] then vs[i]:=false
    else vs[i]:=vs[i+1];
  end;
end;
//==================
procedure dp1(x,b:longint);
var
  t,s:int64;
  v:boolean;
  i,j,k:longint;
begin
  t:=0;
  c[en[x]]:=g[son[en[x]],b]; vc[en[x]]:=v2[son[en[x]],b];
  for i:=en[x]-1 downto fr[x] do
  begin
    c[i]:=(c[i+1]*(f[son[i],b-1]+g[son[i],b-1])) mod q+((g[son[i],b]*suf[i+1]) mod q) mod q;
    if (not vc[i+1] or (not v1[son[i],b-1])and(not v2[son[i],b-1])) and
       (not v2[son[i],b] or not vs[i+1]) then vc[i]:=false else vc[i]:=vc[i+1];
  end;
  for i:=fr[x] to en[x]-1 do
  begin
    t:=(t+(pre[i-1]*g[son[i],b] mod q)*c[i+1]) mod q;
    if vp[i-1] and v2[son[i],b] and vc[i+1] then v1[x,b]:=true;
  end;
  f[x,b]:=t;
end;
//==================
procedure dp2(x,b:longint);
var
  v:boolean;
  t,p:int64;
  i:longint;
begin
  t:=0; p:=1; v2[x,b]:=false; v:=true;
  for i:=fr[x] to en[x] do
  begin
    t:=(t+((g[son[i],b]*pre[i-1]) mod q)*suf[i+1]) mod q;
    if v2[son[i],b] and vp[i-1] and vs[i+1] then v2[x,b]:=true;
    p:=(p*(f[son[i],b-1]+g[son[i],b-1])) mod q;
    if not v1[son[i],b-1] and not v2[son[i],b-1] then v:=false;
  end;
  g[x,b]:=(t+p) mod q;
  v2[x,b]:=v2[x,b] or v;
end;
//==================
procedure dp3(x,b:longint);    inline;
var
  i,j:longint;
begin
  i:=son[fr[x]]; j:=son[en[x]];
  find(i,b); find(j,b);
  f[x,b]:=(g[i,b]*g[j,b]) mod q;
  if (f[x,b]>0)or(v2[i,b] and v2[j,b]) then v1[x,b]:=true;
end;
//==================
procedure dp4(x,b:longint);    inline;
begin
  find(son[fr[x]],b);
  g[x,b]:=g[son[fr[x]],b];
  v2[x,b]:=v2[son[fr[x]],b];
end;
//==================
procedure find(i,b:longint);
begin
  if f[i,b]>-1 then exit;
  if b>0 then
  begin
    prepare(i,b);
    if sson[i]<2 then f[i,b]:=0 else dp1(i,b);
    if sson[i]=0 then begin g[i,b]:=1; v2[i,b]:=true; end else dp2(i,b);
  end else
  begin
    if sson[i]<>2 then f[i,b]:=0 else dp3(i,b);
    if sson[i]=0 then begin g[i,b]:=1; v2[i,b]:=true; end else
    if sson[i]=1 then dp4(i,b) else g[i,b]:=0;
  end;
end;
//==================
procedure main;
var
  i:longint;
begin
  fillchar(f,sizeof(f),255);
  fillchar(g,sizeof(g),255);
  i:=0;
  while true do
  begin
    find(1,i);
    if v1[1,i] or v2[1,i] then
    begin
      writeln(i); writeln((f[1,i]+g[1,i]) mod q);
      break;
    end;
    inc(i);
  end;
end;
//==================
begin
  assign(input,'design.in'); reset(input);
  assign(output,'design.out'); rewrite(output);
  get_inf;
  main;
  close(input); close(output);
end.