添加个性化自定义资源管理器图标

我们的电脑日常安装了不少的各种各样的软件，你会发现打开我电脑，与C，D，E盘并列的还有什么【迅雷】，【百度网盘】等这种图标存在，入下图：

 

 

 

这种图标有的提供了删除，有的没有提供删除按钮，这种图标是如何创建的呢？

当你知道如何创建这些图标的时候，你也就知道如何删除这些图标了，简而言之，这些图标是这样来的

1、在HKEY_CLASSES_ROOT\CLSID\下创建一个CLSID

2、将这个CLSID显示在NameSpace下。

多的不赘述，下面直接上上图的批处理代码，自己看过程和原理。

@echo off
:Start
echo 请选择要操作的方式【1为新建项目；2为删除项目；3为添加子菜单】
echo 如果要删除项目，你需要输入之前新建项目的CLSID号。
set /p Choices=

if %Choices%==1 goto AddIcon
if %Choices%==2 goto DeleteIcon
if %Choices%==3 goto SubCommand
goto Start


:AddIcon
echo 请输入CLSID号（10-99）
set /p CLSID=
echo 请输入显示名称：
set /p Display=
echo 请输入指令：
set /p sCommand=
echo 请输入显示图标程序名称：
set /p DisIcon=
echo 请输入打开菜单名称：
set /p sOpen=


reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%} /ve /d %Display% /f >nul
reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\defaulticon /ve /d "%DisIcon%" /f >nul
reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\Shell\%sOpen% /ve /d %sOpen% /f >nul 
reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\Shell\%sOpen%\Command /ve /d "%sCommand%" /f >nul 
reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\shellfolder /v Attributes /t REG_DWORD /d 0 /f >nul
reg add HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\{00000000-0000-0000-0000-0000000000%CLSID%} /f >nul
cls
goto Start 

:SubCommand
echo 请输入要操作的CLSID：
set /p CLSID=
echo 请输入打开菜单名称：
set /p sOpen=
echo 请输入指令：
set /p sCommand=

reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\Shell\%sOpen% /ve /d %sOpen% /f >nul 
reg add HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%}\Shell\%sOpen%\Command /ve /d "%sCommand%" /f >nul 
cls
goto Start 

:DeleteIcon

echo 请输入CLSID数（10-99）
set /p CLSID=

reg delete HKEY_CLASSES_ROOT\CLSID\{00000000-0000-0000-0000-0000000000%CLSID%} /f >nul
reg delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\{00000000-0000-0000-0000-0000000000%CLSID%} /f >nul
cls
goto Start