Esp8266连接阿里云MQTT服务器（arduino编译器）

前提条件：

arduino开发环境已搭建

阿里云MQTT服务器已搭建

（搭建方法请参考博客内其他文章）

先放行服务器1883端口，MQTT服务器端口为：1883

输入你的服务器ip:18083，打开MQTT控制面板

点击工具Websocket,如图所示点击连接，提示连接成功

页面下拉找到订阅，输入主题： /test/onoff/，点击订阅，如图所示

下拉找到消息，主题同样输入： /test/onoff/

上烧录的代码，打开arduino软件，复制如下代码：

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
int deng = 14;  //IO14(D5)
const char* ssid = "路由器WiFi账号";
const char* password = "路由器WiFi密码";
const char* mqtt_server = "IP地址"; // 使用HIVEMQ 的信息中转服务
const char* TOPIC = "/test/onoff/";                     // 订阅信息主题
const char* client_id = "ID";                   // 标识当前设备的客户端编号，随便填

WiFiClient espClient;                                                         // 定义wifiClient实例
PubSubClient client(espClient);                                         // 定义PubSubClient的实例
long lastMsg = 0;                                                               // 记录上一次发送信息的时长

void setup() {
  pinMode(deng, OUTPUT);                               // 定义板载LED灯为输出方式
  Serial.begin(115200); 
  setup_wifi();                                                                    //执行Wifi初始化，下文有具体描述
  client.setServer(mqtt_server, 1883);                              //设定MQTT服务器与使用的端口，1883是默认的MQTT端口
  client.setCallback(callback);                                          //设定回调方式，当ESP8266收到订阅消息时会调用此方法
}

void setup_wifi() {

  delay(10);
  // 板子通电后要启动，稍微等待一下让板子点亮
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);   // 打印主题信息
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]); // 打印主题内容
  }
  Serial.println();

  if ((char)payload[0] == '1') {
    digitalWrite(deng, HIGH);   // 亮灯
  } else {
    digitalWrite(deng, LOW);   // 熄灯
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(client_id)) {
      Serial.println("connected");
      // 连接成功时订阅主题
      client.subscribe(TOPIC);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    client.publish("/test/onoff/", "{device:client_id,'status':'on'}");
  }
}

PubSubClient库的安装方法：
点击工具打开库管理面板，在搜索栏输入：PubSubClient
点击安装，如图所示


注意修改代码中的WiFi账号与密码及ip地址，设备的客户端编号ID
插上Esp8266开发板点击向右的箭头开始编译烧录，等待编译成功 100%
烧录成功后点击arduino软件右上角串口监视器查看连接状态
MQTT控制面板消息中消息输入1，点击右侧发送则会出现如下图所示，Esp8266连接MQTT服务器成功



开发板接线图：左侧D5，右侧GND

MQTT服务器发送消息 1，则灯点亮，发送 0 则熄灭

参考博客：MQTT之 PubSubClient 库 https://www.jianshu.com/p/7f54b92d7a7b