Oracle常见问题：将登录失败的信息记录到alert日志中

问题描述

有个数据库用户经常被锁，Unlock之后没几秒就会被锁住，因为涉及的项目太多，很难做到逐一排查，不知道是哪个项目用错密码，导致账户被锁。后面排查日志没有发现登录失败的日志，故在网上查找相关资料，发现可以创建一个触发器可将相关日志记录下来。

解决方案

用dba账户创建如下触发器即可。

CREATE OR REPLACE TRIGGER logon_denied_to_alert
  AFTER servererror ON DATABASE
DECLARE
  message   VARCHAR2(168);
  ip        VARCHAR2(15);
  v_os_user VARCHAR2(80);
  v_module  VARCHAR2(50);
  v_action  VARCHAR2(50);
  v_pid     VARCHAR2(10);
  v_sid     NUMBER;
  v_program VARCHAR2(48);
BEGIN
  IF (ora_is_servererror(1017)) THEN
    -- get ip FOR remote connections :
    IF upper(sys_context('userenv', 'network_protocol')) = 'TCP' THEN
      ip := sys_context('userenv', 'ip_address');
    END IF;
    SELECT sid INTO v_sid FROM sys.v_$mystat WHERE rownum < 2;
    SELECT p.spid, v.program
      INTO v_pid, v_program
      FROM v$process p, v$session v
     WHERE p.addr = v.paddr
       AND v.sid = v_sid;
    v_os_user := sys_context('userenv', 'os_user');
    dbms_application_info.read_module(v_module, v_action);
    message := to_char(SYSDATE, 'YYYY-MM-DD HH24:MI:SS') ||
               ' Password Erro: logon denied from ' || nvl(ip, 'localhost') || ' ' ||
               v_pid || ' User:' || v_os_user || ' with ' || v_program || '    ' ||
               v_module || ' ' || v_action||' dbuser:'||USER;
    sys.dbms_system.ksdwrt(2, message);
  END IF;
END;

参考来源

https://www.modb.pro/db/25539