格子游戏

Problem Description

Alice和Bob玩了一个古老的游戏：首先画一个n*n的点阵，接着他们两个轮流在相邻的点之间画上虚边和粗边，直到围成一个封闭的圈（面积不必为1）为止，“封圈”的那个人就是赢家。因为棋盘实在是太大了（n<=200），他们的游戏实在是长了！他们甚至在游戏中都不知道谁赢得了游戏。于是请你写一个程序，帮助他们计算他们是否结束了游戏？

Input

每组输入数据第一行为两个整数n和m。m表示一共画了m条线。以后m行，每行首先有两个数字（x,y），代表了画线的起点坐标，接着用空格隔开一个字符，假如字符是“D”，则是向下连一条边，如果是“R”就是向右连一条边。输入数据不会有重复的边且保证正确。

Output

对于每组数据，输出一行：在第几步的时候结束。假如m步之后也没有结束，则输出一行“draw”。

Sample Input

3 5
1 1 D
1 1 R
1 2 D
2 1 R 
2 2 D

Sample Output

4

 

 思路

因为读入的边的两个端点a和b在同一个集合，那么就说明连起来一个圈了，

因为已知find(a)到a有边，find(b)到b有边，那么如果find(a)=find(b),就是一个封闭的圈了

二维变一维简单的维度转换然后就是relation的裸题了，

注意维度转换和初始化以及没有结束的情况记得输出，没啦。

 

 

program game;
const
  inf='game.in';
  outf='game.out';
var
  father:array[0..40000] of longint;
  i,n,m,a,b,t1,t2:longint;
  cz:char;

function find(apple:longint):longint;
begin
  if father[apple]<>apple then father[apple]:=find(father[apple]);
  exit(father[apple]);
end;

procedure union(aa,bb:longint);
begin
  father[bb]:=aa;
end;

procedure outgo();
begin
  writeln(i);
  close(input);
  close(output);
  halt;
end;

begin
  assign(input,inf);
  assign(output,outf);
  reset(input); rewrite(output);

  readln(n,m);
  for i:= 1 to n*n do
    father[i]:=i;   //init;

  for i:= 1 to m do
   begin
    read(a,b);
    a:=n*(a-1)+b;
    read(cz); readln(cz);
    if cz='R'then b:=a+1
      else b:=a+n;
    t1:=find(a);
    t2:=find(b);
    if t1<>t2 then union(t1,t2)
      else outgo;
   end;

  writeln('draw');
  close(input);
  close(output);
end.