VGA显示测试模块

　　VGA(Video Graphics Array)是IBM在1987年随PS/2机一起推出的一种视频传输标准，具有分辨率高、显示速率快、颜色丰富等优点，在彩色显示器领域得到了广泛的应用。不支持热插拔，不支持音频传输。它传输红、绿、蓝模拟信号以及同步信号(水平和垂直信号)。随着显示技术的快速发展，VGA接口显示器逐渐被其他更好的接口所替代，当前使用最广泛的显示接口有HDMI和DP，这两种接口已经成为了主流接口。

　　VGA接口虽然逐渐退出了舞台，但是做为图像处理的入门是再好不过的。

　　VGA时序：

　　一行数据包 括： Hor Sync（ 行同步） 、 Hor Back Porch（ 行消隐） 、 Hor Active Video（ 行视频有效） 和 Hor Front Porch（ 行前肩） ； 一场数据包括： Ver Sync（ 场同步） 、 Ver Back Porch（ 场 消隐） 、 Ver Active Video（ 场视频有效） 和 Ver Front Porch（ 场前肩） 。而实际显示的画面为Hor Active Video（ 行视频有效）与Ver Active Video（ 场视频有效）围成的部分即上图中的最小矩形Addressable Video。

VGA 常用分辨率时序参数 ：

　　时钟频率=行最大值 * 列最大值* 扫描频率。例如：800 * 525 * 60 = 25,200,000 ≈ 25.175MHz （误差忽略不计）。

 　　VGA_test_gen.v

