昨天整理照片时发现，选择察看-缩略图，却不能看到缩略的小图，在找照片时显得特别麻烦，得用acdsee一张张浏览，再记下该照片的名称，然后再选择。我清楚地记得，前一阵子完全可以看到缩略图的，杀了一遍毒也不见有问题。这段时间内我下载了一些其它软件，莫非有冲突？还是windows的问题？或是acd的问题？

我先卸载了acd，重启电脑，毛病依旧。在文件夹里改了几个选项，还是不行。最后在网上搜索，终于解决了问题。方法如下：把以下代码复制到记事本：

'RepairImage.vbs
'Start of Image Preview Repair
'This section repairs the associations for Image Preview

Option Explicit

'Declare variables
Dim WSHShell, p1, p2, p3
Set WSHShell = WScript.CreateObject("WScript.Shell")
p2 = "\ShellEx\{BB2E617C-0920-11d1-9A0B-00C04FC2D6C1}\"
p3 = "{7376D660-C583-11d0-A3A5-00C04FD706EC}"

For Each p1 in Array(".art",".bmp",".dib",".gif",".jfif",".jpe",".jpeg",".jpg",".png",".wmf")
  WSHShell.RegWrite "HKCR\" & p1 & p2, p3
Next

p1 = ".tif"
p3 = "{1AEB1360-5AFC-11d0-B806-00C04FD706EC}"
WSHShell.RegWrite "HKCR\" & p1 & p2, p3
p1 = ".tiff"
WSHShell.RegWrite "HKCR\" & p1 & p2, p3
p1 = ".htm"
p3 = "{EAB841A0-9550-11cf-8C16-00805F1408F3}"
WSHShell.RegWrite "HKCR\" & p1 & p2, p3
p1 = ".html"
WSHShell.RegWrite "HKCR\" & p1 & p2, p3


'Start of Thumbnail Repair

'This section repairs the view in Thumbnail mode of Explorer.

p2 = "\CLSID\"
p3 = "{25336920-03F9-11cf-8FD0-00AA00686F13}"

For Each p1 in Array(".art",".bmp",".dib",".gif",".jfif",".jpe",".jpeg",".jpg",".png",".tif",".tiff",".wmf")
   WSHShell.RegWrite "HKCR\" & p1 & p2, p3
Next

MsgBox "Image Preview and Thumbnail View File" & vbCR & "Associations have been restored.", 4096, "Confirmation"

Set WSHShell = Nothing

 

然后在工具-文件夹选项-察看中将“隐藏已知文件类型的扩展名”前面的钩去掉。再将记事本的这个文件另存为.vbs格式，文件名可以任取，注意下面文件类型要选择“所有文件”。最后双击另存的.vbs格式的文件，就ok啦！