操作系统真相还原 第二章 编写MBR主引导记录
第二章 编写MBR主引导记录
8086启动的整体流程
- 启动计算机，寄存器被初始化
CS:FFFF,IP:0000;CS：FFFF，其它的寄存器：00 00。 - FFFF0—> jmp F000：005C
CS：F000 IP：005C;内存中最顶端的ROM（Read-Only Memory，只读存储器）中固化有我们的BIOS,上电后CPU就会执行地址为0xFFFF0处的代码，但是我们可以这里距离顶端只有16个字节，所以可执行的代码是非常有限的。所以，这个地址处存放的是一条跳转指令jmp F000:005C. - F005C—>依次执行BIOS中的指令,做一些硬件的检测工作.
- BIOS所做的最后一件事：将主引导扇区中（0面0道1扇区，最后两个字节为硬盘主引导扇区的有效标志，必须为0x55，0xaa）的内容加载到7C00的位置处。
- BIOS的最后一条指令：JMP 0000：7C00
CS：0000 IP：7C00 - 07C00—>执行主引导扇区中的指令
1)加载操作系统自举代码到内存中
2)通过一条跳转指令，使处理器去执行操作系统的自举代码
简单来说就是bios做自检，然后跳转执行磁盘中主引导扇区中的指令。主引导扇区中指令才是操作系统。
主引导程序
mbr.S代码
;主引导程序
;------------------------------------------------------------
SECTION MBR vstart=0x7c00
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00
; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10 功能号:0x06 功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
mov ax, 0x600
mov bx, 0x700
mov cx, 0 ; 左上角: (0, 0)
mov dx, 0x184f ; 右下角: (80,25),
; VGA文本模式中,一行只能容纳80个字符,共25行。
; 下标从0开始,所以0x18=24,0x4f=79
int 0x10 ; int 0x10
;;;;;;;;; 下面这三行代码是获取光标位置 ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符.
mov ah, 3 ; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
mov bh, 0 ; bh寄存器存储的是待获取光标的页号
int 0x10 ; 输出: ch=光标开始行,cl=光标结束行
; dh=光标所在行号,dl=光标所在列号
;;;;;;;;; 获取光标位置结束 ;;;;;;;;;;;;;;;;
;;;;;;;;; 打印字符串 ;;;;;;;;;;;
;还是用10h中断,不过这次是调用13号子功能打印字符串
mov ax, message
mov bp, ax ; es:bp 为串首地址, es此时同cs一致，
; 开头时已经为sreg初始化
; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
mov cx, 5 ; cx 为串长度,不包括结束符0的字符个数
mov ax, 0x1301 ; 子功能号13是显示字符及属性,要存入ah寄存器,
; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
mov bx, 0x2 ; bh存储要显示的页号,此处是第0页,
; bl中是字符属性, 属性黑底绿字(bl = 02h)
int 0x10 ; 执行BIOS 0x10 号中断
;;;;;;;;; 打字字符串结束 ;;;;;;;;;;;;;;;
jmp $ ; 使程序悬停在此
message db "1 MBR"
times 510-($-$$) db 0
db 0x55,0xaa
编译,生成的mbr.bin大小为512字节
nasm -o mbr.bin mbr.S
将编译后指令写入将主引导扇区中，即0面0道1扇区。
dd：磁盘操作命令，以块为单位操作。
if，要读取的文件。
of，要写入的文件。
bs=512，块的大小。
count=1，只操作一个块。
dd if=/your_path/mbr.bin of=/your_path/hd60M.img bs=512 count=1 conv=notrunc
进入bochs安装目录
bin/bochs -f bochsrc.disk
回车后，输入c继续运行，显示结果如下图：