//**************************************************************************
// *** file name      : VGA_test_gen.v
// *** version        : 1.0
// *** Description    : VGA_test_gen
// *** Blogs          : https://www.cnblogs.com/WenGalois123/
// *** Author         : Galois_V
// *** Date           : 2022.5.15
// *** Changes        : Initial
//**************************************************************************
`timescale  1ns/1ps 
module VGA_test_gen
(
    input                        i_pixel_clk     ,
    input                        i_sys_rstn      ,
    
    input                        i_ctrl_key      ,
    output           [7:0]       o_VGA_red       ,
    output           [7:0]       o_VGA_green     ,
    output           [7:0]       o_VGA_blue      ,
    output    reg                o_VGA_hs        ,
    output    reg                o_VGA_vs        ,
    output                       o_VGA_de        ,
    output    reg    [3:0]       o_mode    
);

    wire                         w_cnt_x_end    ;
    wire                         w_cnt_y_end    ;
    reg            [11:0]        r_cnt_x        ;
    reg            [11:0]        r_cnt_y        ;
    reg                          r_hs_de        ;
    reg                          r_vs_de        ;
    reg            [7:0]         r_grid_small   ;
    reg            [7:0]         r_grid_big     ;
    reg            [23:0]        r_color_bar    ;
    reg            [19:0]        r_key_cnt      ;
    reg            [7:0]         r_VGA_blue     ;
    reg            [7:0]         r_VGA_green    ;
    reg            [7:0]         r_VGA_red      ;
    
/******************************************************************************\
水平扫描参数的设定640*480  60HZ
\******************************************************************************/
    localparam H_Total        =    800    ;
    localparam H_Sync         =    96     ;
    localparam H_Back         =    48     ;
    localparam H_Active       =    640    ;
    localparam H_Front        =    16     ;
    localparam H_Start        =    144    ; //H_Start = H_Sync + H_Back
    localparam H_End          =    784    ; //H_End = H_Total - H_Front
/******************************************************************************\
垂直扫描参数的设定640*480    60HZ  
\******************************************************************************/    
    localparam V_Total        =    525    ;
    localparam V_Sync         =    2      ;
    localparam V_Back         =    33     ;
    localparam V_Active       =    480    ;
    localparam V_Front        =    10     ;
    localparam V_Start        =    35     ; //V_Start = V_Sync + V_Back 
    localparam V_End          =    515    ; //V_End = V_Total - V_Front 
/******************************************************************************\
水平扫描参数的设定1280*720  60HZ
\******************************************************************************/
    // localparam H_Total        =    1650   ;
    // localparam H_Sync         =    40     ;
    // localparam H_Back         =    220    ;
    // localparam H_Active       =    1280   ;
    // localparam H_Front        =    110    ;
    // localparam H_Start        =    260    ;
    // localparam H_End          =    1540   ;
/******************************************************************************\
垂直扫描参数的设定1280*720    60HZ 
\******************************************************************************/
    // localparam V_Total        =    750    ;
    // localparam V_Sync         =    5      ;
    // localparam V_Back         =    20     ;
    // localparam V_Active       =    720    ;
    // localparam V_Front        =    5      ;
    // localparam V_Start        =    25     ;
    // localparam V_End          =    745    ;

    localparam H_STEP         =    H_Active >> 3;

/******************************************************************************\
像素计数
\******************************************************************************/    
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn | w_cnt_x_end)
        begin
            r_cnt_x <= 'd0;
        end
        else
        begin
            r_cnt_x <= r_cnt_x + 1'b1;
        end
    end
    assign w_cnt_x_end = r_cnt_x == (H_Total - 1'b1);
    
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn | w_cnt_y_end)
        begin
            r_cnt_y <= 'd0;
        end
        else if(w_cnt_x_end)
        begin
            r_cnt_y <= r_cnt_y + 1'b1;
        end
    end
    assign w_cnt_y_end = r_cnt_y == V_Total;
/******************************************************************************\
行场同步信号产生
\******************************************************************************/
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn)
        begin
            o_VGA_hs <= 'd0;
        end
        else if(r_cnt_x == 0)
        begin
            o_VGA_hs <= 1'b1;
        end
        else if(r_cnt_x == H_Sync)
        begin
            o_VGA_hs <= 'd0;
        end
    end
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn)
        begin
            r_hs_de <= 'd0;
        end
        else if(r_cnt_x == H_Start)
        begin
            r_hs_de <= 1'b1;
        end
        else if(r_cnt_x == H_End)
        begin
            r_hs_de <= 'd0;
        end
    end
    
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn)
        begin
            o_VGA_vs <= 'd0;
        end
        else if(r_cnt_y == 0)
        begin
            o_VGA_vs <= 1'b1;
        end
        else if(r_cnt_y == V_Sync)
        begin
            o_VGA_vs <= 'd0;
        end
    end
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn)
        begin
            r_vs_de <= 'd0;
        end
        else if(r_cnt_y == V_Start)
        begin
            r_vs_de <= 1'b1;
        end
        else if(r_cnt_y == V_End)
        begin
            r_vs_de <= 'd0;
        end
    end
/******************************************************************************\
图像切换
\******************************************************************************/
    always@(posedge i_pixel_clk)
    begin
        if(i_ctrl_key == 'd0)
        begin
            r_key_cnt  <= 'd0;
        end
        else if((i_ctrl_key == 1) & (r_key_cnt <= 1_000_000))
        begin
            r_key_cnt  <= r_key_cnt + 1'b1;
        end
        if(r_key_cnt == 1_000_000)
        begin
            if(o_mode == 12)
            begin
                o_mode <= 'd0;
            end
            else
            begin
                o_mode <= o_mode + 1'b1;
            end
        end
    end
/******************************************************************************\
格子图像
\******************************************************************************/
    always@(posedge i_pixel_clk)
    begin
        if(r_cnt_x[4] ^ r_cnt_y[4])
        begin
            r_grid_small <= 'd0;
        end
        else
        begin
            r_grid_small <= 8'hff;
        end
    end
    
    always@(posedge i_pixel_clk)
    begin
        if(r_cnt_x[6] ^ r_cnt_y[6])
        begin
            r_grid_big <= 'd0;
        end
        else
        begin
            r_grid_big <= 8'hff;
        end
    end
/******************************************************************************\
竖彩条图像
\******************************************************************************/
    always@(posedge i_pixel_clk)
    begin
        if(r_cnt_x == H_Start)
        begin
            r_color_bar <= 24'hff_00_00;
        end
        else if(r_cnt_x == H_Start + H_STEP)
        begin
            r_color_bar <= 24'h00_ff_00;
        end
        else if(r_cnt_x == H_Start + H_STEP*2)
        begin
            r_color_bar <= 24'h00_00_ff;
        end
        else if(r_cnt_x == H_Start + H_STEP*3)
        begin
            r_color_bar <= 24'hff_00_ff;
        end
        else if(r_cnt_x == H_Start + H_STEP*4)
        begin
            r_color_bar <= 24'hff_ff_00;
        end
        else if(r_cnt_x == H_Start + H_STEP*5)
        begin
            r_color_bar <= 24'h00_ff_ff;
        end
        else if(r_cnt_x == H_Start + H_STEP*6)
        begin
            r_color_bar <= 24'hff_ff_ff;
        end
        else if(r_cnt_x == H_Start + H_STEP*7)
        begin
            r_color_bar <= 24'h00_00_00;
        end
        else
        begin
            r_color_bar <= r_color_bar;
        end
    end
/******************************************************************************\
各模式图像显示
\******************************************************************************/
    always@(posedge i_pixel_clk)
    begin
        if(~i_sys_rstn)
        begin
            {r_VGA_red,r_VGA_green,r_VGA_blue} <= 'd0;
        end
        else
        case(o_mode)
            4'd0:begin                        //全黑
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= 'd0;
                end
            4'd1:begin                        //全白
                    r_VGA_red      <= 8'hff;
                    r_VGA_green    <= 8'hff;
                    r_VGA_blue     <= 8'hff;
                end
            4'd2:begin                        //全红
                    r_VGA_red      <= 8'hff;
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= 'd0;
                end
            4'd3:begin                        //全绿
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= 'hff;
                    r_VGA_blue     <= 'd0;
                end
            4'd4:begin                        //全蓝
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= 'hff;
                end
            4'd5:begin                        //小方格
                    r_VGA_red      <= r_grid_small;
                    r_VGA_green    <= r_grid_small;
                    r_VGA_blue     <= r_grid_small;
                end
            4'd6:begin                        //大方格
                    r_VGA_red      <= r_grid_big;
                    r_VGA_green    <= r_grid_big;
                    r_VGA_blue     <= r_grid_big;
                end
            4'd7:begin                        //水平白渐变
                    r_VGA_red      <= r_cnt_x[7:0];
                    r_VGA_green    <= r_cnt_x[7:0];
                    r_VGA_blue     <= r_cnt_x[7:0];
                end
            4'd8:begin                        //垂直白渐变
                    r_VGA_red      <= r_cnt_y[8:1];
                    r_VGA_green    <= r_cnt_y[8:1];
                    r_VGA_blue     <= r_cnt_y[8:1];
                end
            4'd9:begin                        //水平红渐变
                    r_VGA_red      <= r_cnt_x[7:0];
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= 'd0;
                end
            4'd10:begin                        //水平绿渐变
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= r_cnt_x[7:0];
                    r_VGA_blue     <= 'd0;
                end
            4'd11:begin                        //水平蓝渐变
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= r_cnt_x[7:0];
                end
            4'd12:begin                        //竖彩条
                    r_VGA_red      <= r_color_bar[23:16];
                    r_VGA_green    <= r_color_bar[15:8];
                    r_VGA_blue     <= r_color_bar[7:0];
                end
            default:begin                    //全黑
                    r_VGA_red      <= 'd0;
                    r_VGA_green    <= 'd0;
                    r_VGA_blue     <= 'd0;
                end
        endcase
    end
/******************************************************************************\
输出
\******************************************************************************/
    assign o_VGA_de     = r_hs_de & r_vs_de;
    assign o_VGA_red    = (r_hs_de & r_vs_de) ? r_VGA_red : 'd0;
    assign o_VGA_green  = (r_hs_de & r_vs_de) ? r_VGA_green : 'd0;
    assign o_VGA_blue   = (r_hs_de & r_vs_de) ? r_VGA_blue : 'd0;
    
endmodule

　　如图为彩条模式：

 

　　实验成功。