AS3调用GPU渲染

内容转自天地会

先帖代码，后讲解：

AS 代码(TestShader.as)：

 1 package
 2 {
 3         import flash.display.Sprite;
 4         import flash.display.BitmapData;
 5         import flash.display.Loader;
 6         import flash.display.Shader;
 7         import flash.display.StageScaleMode;
 8         import flash.display.StageAlign;
 9         import flash.events.Event;
10         import flash.events.TimerEvent;
11         import flash.net.URLStream;
12         import flash.net.URLRequest;
13         import flash.utils.ByteArray;
14         import flash.utils.Timer;
15         
16         public class TestShader extends Sprite
17         {
18                 private var _bitmapData:BitmapData;
19                 private var _shader:Shader = new Shader();
20                 private var _sl:URLStream=new URLStream();
21                 
22                 public function TestShader()
23                 {
24                         this.stage.scaleMode=StageScaleMode.NO_SCALE;
25                         this.stage.align=StageAlign.TOP_LEFT;
26                         this.stage.showDefaultContextMenu=false;
27                         //===========================================
28                         
29                         //加载图片
30                         var imgloader:Loader=new Loader();
31                         imgloader.contentLoaderInfo.addEventListener(Event.COMPLETE,imgComplete);
32                         imgloader.load(new URLRequest("image.jpg"));
33                 }
34                 
35                 /**
36                  * 加载图片完成
37                  * @param event
38                  * 
39                  */                
40                 private function imgComplete(event:Event):void
41                 {
42                         _bitmapData=event.target.content.bitmapData;
43                     _sl.addEventListener(Event.COMPLETE,shaderLoaded);
44                     _sl.load(new URLRequest("opengltest.pbj"));
45                 }
46                 
47                 /**
48                  * 加载GLSL代码完成
49                  * @param event
50                  * 
51                  */                
52                 private function shaderLoaded(event:Event):void
53                 {
54                         var sls:URLStream= event.target as URLStream;
55                         if(sls==null){
56                                 throw new Error("GLSL data is empty or load error");
57                         }
58                         var byArr:ByteArray=new ByteArray();
59                         sls.readBytes(byArr);
60                         
61                         //开始着色渲染
62                         _shader.byteCode = byArr;
63                         _shader.data.src.input = _bitmapData;
64                         changeShader();
65                         
66                         
67                         //时间间隔
68                         var time:Timer=new Timer(1000);
69                         time.addEventListener(TimerEvent.TIMER,onTime);
70                         time.start();
71                 }
72                 
73                 /**
74                  * 时间间隔，动态改变着色渲染 
75                  * @param event
76                  * 
77                  */                
78                 private function onTime(event:TimerEvent):void
79                 {
80                         changeShader();
81                 }
82                 
83                 /**
84                  * 改变着色渲染
85                  * 
86                  */                
87                 private function changeShader():void
88                 {
89                         _shader.data.exposure.value = [0.5-Math.random()];
90 
91                         graphics.clear();
92                         graphics.beginShaderFill(_shader);
93                         graphics.drawRect(0,0,300,300);
94                 }
95         }
96 }
97 

Pixel Bender 代码(opengltest.pbk):

<languageVersion : 1.0;>
kernel ExposureFilter
<
    namespace : "tb";
    vendor : "common";
    version : 1;
    description : "picture exposure";
>
{
    parameter float exposure
    <
        minValue:float(-0.5);
        maxValue:float(0.5);
        defaultValue:float(0.0);
        description: "exposure";
    >;
    
    input image4 src;
    output pixel4 dst;

    void evaluatePixel()
    {
        float4 inputColor = sampleNearest(src, outCoord());
        dst.rgb = pow(inputColor.rgb, float3(1.0 - exposure));
        dst.a = inputColor.a;
    }
}

OpenGL的一些知识（针对FP10的知识）:
OpenGL 是个专业的3D程序接口，是一个功能强大，调用方便的底层3D图形库。目前主流的显卡是支持OpenGL 2.0，而FP10支持OpenGL 2.0。
百度百科资料：[url=http://baike.baidu.com/view/9222.htm]http://baike.baidu.com/view/9222.htm[/url]。

GLSL 是OpenGL的开发语言，是用GPU运算的。
Pixel Bender  是建立在GLSL基础上的语言，其实是adobe自己专用的，官方说是有效的在CPU或GPU上运算(怎么感觉比GLSL还智能化，哈哈)。
pbk 是Pixel Bender Toolkit开发工具开发Pixel Bender的代码源文件的后缀名。
pbj 是Pixel Bender Toolkit发布编译后的Pixel Bender代码文件的后缀名，给FP10调用的文件。

因为说GLSL比较顺口，下面都是用GLSL表示，不用Pixel Bender :loveliness:
例子简解：

as部分：
flash.display.Shader： 着色器，调用GLSL就靠她了。
flash.display.Shader： 该类中有data属性，data是GLSL代码数据，这个属性就是用于调用GLSL中的代码；

_shader.byteCode = byArr： 以字节流获取GLSL代码。

_shader.data.src.input = _bitmapData： 这句中的src对应GLSL中的input image4 src;，意思是把位图数据传给GLSL代码处理。
_shader.data.exposure.value = [0.5-Math.random()]：  这句中的exposure 是GLSL代码中的exposure属性，value 是赋值给GLSL代码中的exposure。

GLSL部分：
<languageVersion : 1.0;>：  Pixel Bender Toolkit 编译必须的文件头。
kernel ExposureFilter： kernel 基本的图形渲染核心单元，如果不明白可以先理解为 AS中的 Class，ExposureFilter 渲染单元名，可以先理解为AS中的自定义类名，必须的。
void evaluatePixel()： 这个可以理解为主入口运行函数，相当于C语言的 main，必须的。
parameter ：  声明给AS调用的属性。
input image4 src： GLSL代码获取AS传入的位图数据，src为自定义属性名，image4是src的类型，input声明src为输入。
output pixel4 dst ： GLSL代码处理后输出给flash.display.Shader着色显示的。dst为自定义属性名，pixel4是dst的类型，output 声明dst为输出。

注意细节：
AS中的shader.data.*** 所调用的属性 要与 GLSL中提供的属性对应；
AS中给GLSL的属性赋值是用[]，而不是直接=，如: _shader.data.exposure.value = [0.5];
具体类型参考 ShaderParameterType 类中的静态属性：
package flash.display {
        final public class ShaderParameterType extends Object
        {
            static public var BOOL:String = "bool";
            static public var BOOL2:String = "bool2";
            static public var BOOL3:String = "bool3";
            static public var BOOL4:String = "bool4";
            static public var FLOAT:String = "float";
            static public var FLOAT2:String = "float2";
            static public var FLOAT3:String = "float3";
            static public var FLOAT4:String = "float4";
            static public var INT:String = "int";
            static public var INT2:String = "int2";
            static public var INT3:String = "int3";
            static public var INT4:String = "int4";
            static public var MATRIX2X2:String = "matrix2x2";
            static public var MATRIX3X3:String = "matrix3x3";
            static public var MATRIX4X4:String = "matrix4x4";

            public function ShaderParameterType();
        }
}


如果显卡驱动不支持OpenGL 2.0，程序将使用CPU运算，而不是使用GPU运算，没有显卡硬件加速的效果。请更新最新显卡驱动，支持OpenGL 2.0。

相信不久的将来，将会有用Pixel Bender 开发的提供给AS调用的着色渲染引擎。