[CU]reg model构建篇-uvm_reg_adapter(与前门访问相关)

资料来源

(1) 浅谈UVM register adapter机制 (qq.com)

(2) 《UVM cookbook》

注1:该篇文章会涉及到uvm_reg_bus_op转换为uvm_sequence_item以及uvm_sequence_item发送的细节;

注2:前门访问寄存器方式1- 使用reg model以前门方式访问寄存器时,需要adapter的参与(实现uvm_reg_item到bus_transaction的转换);

注3:前门访问寄存器方式2-直接通过bus_agent(包括bus_sequencer, bus_driver等), bus sequence, bus transaction进行;这种方式绕开了reg model;

1. uvm_reg_adapter的作用

(1) uvm_reg_adapter对于前门操作而言必不可少;

注1:将reg model集成到testbench的先决条件是:  a)register model已经准备好;   b)uvm_reg_adapter类准备好;

(2) 《uvm cookbook》中对uvm_reg_adapter作用的描述比较好,如下:

There are two parts to the register adaption layer, the first part implements the sequence based stimulus layering(即reg2bus转换) and the second part implements the analysis based update of the register model using a predictor component(即bus2reg转换);

2. uvm_reg_bus_op

typedef struct {

  uvm_access_e kind;
  uvm_reg_addr_t addr;
  uvm_reg_data_t data;
  int n_bits;
  uvm_reg_byte_en_t byte_en;
  uvm_status_e status;

} uvm_reg_bus_op;

3. uvm_reg_adapter派生类的实现

virtual class uvm_reg_adapter extends uvm_object;

  function new(string name="");
    super.new(name);
  endfunction

  bit supports_byte_enable;
  bit provides_responses; 
  uvm_sequence_base parent_sequence; 

  pure virtual function uvm_sequence_item reg2bus(const ref uvm_reg_bus_op rw);
  pure virtual function void bus2reg(uvm_sequence_item bus_item,ref uvm_reg_bus_op rw);

  local uvm_reg_item m_item;

  virtual function uvm_reg_item get_item();
    return m_item;
  endfunction
  
  virtual function void m_set_item(uvm_reg_item item);
    m_item = item;
  endfunction
endclass

(1)定义reg2bus函数,将寄存器模型通过sequence发出的uvm_reg_bus_op型变量(register model使用的通用transaction)转换成bus_sequencer能够接受的形式(与协议相关的transaction);

(2) 定义bus2reg函数,将从总线上收集来的transaction转换成寄存器模型能够接受的形式,以便寄存器模型能够更新相应的寄存器的值.

(3) supports_byte_enable成员变量:如果bus协议支持byte enable,需要在adapter的new函数中将supports_byte_enable配为0;

(4) provides_responses成员变量:如果agent driver返回一个单独的response item(比如通过put(response)或者item_done(response)),那么provides_response就会被用于register model层决定是否wait response; provides_response被设置为1的情况下,如果driver没有回复response,会发生异常情况(详见《uvm cookbook》);

//示例1

class my_adapter extends uvm_reg_adapter;
    `uvm_object_utils(my_adapter)
    string tID=get_type_name();

    function new(string name="my_adapter");
        super.new(name);
    endfunction

    //uvm_reg_bus_op->bus_transaction
    function uvm_sequence_item reg2bus(const ref uvm_reg_bus_op rw);
        bus_transaction tr;
        tr=new("tr");
        tr.addr=rw.addr;
        tr.bus_op=(rw.kind==UVM_READ)?BUS_RD:BUS_WR;

        if(tr.bus_op==BUS_WR) tr.wr_data=rw.data;
        return tr;
    endfunction

    //bus_transaction->uvm_reg_bus_op
    function void bus2reg(uvm_sequence_item bus_item, ref uvm_reg_bus_op rw);
        bus_transaction tr;
        if(!$cast(tr,bus_item)) begin
            `uvm_fatal(tID,"Provided bus_item is not of the correct type, expecting bus_trans action")
            return;
        end

        rw.kind=(tr.bus_op==BUS_RD)?UVM_READ:UVM_WRITE;
        rw.addr=tr.addr;
        rw.byte_en='h3;
        rw.data=(tr.bus_op==BUS_RD)?tr.rd_data:tr.wr_data;
        rw.status=UVM_IS_OK;
    endfunction
