ABAP-ALV监听修改事件程序例子

REPORT y4_b4_test4.

TABLES:mara .

TYPES:BEGIN OF ty_data,
        checkbox TYPE char1,
        style    TYPE   lvc_t_styl,
        num      TYPE i.
        INCLUDE TYPE mara.
TYPES: END OF ty_data.

DATA:gt_data TYPE TABLE OF ty_data,
     gs_data TYPE ty_data.

DATA:gt_fieldcat TYPE lvc_t_fcat, "字段目录
     gs_fieldcat TYPE lvc_s_fcat,  "字段目录
     gs_layout   TYPE lvc_s_layo.  "布局结构

************************************************事件定义

DATA: ls_edit TYPE lvc_s_styl.

DATA:gt_event   TYPE slis_t_event,
     gs_event   LIKE LINE OF gt_event,
     gs_variant TYPE disvariant.                                    "格式

DATA: gv_grid TYPE REF TO cl_gui_alv_grid.

CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    METHODS:
      handle_data_changed FOR EVENT data_changed_finished OF cl_gui_alv_grid
        IMPORTING e_modified et_good_cells.
ENDCLASS.

CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_data_changed.
    PERFORM frm_data_changed USING et_good_cells.
  ENDMETHOD.
ENDCLASS.

DATA: gv_event_receiver TYPE REF TO lcl_event_receiver.

FIELD-SYMBOLS: <fs_data>  LIKE gs_data,
               <fs_event> TYPE ty_data.

***************************************************************

SELECTION-SCREEN BEGIN OF BLOCK bk1 WITH FRAME TITLE TEXT-001.

  SELECT-OPTIONS s_matnr FOR mara-matnr .  "物料

SELECTION-SCREEN END OF BLOCK bk1.

START-OF-SELECTION.
  PERFORM frm_layout.
  PERFORM frm_set_event."监听事件
  PERFORM frm_fieldcat CHANGING gt_fieldcat .    "获取字段
  PERFORM frm_getdata.

END-OF-SELECTION.
  PERFORM frm_display.

FORM frm_getdata .

  SELECT *
    INTO CORRESPONDING FIELDS OF TABLE gt_data
    FROM mara
    WHERE matnr IN s_matnr .

ENDFORM .

FORM frm_num .

  IF <fs_event>-num > 20 .

    <fs_event>-checkbox = 'X' .

  ELSE .

    <fs_event>-checkbox = '' .

  ENDIF .

  IF <fs_event>-num = 10 .

    CLEAR ls_edit.
    ls_edit-fieldname = 'CHECKBOX'.
    ls_edit-style = cl_gui_alv_grid=>mc_style_disabled.
    INSERT ls_edit INTO TABLE <fs_event>-style.

  ELSEIF <fs_event>-num = 20 .

    CLEAR <fs_event>-style .

  ENDIF .

ENDFORM .

FORM frm_data_changed USING et_good_cells TYPE lvc_t_modi.

  DATA: ls_mod_data TYPE lvc_s_modi.
  DATA: stbl1 TYPE lvc_s_stbl.
  LOOP AT et_good_cells INTO ls_mod_data.
    READ TABLE gt_data ASSIGNING <fs_event> INDEX ls_mod_data-row_id.
    CASE ls_mod_data-fieldname.
      WHEN 'NUM'.
        PERFORM frm_num .
    ENDCASE.

    stbl1-row = 'X'.
    stbl1-col = 'X'.
    CALL METHOD gv_grid->refresh_table_display
      EXPORTING
        is_stable = stbl1.

  ENDLOOP.

ENDFORM.

FORM frm_set_event.

  gs_event-name = 'CALLER_EXIT'.
  gs_event-form = 'FRM_BUTTON'.
  APPEND gs_event TO gt_event.

ENDFORM.

FORM frm_button USING e_grid TYPE slis_data_caller_exit .

  CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
    IMPORTING
      e_grid = gv_grid.
  CALL METHOD gv_grid->set_ready_for_input
    EXPORTING
      i_ready_for_input = 1.
  CALL METHOD gv_grid->check_changed_data.
  "光标移动事件
  CALL METHOD gv_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_modified
    EXCEPTIONS
      error      = 1
      OTHERS     = 2.
  "设置ENTER事件
  CALL METHOD gv_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_enter
    EXCEPTIONS
      error      = 1
      OTHERS     = 2.
  "数据修改事件
  CREATE OBJECT gv_event_receiver.
  SET HANDLER gv_event_receiver->handle_data_changed FOR gv_grid.

ENDFORM.

FORM frm_layout.

  CLEAR gs_layout.
  gs_layout-zebra      = 'X'.     "斑马线显示
  gs_layout-cwidth_opt = 'X'.     "自适应宽度
  gs_layout-sel_mode   = 'A'.     "选择模式:多选/单选
  gs_layout-stylefname = 'STYLE'.

ENDFORM.

FORM frm_display.
  gs_variant-report = sy-repid.
  gs_variant-handle = 1.
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC' "调用函数
    EXPORTING
      i_callback_program       = sy-repid
      is_layout_lvc            = gs_layout "布局
      it_fieldcat_lvc          = gt_fieldcat "字段
*      i_callback_pf_status_set = 'SET_PF_STATUS' "按钮
*      i_callback_user_command  = 'ALV_USER_COMMAND' "按钮事件
      i_save                   = 'A'
      it_events                = gt_event
      is_variant               = gs_variant
    TABLES
      t_outtab                 = gt_data "数据
    EXCEPTIONS "抛出异常
      program_error            = 1
      OTHERS                   = 2.
ENDFORM.

FORM frm_fieldcat CHANGING VALUE(ot_fieldcat) TYPE lvc_t_fcat.

  DATA:l_pos       TYPE i VALUE 2,
       ls_fieldcat TYPE lvc_s_fcat.
  DEFINE alv_append_field.
    CLEAR ls_fieldcat.
    ls_fieldcat-col_pos = l_pos.
    ls_fieldcat-fieldname = &1 .
    ls_fieldcat-reptext = &2 .
    ls_fieldcat-no_zero = &3.
    ls_fieldcat-key = &4 .        "状态灯
    ls_fieldcat-scrtext_l = &2.
    ls_fieldcat-scrtext_m = &2.
    ls_fieldcat-scrtext_s = &2.
    ls_fieldcat-edit = &5.
    ls_fieldcat-ref_table = &6.
    ls_fieldcat-ref_field = &7.
    ls_fieldcat-outputlen = &8 .
    APPEND ls_fieldcat TO ot_fieldcat.
    l_pos = l_pos + 1 .
  END-OF-DEFINITION.
  REFRESH ot_fieldcat.

  CLEAR gs_fieldcat.
  ls_fieldcat-fieldname = 'CHECKBOX'."多选框字段名
  ls_fieldcat-reptext = '选项'."文本
  ls_fieldcat-edit      = 'X'."能够修改
  ls_fieldcat-checkbox  = 'X'. "多选框
  ls_fieldcat-intlen = 1.
  APPEND ls_fieldcat TO ot_fieldcat.

  alv_append_field 'NUM' '状态' 'X' '' 'X' '' '' ''.
  alv_append_field 'MATNR' '物料' 'X' '' '' '' '' ''.
  alv_append_field 'MTART' '物料类型' 'X' '' '' '' '' ''.
  alv_append_field 'MBRSH' '行业领域' 'X' '' '' '' '' ''.
  alv_append_field 'MATKL' '物料组' 'X' '' '' '' '' ''.

ENDFORM.