unity中Shader实现地形中根据实际高度绘制等高线，剖切功能，颜色渐变等功能

问题背景

在做地形模块时，需要根据实际地形高度画出世界相应的等高线，以及根据高度做颜色渐变，以及剖切功能。

解决方法

通过像素点在世界坐标系下的真实高度值来判断计算绘制等高线，剖切功能以及颜色渐变均有世界坐标实际高度值来判断，具体逻辑在代码中，这些均 在shder 中为的fragment阶段进行，

Shader代码

Shader "Custom/StratumFrontShader" {
    Properties{
        _FristColir("MainColor", color) = (0,1,0,1)           //第一种颜色：绿
        _SecondColor("SecondColor", color) = (1,0,0,1)       //第二种颜色：红
        _Diffuse("Diffuse", Color) = (1,1,1,1)

        _K("K", float) = 0.8
        _P("P", float) = 0.8
    }
    SubShader {
        pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "unitycg.cginc"
            #include "Lighting.cginc"

            fixed4 _Diffuse;
            uniform half _K;
            uniform half _P;

            //高低点颜色
            fixed4 _FristColir;
            fixed4 _SecondColor;
            
            //高低点值
            float _HighValue;
            float _LowValue;
             
            //是否显示等高线
            float _IsShowContour=0;

            //等高线密集比例
            float _ContourScale=0.12;

            //是否是同一颜色
            float _IsSameColor=0;

             //是否开启剖切
             float clipping;
             float3 clipPlanePosition;
             float3 clipPlaneNormal;


            struct v2f {
                float4 pos:POSITION;
                float y : TEXCOORD1;
                fixed3 worldNormal: TEXCOORD2;
                fixed3 worldPos: TEXCOORD3;
            };

            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                o.y = v.vertex.y;
                return o;
            }
            fixed4 frag(v2f IN):COLOR
            {
               float y = IN.y;
    
             //剖切逻辑
              if ( clipping > 0.0 ) {
                float  r = dot( normalize( IN.worldPos - clipPlanePosition ), clipPlaneNormal );
                 if ( r > 0.0 ) {
                    discard;
                 }
               }

               //等高线
               float f = abs( frac( y * _ContourScale ) - 0.5 );  
               float df = fwidth( y * _ContourScale );             
               float g = smoothstep( -df * 2, df * 2, f );
               float3 lineCol = float3( 0.0, 0.0, 0.0 );

               //颜色随高度渐变
               float h=saturate((_HighValue-y)/(_HighValue-_LowValue));
               h = _IsSameColor == 0 ? h : 0;//同一种颜色时为第一默认色
               fixed3 col = lerp( _FristColir, _SecondColor, h );
               g = _IsShowContour == 0 ? g : 1;
               col = lerp( lineCol, col, g );

               //光照
               float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
               float lightDot = clamp(dot(IN.worldNormal, worldLightDir), -1, 1);
               lightDot = exp(-pow(_K* (1 - lightDot), _P));
               float3 diffuse = _LightColor0.rgb * col * lightDot;
               fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
               fixed3 color0=ambient + diffuse;

              return (fixed4(color0,1));
            }
            ENDCG
        }
    }
}

ps：剖切功能：在于实际坐标点与剖切面的夹角选择性剔除。渐变功能：根据高度区间变换做的混合，等高线：高度值根据设定参数计算，插值出等高线。

这里是我功能源代码，这里做了剖切和颜色渐变和光照，提供给大家做个参考吧。

效果如下：