endclass

//示例2
class reg2apb_adapter extends uvm_reg_adapter;
    `uvm_object_utils(reg2apb_adapter)

    function new(string name="reg2apb_adapter");
        super.new(name);
    endfunction

    virtual function uvm_sequence_item reg2bus(const ref uvm_reg_bus_op rw);
        apb_rw apb=apb_rw::type_id::create("apb_rw");
        apb.kind=(rw.kind==UVM_READ)?apb_rw::READ : apb_rw::WRITE;
        apb.addr=rw.addr;
        apb.data=rw.data;
        return apb;
    endfunction

    virtual fuction void bus2reg(uvm_sequence_item bus_item, ref uvm_reg_bus_op rw);
        apb_rw apb;
        if(!$cast(apb, bus_item)) begin
            `uvm_fatal("NOT_APB_TYPE","provided bus_item is not of the correct type")
            return;
        end

        rw.kind=apb.kind?UVM_READ:UVM_WRITE;
        rw.addr=apb.addr;
        rw.data=apb.data;
        rw.status=UVM_IS_OK;
    endfunction
endclass

class block_env extends uvm_env;
    block_reg_model regmodel;
    subblk_env subblk;

    virtual function void connect_phase(uvm_phase phase);
        ...
        if(regmodel.get_parent==null) begin
            reg2apb_adapter reg2apb=reg2apb_adapter::type_id::create("reg2apb",get_full_name());
            ...
        end
    endfunction

endclass

//示例3

class vga_ral_adapter extends uvm_reg_adapter;
    `uvm_object_utils(vga_ral_adapter)

    function new(string name="");
        super.new(name);
    endfunction

    virtual function uvm_sequence_item reg2bus(const ref uvm_reg_bus_op rw);
        wb_transaction w_trans;
        w_trans=wb_transaction::type_id::create("w_trans");
        w_trans.address=rw.addr;
        w_trans.sel=4'hf;
        w_trans.data=rw.data;
        w_trans.kind=(rw.kind==UVM_READ)?wb_transaction::READ:wb_transaction::WRITE;
        
        return w_trans;
    endfunction

    virtual function void bus2reg(uvm_sequence_item bus_item, ref uvm_reg_bus_op rw);
        wb_transaction trans;
        if(!$cast(trans,bus_item)) begin
            `uvm_fatal("BUS2REF", "Wrong type received")
        end

        rw.addr=trans.address;
        rw.data=trans.data;
        rw.kind=(trans.kind==wb_transaction::READ)?UVM_READ:UVM_WRITE;
        rw.status=UVM_IS_OK;
    endfunction
endclass 

4. uvm_reg_adapter的具体工作过程(前门访问)

(1) 通过reg_model write/read task发寄存器读写命令;

uvm_status_e status;
bit[31:0] rdata;

env.reg_model.XXXX_REG.write(status, 32'haaaa_ffff);
env.reg_model.XXXX_REG.read(status, rdata);

(2)在uvm_reg::write(*) task内,会调用uvm_reg::do_write(uvm_reg_item rw) task,并最终调用uvm_reg_item.local_map.do_write task,即uvm_reg_map.do_write;

(3)在uvm_reg_map的do_write task中,会先为uvm_reg_item.parent赋值,然后调用uvm_reg_map::do_bus_write task;

task uvm_reg_map::do_write(uvm_reg_item rw);

  uvm_sequence_base tmp_parent_seq;
  uvm_reg_map system_map = get_root_map();
  uvm_reg_adapter adapter = system_map.get_adapter();
  uvm_sequencer_base sequencer = system_map.get_sequencer();

  if (adapter != null && adapter.parent_sequence != null) begin
    uvm_object o;
    uvm_sequence_base seq;
    o = adapter.parent_sequence.clone();
    assert($cast(seq,o));
    seq.set_parent_sequence(rw.parent);
    rw.parent = seq;
    tmp_parent_seq = seq;
  end

  if (rw.parent == null) begin
     rw.parent = new("default_parent_seq");
     tmp_parent_seq = rw.parent;
  end

  if (adapter == null) begin
    rw.set_sequencer(sequencer);
    rw.parent.start_item(rw,rw.prior);
    rw.parent.finish_item(rw);
    rw.end_event.wait_on();
  end
  else begin
    do_bus_write(rw, sequencer, adapter);
  end

  if (tmp_parent_seq != null)
    sequencer.m_sequence_exiting(tmp_parent_seq);

endtask

(4)在uvm_reg_map::do_bus_write task中,会调用uvm_reg_adapter.reg2bus将uvm_reg_bus_op转换为uvm_sequence_item;

(5)为uvm_seq_item设置相应的sequencer(该sequencer为uvm_reg_map的sequencer),并调用uvm_reg_item.parent.start_item(uvm_seq_item)进行trans的发送;

注1:uvm_reg与uvm_reg_map的联系是通过uvm_reg_map.add_reg建立的;uvm_reg_map::add_reg函数会调用uvm_reg.add_map(this);uvm_reg.add_map(this)会将this指向的uvm_reg_map作为uvm_reg的关联数组m_maps的索引);

