flash+XML 做的图片浏览器

 //-------------------------------------
//         flash XML Jpg Viewer
//      bg WhiteCrow in 2005-04-11
//-------------------------------------
//初始化部分
var myXML = new XML ();
var myArray = new Array ();
//初始化参数设置
var smallPicWidth = 50;
var smallPicHeight = 50;
var bigPicWidth = 610;
var bigPicHeight = 440;
myXML.ignoreWhite = true;
//初始化函数设置
myXML.onLoad = function (ok)
{
    if (ok)
    {
        _global.scrollSpeed = myXML.firstChild.attributes.scrollSpeed;
        albumText = myXML.firstChild.attributes.albumText;
        _global.gap = myXML.firstChild.attributes.gap;
        praseXML ();
    }
}
//函数设置
function praseXML ()
{
    for (var i = 0; i < myXML.firstChild.childNodes.length; i ++)
    {
        var tempObj = myXML.firstChild.childNodes [i].attributes;
        myArray.push (
        {
            linkURL : tempObj.linkURL,
            imgURL : tempObj.imgURL,
            imgText : tempObj.imgText
        })
    }
    drawLeft ();
}
function drawLeft ()
{
    for (var i = 0; i < myArray.length; i ++)
    {
        var picLoaderTemp = leftBar.createEmptyMovieClip ("picLoader" + i, i + 1);
        var picCounterTemp = leftBar.createEmptyMovieClip ("picCounter" + i, i + 10001);
        picCounterTemp.id = i;
        picLoaderTemp._x = 10;
        picLoaderTemp._y = smallPicHeight * i + _global.gap * i + 10;
        picLoaderTemp.loadMovie (myArray [i].imgURL);
        picCounterTemp.onEnterFrame = function ()
        {
            var tempName = leftBar ["picLoader" + this.id];
            if (tempName._width > 0)
            {
var tempScale = Math.min (smallPicWidth/tempName._width, smallPicHeight/tempName._height)
                tempName._width = tempScale * tempName._width
                tempName._height = tempScale * tempName._height;
                tempName.onPress = function ()
                {
                    var tempNum = this._name.slice (9);
                    textArea.contentText.text = myArray [tempNum].imgText;
                    drawRight (myArray [tempNum].imgURL);
                }
                delete this.onEnterFrame;
            }
        }
    }
}
function drawRight (a)
{
    picLoader.loadMovie (a);
    var picCounter = this.createEmptyMovieClip ("picCounter", 60000);
    picCounter.onEnterFrame = function ()
    {
        if (picLoader._width > 0)
        {
var tempScale = Math.min (bigPicWidth/picLoader._width , bigPicHeight/picLoader._height);
            picLoader._width = tempScale * picLoader._width;
            picLoader._height = tempScale * picLoader._height;
            picLoader._x = (bigPicWidth+20 - picLoader._width) / 2 + smallPicWidth+20;
            picLoader._y = (bigPicHeight - picLoader._height) / 2+35;
            picLoader.onPress = function ()
            {
                getURL (a, "_blank");
            }
            delete picCounter.onEnterFrame;
        }
    }
}
leftBar.onEnterFrame = function ()
{
    if (_xmouse < smallPicWidth+20)
    {
        leftBar._y -= (_ymouse - Stage.height/ 2)/10;
        if (leftBar._y > 0)
        {
            leftBar._y = 0;
        } else if (leftBar._y <= Stage.height - leftBar._height-20)
        {
            leftBar._y = Stage.height - leftBar._height-20;
        }
    }
}
//开始执行函数
myXML.load ("pics.xml");