[原创]一键转移桌面-收藏夹-文档

     多次的装机经验告诉我,系统的一些文件夹如桌面、收藏夹、我的文档等用户数据文件夹不能存放在C分区，也就是系统分区下面，这样做主要是为了使Ghost恢复系统之后不至于导致自己的文档和收藏夹丢失，还有一些垃圾文件夹（如临时文件夹、网页缓存、历史记录等等）也不能放在这里，因为长期使用后会导致这个分区日益膨胀，最后臃肿不堪，所以非常有必要转移到别的分区。用户的个人文档放在你选定的分区下面的一个叫Personal的文件夹，垃圾文件就通通放在Rubbish中。这样找文档的时候直接到Personal里面，清理系统的垃圾的时候直接到Rubbish中。下面的批处理代码，直接分别复制到记事本中，然后保存为bat文件，然后双击运行，按照上面的提示就可自动实现文档的转移了。

@echo off
::设置标题
title 桌面,收藏夹,文档数据转移程序,Designed By CriD.CN,�te%
::定制程序样式
mode con cols=75 lines=15
color f0
::输入及判断分区的合法性
:check
::partition为分区，如C,D,E,F等；
set partition=
set /p partition=请输入放置文档的分区,例如保存在D盘,直接输入D然后回车:
cls
echo 正在检查你的输入,请等待......
if "%partition%"=="" (
echo 不好意思，你没有输入任何东西
goto check)
for /f %%i in ('mountvol ^|find /i "%partition%:"') do @set tmppf=%%i
if not "%tmppf%"=="%partition%:\" (
echo 不好意思,你输入的%partition%盘不存在,请重新输入
goto check )
if "%partition%:"=="A:" (
echo 不好意思，A盘为软驱盘,请重新输入
goto check)
fsutil fsinfo drivetype %partition%:>type.txt
for /f "tokens=3" %%j in (type.txt) do (
if "%%j"=="CD-ROM" (
echo 不好意思，你输入的%partition%盘为CD-ROM驱动器，请重新输入
goto check))
del type.txt /q
::创建目标文件夹
echo 正在创建目标文件夹......
md "%partition%:\Rubbish\Temporary Internet Files">nul 2>nul
md "%partition%:\Rubbish\Temp">nul 2>nul
md "%partition%:\Rubbish\cookies">nul 2>nul
md "%partition%:\Rubbish\history">nul 2>nul
md "%partition%:\Rubbish\最近文档">nul 2>nul
md "%partition%:\Personal\桌面">nul 2>nul
md "%partition%:\Personal\收藏夹">nul 2>nul
md "%partition%:\Personal\我的文档">nul 2>nul
md "%partition%:\Personal\我的文档\我的音乐">nul 2>nul
md "%partition%:\Personal\我的文档\我的图片">nul 2>nul
md "%partition%:\Personal\我的文档\我的视频">nul 2>nul
md "%partition%:\Personal\我的下载">nul 2>nul
::备份原来的注册表
echo 正在备份你原来的设置,若不满意该程序的设置可以,双击reset.bat恢复原来的设置
reg export "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" "Shell Folders.reg">nul
reg export "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" "User Shell Folders.reg">nul
reg export "HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" "Default Shell Folders.reg">nul
reg export "HKEY_CURRENT_USER\Environment" "Environment.reg">nul
echo @echo off>reset.bat
echo regedit /s "Shell Folders.reg">>reset.bat
echo regedit /s "User Shell Folders.reg">>reset.bat
echo regedit /s "Default Shell Folders.reg">>reset.bat
echo regedit /s "Environment.reg">>reset.bat
echo echo 恢复成功,恢复后的设置将在重启后生效,按任意键将重启电脑>>reset.bat
echo pause^>nul>>reset.bat
echo shutdown -r -f -t 0 >>reset.bat
::备份原来的文件(桌面,文档,收藏夹)到目标文件夹
echo 正在转移文件......
xcopy "%userprofile%\桌面" "%partition%:\Personal\桌面" /s /q /h /y>nul 2>nul
xcopy "%userprofile%\My Documents" "%partition%:\Personal\我的文档"  /s /q /h /y>nul 2>nul
rd "%partition%:\Personal\我的文档\My Music" /s /q>nul 2>nul
rd "%partition%:\Personal\我的文档\My Pictures" /s /q>nul 2>nul
rd "%partition%:\Personal\我的文档\My Video" /s /q>nul 2>nul
xcopy "%userprofile%\My Documents\My Music" "%partition%:\Personal\我的文档\我的音乐" /s /q /h /y>nul 2>nul
xcopy "%userprofile%\My Documents\My Pictures" "%partition%:\Personal\我的文档\我的图片" /s /q /h /y>nul 2>nul
xcopy "%userprofile%\My Documents\My Video" "%partition%:\Personal\我的文档\我的视频" /s /q /h /y>nul 2>nul
xcopy "%userprofile%\Favorites" "%partition%:\Personal\收藏夹" /s /q /h /y>nul 2>nul
::将信息生成注册表文件,并将其导入
echo 正在生成新的配置信息......
echo  Windows Registry Editor Version 5.00>set.reg
echo. >>set.reg
::[HKEY_CURRENT_USER\So ftware\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]
echo  [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]>>set.reg
echo  "Cache"="%partition%:\\Rubbish\\Temporary Internet Files">>set.reg
echo  "Cookies"="%partition%:\\Rubbish\\cookies">>set.reg
echo  "History"="%partition%:\\Rubbish\\history">>set.reg
echo  "Desktop"="%partition%:\\Personal\\桌面">>set.reg
echo  "Favorites"="%partition%:\\Personal\\收藏夹">>set.reg
echo  "Personal"="%partition%:\\Personal\\我的文档">>set.reg
echo  "My Music"="%partition%:\\Personal\\我的文档\\我的音乐">>set.reg
echo  "My Pictures"="%partition%:\\Personal\\我的文档\\我的图片">>set.reg
echo  "My Video"="%partition%:\\Personal\\我的文档\\我的视频">>set.reg
echo  "Recent"="%partition%:\\Rubbish\\最近文档">>set.reg
::[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders]
echo  [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders]>>set.reg
echo  "Cache"="%partition%:\\Rubbish\\Temporary Internet Files">>set.reg
echo  "Cookies"="%partition%:\\Rubbish\\cookies">>set.reg
echo  "History"="%partition%:\\Rubbish\\history">>set.reg
echo  "Desktop"="%partition%:\\Personal\\桌面">>set.reg
echo  "Favorites"="%partition%:\\Personal\\收藏夹">>set.reg
echo  "Personal"="%partition%:\\Personal\\我的文档">>set.reg
echo  "My Music"="%partition%:\\Personal\\我的文档\\我的音乐">>set.reg
echo  "My Pictures"="%partition%:\\Personal\\我的文档\\我的图片">>set.reg
echo  "My Video"="%partition%:\\Personal\\我的文档\\我的视频">>set.reg
echo  "Recent"="%partition%:\\Rubbish\\最近文档">>set.reg
::[HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]
echo  [HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]>>set.reg
echo  "Desktop"="%partition%:\\Personal\\桌面">>set.reg
echo  "Cache"="%partition%:\\Personal\\我的文档">>set.reg
echo  "Download Directory"="%partition%:\\Personal\\我的下载">>set.reg
::[HKEY_CURRENT_USER\Environment]设置环境变量
echo  [HKEY_CURRENT_USER\Environment]>>set.reg
echo  "TEMP"="%partition%:\\Rubbish\\Temp">>set.reg
echo  "TMP"="%partition%:\\Rubbish\\Temp">>set.reg
echo 正在导入配置信息......
regedit /s set.reg
del set.reg /q
echo 转移成功,设置将在重启之后生效,按任意键重启计算机
pause>nul
shutdown -r -f -t 0