客户端实现SQL 查询
由于在客户端不存在TQuery控件,似乎客户服务器模式是无法做SQL查询的。但是,Delphi很好的解决了这个问题。事实上,只要客户端连接上服务端应用程序,客户端的TClientDataSet就包含了一个名字为Provider的属性,对应到服务器端DataSetProvider的所有默认属性和方法,其中DataSetProvider有一个Options属性,只要让其中的poAllowCommandText=true,那么,DataSetProvider的poAllowCommandText就可以接受前台来的SQL 命令,并传送给TQuery。可以看出,真正传递数据的是DataSetProvider的接口,所以,用这个接口搭建传递SQL 的桥梁是必需的。
客户端进行SQL 查询的方法是:
ClientDataSet.Close;
ClientDataSet.CommandText := 'SQL语句';
ClientDataSet.Open;
下面通过一个实例来说明方法:
一、SQL 服务器端程序:
首先用上面相同的方法建立一个服务器端COM 工程。工程名取为:PcSQL。
放入一个Query和一个DataSetProvider。
DataSetProvider的属性Options下的poAllowCommandText=true
这实际上已经建立了一个基于SQL 查询的服务器端程序。
客户端查询服务器端的别名集
在SQL 查询以前,用户往往需要指定查询哪个数据库,所以需要把服务器上BDE 数据库别名(Alias )设置数据抓到前台程序来具体做法我们通过一个实例来解决:
还是先回到服务器端:
在上述服务器端再建立一个TSession和一个TdataBase(在BDE 页下)
Session1属性:
AutoSessionName=true
SessionName=Session1_4 (运行中是可以自动调整的)
KeepConnection=true
Active=true
DataBase1属性:
AliasName: 连接数据库别名(比如Mymdb)
DataBaseName: 自定义的名(这里比如为a)
SessionName: Session1_4 (SessionName值)
如果不希望输入密码:
LoginPrompt : false
这样Query1的连接属性要变一下,因为它要通过Database来联接数据库(以后在前台可以直接通过改变DataBase的属性来改变联接)
DataBaseName= DataBase1的DataBaseName:自定义的名(这里比如为a)。
SQL属性输入一个基本的SQL语言:select * from 奖金 Active=true 表示这样也可以连接上了。
TQurey 增加个属性
SessionName: Session1_4
这样就可以用Session对象来管理数据源的信息了。
再加入四个Label,显示当前在线人数,以及进行SQL 查询的人数。
为了传给客户端值,并能够由客户端来对服务器端进行某些控制,需要在COM 中加入两个方法:
View -> Type Library 显示接口窗口。
右键 IPcSQL(具体根据设置名不同而不同) -> New ->建立两个方法(Method):
GetDatabaseNames ,用以传下别名数据,其接口信息为:
Return type :HRESULT
Parameters
name type modifier
Param1 VARIANT* [out,retval]
SetDatabaseName , 用以接受客户机来的信息,其接口信息要求传入
三个信息(注意:图上的SetDatabaseName误为SetDatabaseNames,实际请设为SetDatabaseName,否则客户调用名称可能会出错)。
Return type :HRESULT
Parameters
name type modifier
DBName BSTR [in] ----传上来的别名
(用Add加入)
UserName BSTR [in]
Password BSTR [in]
刷新(Refresh Implementation)以后,就产生两个函数
function TPcSQL.GetDatabasenames: OleVariant;
begin
end;
procedure TPcSQL.SetDatabasename(const DBname, Username,
Password: WideString);
begin
end;
function TPcSQL.GetDatabaseNames: OleVariant;
var
I: Integer;
DBNames: TStrings;
begin
// 建立一个字符串数组存放BDE所有的数据库别名数据。
DBNames := TStringList.Create;
try
// 利用Session控件取得当前BDE所有的数据库别名数据。
Session1.GetDatabaseNames(DBNames);
/// 建立一个变量数组给函数返回变量Result。
Result := VarArrayCreate([0, DBNames.Count - 1], varOleStr);
// 最后再把数据库别名数据指定给该变量数组。
for I := 0 to DBNames.Count - 1 do
Result[I] := DBNames[I];
Finally
//如果错误就把构造的DBNames释放掉。
DBNames.Free;
end;
end;
上面的函数的关键除了取得BDE 数据库别名以外,还声明了一个变量数组来存放数据库别名数据,所以用VarArrayCreate函数建立一个变量数组,其中参数1: 指定数组范围;参数2:数组数据类型,由于别名要通过DCOM传给前台,数据类型必须设成varOleStr 才有效。 同时还要说明VarArrayCreate函数是在Variants单元中建立的,所以,在implementation下还需要声明:
uses Variants;
否则会编译出错,,必要时还要加上Unit1。
第二个过程是客户机提供上来的联机数据。
procedure TPcSQL.SetDatabaseName(const DBName, UserName,
Password: WideString);
begin
try
// 把前台传来的数据库别名、用户上线名称、用户上线密码
// 等三项数据指定给TDatabase控件,并且执行联机的操作。
Database1.Close;
Database1.AliasName := DBName;
if (UserName<>'') and (Password<>'') then begin
Database1.Params.Values['PASSWORD'] := Password;
Database1.Params.Values['USER NAME'] := UserName;
end;
Database1.Open;
except
// 如果联机时发生错误,则产生一个exception给前台程序
// 前台程序将会利用到这个exception来判断是否要把输入上
// 线数据的窗口激活。
on E: EDBEngineError do
raise Exception.Create('Password Required') ;
end;
end;
服务器端进行客户计数
除了上面的功能外,这个程序还加上了一个在线用户以及查询用户统计的功能。由于这个应用程序执行模式是 Multiple Instance执行模式,所以当某个前台第一次连上线后,应用程序服务器会激活RemoteDataModule的事件程序,而断线后又会执行OnDestroy事件程序,因此就可以用这两个事件计算连上服务器的用户个数。至于Query个数的计算,则由TQuery的OnAfterOpen事件函数判断。
-----------------------------------------------------------------
Form1部分,主要用于显示
-----------------------------------------------------------------
首先在form上安放五个Tlabel控件,其中四个放在一个容器Panel1里两个计数的label分别取名为ClientCount和QueryCount。属性Capyion=0。注意,下面的程序在Form1所在的单元Unit1中编写。
在private下声明两个变量:
FQueryCount: Integer;
FClientCount: Integer;
在public下声明两个过程
procedure UpdateClientCount(Incr: Integer);
procedure IncQueryCount;
在实现区写入过程:
procedure Tform1.UpdateClientCount(Incr: Integer);
begin
FClientCount := FClientCount + Incr;
ClientCount.Caption := IntToStr(FClientCount);
end;
procedure Tform1.IncQueryCount;
begin
Inc(FQueryCount);
QueryCount.Caption := IntToStr(FQueryCount);
end;
--------------------------------------------------------
COM部分
--------------------------------------------------------
在PcSQL窗口的两个事件OnCreate和OnDesticy,建立事件驱动程序:
procedure TPcSQL.RemoteDataModuleCreate(Sender: TObject);
begin
end;
procedure TPcSQL.RemoteDataModuleDestroy(Sender: TObject);
begin
end;
procedure TPcSQ.RemoteDataModuleCreate(Sender: TObject);
begin
// 增加一位前台上线者(调用Form1上的程序)
Form1.UpdateClientCount(1);
end;
procedure TPcSQ.RemoteDataModuleDestroy(Sender: TObject);
begin
// 减少一位前台上线者(调用Form1上的程序)
Form1.UpdateClientCount(-1);
end;
在Tqurey的事件AfterOpen建立事件驱动程序:
procedure TPcSQL.Query1AfterOpen(DataSet: TDataSet);
begin
end;
procedure TPcSQ.AdHocQueryAfterOpen(DataSet: TDataSet);
begin
// 新打开一个TQuery查询(调用Form1上的程序)
Form1.IncQueryCount;
end;
保存,编译,注册
二、SQL 客户端程序
1)建立一个普通的工程。
2)放置一个TDCOMConnrction控件(在Datasnap页),属性:
在本机注册时,可直接设置以下属性:
ServerName:应用程序服务器注册名(pro1.pc121)
Connected=true 激活
这时你可以看到服务器端的COM 程序被激活了。
如果在网络上调试,需要给出服务器名:
ComputerName:服务器名(自动给出网上邻居)
注意:
ServerGUID的GUID值是自动给出的。
3)放置一个TClientDataSet控件(在Data Access页)
属性:
RemoteServer= DCOMConnrction1
ProviderName:=DataSetProvider1
Active=true (激活后将能正常连接)
4)放置TDataSource,属性:
Dataset:指向ClientDataSet1
安放合适的数据库绑定控件。放置Demo控件作为SQL 数据输入用。
procedure TForm1.Button1Click(Sender: TObject);
begin
// 把Memo内用户输入的SQL命令,通过IProvide的
// DataRequest方法传给应用程序服务器。
ClientDataSet1.Close;
ClientDataSet1.CommandText := Memo1.Lines.Text;
ClientDataSet1.Open;
end;
希望用户直接调用服务器端的别名,可以加入一个ComboBox控件:
form1的Create 事件可以写成:
procedure TForm1.FormCreate(Sender: TObject);
var
I: Integer;
DBNames: OleVariant;
begin
// 连上应用程序服务器
DCOMConnection1.Connected := True;
// 取得BDE所有设置的数据库别名数据
DBNames := DCOMConnection1.AppServer.GetDatabaseNames;
// 假如有数据库别名数据,则将其一个一个地加到ComboBox控件内
if VarIsArray(DBNames) then
for I := 0 to VarArrayHighBound(DBNames, 1) do
ComboBox1.Items.Add(DBNames[I]);
//把默认的数据库显示在第一个
ComboBox1.Text:='mymdb';
end;
运行以后可以看到服务器端的所有的别名:
为了用这个别名列表调用其它的数据库,考虑到有的数据库需要输入密码和用户名,需要加入一个新的Form。
File->New->other->new-form 这就加入了一个Form2
加入相应的输入密码控件。
其中:CheckBox1的属性 Name=Check ;而两个Edit控件的Text属性为空字符串。
Form2的两个按钮事件可以写成:
procedure TForm2.Button1Click(Sender: TObject);
begin
Check.Checked:=True;
close;
end;
procedure TForm2.Button2Click(Sender: TObject);
begin
Check.Checked:=False;
close;
end;
然后回到form1。
首先在private 区声明一个函数InputDialog,用于启动让用户输入上线数据的Form2。
function InputDialog(var UserName, Password:String):Boolean;
然后在实现区写入该函数的程序:
// 启动让用户输入上线数据的Form
function TForm1.InputDialog(var UserName, Password:String):Boolean;
var ret:Boolean;
begin
ret:=False;
try
Form2:=TForm2.Create(Application);
Form2.ShowModal;
UserName:=Form2.Edit1.Text;
Password:=Form2.Edit2.Text;
if Form2.Check.Checked then ret:=True
else ret:=False;
finally
Form2.Free;
Result:=ret;
end;
end;
现在,可以给ComboBox1加入一个双击事件:
procedure TForm1.ComboBox1DblClick(Sender: TObject);
var
UserName, Password: string;
begin
// 当您在ComboBox中选取的数据不是空字符串时
if ComboBox1.Text <> '' then
begin
ClientDataSet1.Close;
try
// 先给应用程序服务器传一次空的UserName及Password
// 如果后台数据库是Paradox或dBASE可能就没问题,
// 可是如果是SQL base的关系型数据库则会收到exception。
//SetDatabaseNames是服务端的COM 方法
DCOMConnection1.AppServer.SetDatabaseName(ComboBox1.Text,'','');
except
// 由于后台数据库是SQL base的关系型数据库,所以您必须
// 通过Form2输入UserName及Password,并且把这些数据
// 通过应用程序服务器提供的SetDatabaseName传给后台数
// 据库验证。
on E: Exception do
if E.Message = 'Password Required' then
begin
if InputDialog(UserName, Password) then
DCOMConnection1.AppServer.SetDatabaseName(ComboBox1.Text,
UserName, Password);
end else raise;
end;
end;
end;
以后就可以利用服务器端的别名列表选择数据库了。
双击该列表框实际上已经实现了联接,但是,窗口除关闭掉数据库显示以外,并没有其它的反应,这就是说,这个程序使用上还有若干不方便的地方,最重要的就是当连结上数据库以后,无法知道表的名字。这样,也无法方便的构造查询数据集的SQL语言。
下面解决这个问题。
现在,在服务器上再做一个方法: GetTableNames ,准备向客户端送表名。
注意,要用Add加入一个传出参数。
刷新后产生一个新的方法:
function GetTableNames: OleVariant; safecall;
现在可以写方法程序了:
function TPcSQL.GetTableNames: OleVariant;
var
I: Integer;
DBTables: TStrings;
begin
// 建立一个字符串数组存放所有表名。
DBTables := TStringList.Create;
try
// 利用Database控件取得当前所有表名数据。
Database1.GetTableNames(DBTables , False);
/// 建立一个变量数组给函数返回变量Result。
Result := VarArrayCreate([0, DBTables.Count - 1], varOleStr);
// 最后再把表名数据指定给该变量数组。
for I := 0 to DBTables.Count - 1 do
Result[I] := DBTables[I];
finally
DBTables.Free;
end;
end;
然后重新保存,注册,运行一下。
再看客户端:
现在给它再加一个ComboBox,以显示当前打开的数据库的表名。
; 在.FormCreate事件过程中,再声明一个变量:
DBTables: OleVariant;
在.FormCreate程序的最后加上:
//显示表名
ComboBox2.Clear;
DBTables := DCOMConnection1.AppServer.GetTableNames;
if VarIsArray(DBTables) then
for I := 0 to VarArrayHighBound(DBTables, 1) do
ComboBox2.Items.Add(DBtables[I]);
为了在改变数据库后也能正确显示相应的表名,ComboBox1的双击事件也要加上相应的一段。
procedure TForm1.ComboBox1DblClick(Sender: TObject);
var
UserName, Password: string;
//下面两的变量声明是新加的
DBTables: OleVariant;
i:integer;
begin
// 当您在ComboBox中选取的数据不是空字符串时
if ComboBox1.Text <> '' then
begin
ClientDataSet1.Close;
try
// 先给应用程序服务器传一次空的UserName及Password
// 如果后台数据库是Paradox或dBASE可能就没问题,
// 可是如果是SQL base的关系型数据库则会收到exception。
//SetDatabaseNames是服务端的COM 方法
DCOMConnection1.AppServer.SetDatabaseName(ComboBox1.Text,'','');
except
// 由于后台数据库是SQL base的关系型数据库,所以您必须
// 通过Form2输入UserName及Password,并且把这些数据
// 通过应用程序服务器提供的SetDatabaseName传给后台数
// 据库验证。
on E: Exception do
if E.Message = 'Password Required' then
begin
if InputDialog(UserName, Password) then
DCOMConnection1.AppServer.SetDatabaseName(ComboBox1.Text,
UserName, Password);
end else raise;
end;
//显示表名,这段程序是新加的
ComboBox2.Clear;
DBTables := DCOMConnection1.AppServer.GetTableNames;
if VarIsArray(DBTables) then
for I := 0 to VarArrayHighBound(DBTables, 1) do
ComboBox2.Items.Add(DBtables[I]);
ComboBox2.Text:=ComboBox2.items[0];
end;
end;
给ComboBpx2加一个双击事件,可以把表的名字加入SQL 语言:
procedure TForm1.ComboBox2DblClick(Sender: TObject);
begin
Memo1.text:=Memo1.text+combobox2.text;
end;
效果就完全不同了,你可以方便的选择数据库和表:
然后组合适当的SQL语言,最终打开一个合适的表。
进一步考虑,组合新的SQL语言的时候最好要有字段名的数据,这不需要从服务器得到,因为在多层情况下,ClientDataSet实际上起着Ttable或者Tquery相似的作用,对数据库的控制上,有几乎相同的语言,例如记录指针的移动,字段数据的取得和写入等等,这样一来,你也可以直接使用这些方法来操纵数据库。
再一次提醒大家,ClientDataSet是个功能强大非常重要的控件,在Delphi的很多高级场合,都要使用到它。
当然,利用ClientDataSet,被打开数据库的字段名表也很容易得到。
首先再加一个Combbox控件Combbox3。
把SQL 查询的Button事件作如下修改:
procedure TForm1.Button1Click(Sender: TObject);
//首先要定义两个变量
var i,N:integer;
begin
ClientDataSet1.Close;
ClientDataSet1.CommandText := Memo1.Lines.Text;
ClientDataSet1.Open;
//这是后加入的显示子段名的程序
ComboBox3.Clear;
N:=ClientDataSet1.FieldCount;
for I := 0 to N - 1 do
ComboBox3.Items.Add(ClientDataSet1.Fields[i].FieldName);
ComboBox3.Text:=ComboBox3.items[0];
end;
事实上,FormCreate事件程序也要加入相应的程序,使一打开程序就有子段名表显示。
procedure TForm1.FormCreate(Sender: TObject);
var
//增加两个定义
I,N: Integer;
DBNames: OleVariant;
DBTables: OleVariant;
begin
// 连上应用程序服务器
DCOMConnection1.Connected := True;
// 取得BDE所有设置的数据库别名数据
DBNames := DCOMConnection1.AppServer.GetDatabaseNames;
// 假如有数据库别名数据,则将其一个一个地加到ComboBox控件内
if VarIsArray(DBNames) then
for I := 0 to VarArrayHighBound(DBNames, 1) do
ComboBox1.Items.Add(DBNames[I]);
//把默认的数据库显示在第一个
ComboBox1.Text:='abc';
//显示表名
DBTables := DCOMConnection1.AppServer.GetTableNames;
if VarIsArray(DBTables) then
for I := 0 to VarArrayHighBound(DBTables, 1) do
ComboBox2.Items.Add(DBtables[I]);
ComboBox2.Text:=ComboBox2.items[0];
//显示字段名表,增加的程序
ComboBox3.Clear;
N:=ClientDataSet1.FieldCount;
for I := 0 to N - 1 do
ComboBox3.Items.Add(ClientDataSet1.Fields[i].FieldName);
ComboBox3.Text:=ComboBox3.items[0];
end;
需要时,也可以写入ComboBox3的双击事件:
procedure TForm1.ComboBox3DblClick(Sender: TObject);
begin
Memo1.text:=Memo1.text+combobox3.text;
end;
好了,现在可以看看效果:
这些数据取得以后,你就可以把这个客户程序做得更加方便通用,那就要看你的想象力和程序设计的水平了,这里的例子,主要是想提供客户端使用DCOM提供的方法的思想和规则,通过这样的研究,您是不是对DCOM 和分布式数据库的问题有了更深的理解了呢?
第七节一对多表的服务器端程序
一、Application Server
事先要有一个标准的Form
file -> New -> Multitier -> Remote Data Module
CoClass Name : Master2
Instacting: Multiple Instacting
Threading Model: Apartment
放入 ADOTable1
ADOTable2
Datasouce1
DataSetProvider1(在Data Access)
DataSetProvider2
属性:
ADOTable1(主表)
ADOTable2(从表)
用ConnectionString和TableName连上数据库
为了构建主从表,注意下面的图:
DataSouce1属性:DataSet=ADOTab1
ADOTable2属性:MasterSource=DataSource1
MasterField=连结字段
TdataSetProvider1属性:Dataset=ADOTable1
TdataSetProvider2属性:Dataset=ADOTable2
这就完成了主从表的服务器端构建。
保存,注册,运行一下。
二、客户端编程
首先建立一个普通的工程:
加入一个TDCOMConnection,两个TClientDataSet,和两个TdataSource。
DCOMConnection1
属性:ComputerName=计算机名(本地可以不写)
ServerName=服务器端程序名(COM)
Connecter=true (表示连上)
ClientDataSet1
属性:RemoteServer=DCOMConnection1
ProviderName=DataSetProvider1
Active-=true
ClientDataSet2
属性:RemoteServer=DCOMConnection2
ProviderName=DataSetProvider2
Active-=true
两个TDataSource分别连上
ClientDataSet1和
ClientDataSet2
加入两个TDBGrid,分别连上相应的DataSource。
主从表似乎应该建立起来了,但运行一下就可以发现,主从关系并没有建立起来。
解决办法:
双击ClientDataSet1,出现一个Form1.ClientDataSet1窗口:
在窗口空白处右键,快捷菜单上选Add Field 这时,我们可以看到最后一行出现:ADOTable2 。这是很重要的,正是靠这个建立了主从联接关系
OK 让它进入Form1.ClientDataSet1窗口(也可以调整主表所显示的字段,但ADOTable2 不能少,它实际上是把从表作为主表的一个字段使用了)。
ClientDataSet2属性:
DataSetField=ClientDataSet1ADOTable2
Active=true
好啦,主从关系建立起来了。
通过这个研究可以发现,实际上在服务端程序中,DataSetProvider2是多余的,以后在设置的时候,可以不要。只需要一个DataSetProvider1就可以和客户端联系了。