SVN 每日自动备份

备份需要两个文件backup.bat和simpleBackup.bat, 再把backup.bat添加到windows的 计划任务里.

 

1. simpleBackup.bat 文件放在svn代码库在D:\Repositories(我的机子是这个目录)

simpleBackup.bat:

@echo 正在备份版本库%1......
@%SVN_HOME%bin\svnadmin hotcopy %1 %BACKUP_DIRECTORY%\%2
@echo 版本库%1成功备份到了%2!

 

2.backup.bat这个文件随便你放哪.(以下红色的三个目录设置设置一下就可以了)

backup.bat

echo off
rem Subversion的安装目录
set SVN_HOME="D:\Program Files\VisualSVN Server\"

rem 所有版本库的父目录
set SVN_ROOT=D:/Repositories

rem 备份的目录
set BACKUP_SVN_ROOT=F:/svnbak
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%/%date:~0,10%

rem 如果已经存在当天的备份文件夹,就跳到下面的提示信息
if exist %BACKUP_DIRECTORY% goto checkBack

echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log
mkdir "%BACKUP_DIRECTORY%"

rem 验证目录是否为版本库，如果是则取出名称备份
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf" %SVN_ROOT%/simpleBackup.bat "%%~fI" %%~nI
goto end

:checkBack
echo 备份目录%BACKUP_DIRECTORY%已经存在,请清空。
goto end
:end

 

3.backup 压缩版

你的机器上要有7zip的命令行程序7z.exe，如果没有，请去7zip官方网站下载，因为我们要用到这个程序来实现对备份后的版本库进行压缩保存

(7-Zip http://www.7-zip.org/download.html)

backup 7zip压缩版.bat

echo off
rem Subversion的安装目录
set SVN_HOME="D:\Program Files\VisualSVN Server\"

rem 所有版本库的父目录
set SVN_ROOT=D:/Repositories

rem 备份的目录
set BACKUP_SVN_ROOT=F:/SVNBackUp
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%/%date:~0,10%

rem 如果已经存在当天的备份文件夹,就跳到下面的提示信息
if exist %BACKUP_DIRECTORY% goto checkBack

echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log
mkdir "%BACKUP_DIRECTORY%"

rem 验证目录是否为版本库，如果是则取出名称备份
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I\conf\svnserve.conf" call %SVN_ROOT%\simpleBackup.bat "%%~fI" %%~nI 

echo 开始压缩版本库，请不要中止.... 
%SVN_ROOT%\7zG.exe a -tzip %BACKUP_SVN_ROOT%\%date:~0,4%%date:~5,2%%date:~8,2%.zip %BACKUP_DIRECTORY%\* -r >nul 
echo 版本库压缩完成! 
rem 清除临时创建备份目录 
rd/s/q "%BACKUP_DIRECTORY%"
goto end

:checkBack
echo 备份目录%BACKUP_DIRECTORY%已经存在,请清空。
goto end
:end

 

注意：执行此计划任务的windows用户必须要设置密码，否则此计划任务不会执行。