function void uvm_reg_map::add_reg(uvm_reg rg, 
                                   uvm_reg_addr_t offset,
                                   string rights = "RW",
                                   bit unmapped=0,
                                   uvm_reg_frontdoor frontdoor=null);

   if (m_regs_info.exists(rg)) begin
      `uvm_error("RegModel", {"Register '",rg.get_name(),
                 "' has already been added to map '",get_name(),"'"})
      return;
   end

   if (rg.get_parent() != get_parent()) begin
      `uvm_error("RegModel",
         {"Register '",rg.get_full_name(),"' may not be added to address map '",
          get_full_name(),"' : they are not in the same block"})
      return;
   end
   
   rg.add_map(this);

   begin
   uvm_reg_map_info info = new;
   info.offset   = offset;
   info.rights   = rights;
   info.unmapped = unmapped;
   info.frontdoor = frontdoor;
   m_regs_info[rg] = info;
   end
endfunction

function void uvm_reg::add_map(uvm_reg_map map);
  m_maps[map] = 1;
endfunction

注2:uvm_reg_item与uvm_reg_map的联系是怎么建立的? uvm_reg_item.local_map是在uvm_reg::do_write调用的Xcheck_accessX内获取的; uvm_reg_item.map是在uvm_reg::write等函数内获取的);

function bit uvm_reg::Xcheck_accessX (input uvm_reg_item rw,
                                      output uvm_reg_map_info map_info,
                                      input string caller);


   if (rw.path == UVM_DEFAULT_PATH)
     rw.path = m_parent.get_default_path();

   if (rw.path == UVM_BACKDOOR) begin
      if (get_backdoor() == null && !has_hdl_path()) begin
         `uvm_warning("RegModel",
            {"No backdoor access available for register '",get_full_name(),
            "' . Using frontdoor instead."})
         rw.path = UVM_FRONTDOOR;
      end
      else
        rw.map = uvm_reg_map::backdoor();
   end


   if (rw.path != UVM_BACKDOOR) begin

     rw.local_map = get_local_map(rw.map,caller);

     if (rw.local_map == null) begin
        `uvm_error(get_type_name(), 
           {"No transactor available to physically access register on map '",
            rw.map.get_full_name(),"'"})
        rw.status = UVM_NOT_OK;
        return 0;
     end

     map_info = rw.local_map.get_reg_map_info(this);

     if (map_info.frontdoor == null && map_info.unmapped) begin
          `uvm_error("RegModel", {"Register '",get_full_name(),
             "' unmapped in map '",
             (rw.map==null)? rw.local_map.get_full_name():rw.map.get_full_name(),
             "' and does not have a user-defined frontdoor"})
          rw.status = UVM_NOT_OK;
          return 0;
     end

     if (rw.map == null)
       rw.map = rw.local_map;
   end
   return 1;
endfunction

5. uvm_reg_adapter与bus_seqr及uvm_reg_map的联系

(1)通过调用regmodel.reg_map的set_sequencer(sequencer, adapter)函数使用reg adapter;

//示例1
default_map.set_sequencer(env.bus_agt.sqr,reg_sqr_adapter);

//示例2
virtual function void connect_phase(uvm_phase phase);
    super.connect_phase(phase);
    reg_adapter adapter;
    adapter=reg_adapter::type_id::create("adapter",this);
    regmodel.default_map.set_sequence(m_agent.seqr,adapter);
endfunction