3243: [Noi2013]向量内积 - BZOJ

Description


两个d 维向量A=[a1,a2,...,ad]与B=[b1,b2,...,bd]的内积为其相对应维度的权值的乘积和，即：

现有 n 个d 维向量x1,...,xn ，小喵喵想知道是否存在两个向量的内积为k的倍数。请帮助她解决这个问题
Input

第一行包含3个正整数n,d,k，分别表示向量的个数，维数以及待检测的倍数。
接下来n行每行有d个非负整数，其中第i行的第j个整数表示向量xi的第j维权值xi,j。
Output

包含两个整数，用空格隔开。
如果存在两个向量xp,xq的内积为k的整数倍，则输出两个向量的编号p与q（要求p<q）。如果存在多组这样的向量组合，输出其中任意一组即可。
若不存在这样的向量组合，则输出两个-1。
Sample Input
Sample Output
HINT

 

 

话说每次我都把题目复制一遍充字数2333

k=2时

我们把n个向量拼在一起，变成一个n*d的矩阵，设它为A，然后D=A*A’，A’为A的转置矩阵（行列互换），发现D[i,j]就表示向量i和向量j的内积

假设无解的话那么D矩阵除了对角线以外其他都是1，我们把无解的这个矩阵求出来设为C（只要求对角线），然后判断C和D是否相等，相等就无解

于是随机生成一个1*n的矩阵X判断X*A*A’是否等于X*C，假设不等于的话我们就找出不相等的那个位置，假设是第i个不相等，那就肯定存在一个j使得向量i与向量j的内积mod k=0

所以这个就暴力判断一下

k=3时

我们不能确定矩阵C的样子了，因为有三种情况0,1,2

但是我们发现1^2 mod 3=1，2^2 mod 3=1，所以我们让这个矩阵的元素都平方一下，那么矩阵C又变成了除了对角线其他都是1

但是前面又不好算了，其实也很好算，内积的平方拆开就变成了d^2维的向量的内积（空间存不下，直接照着式子算就行了）

其实随机生成矩阵不是很好，为0的话就没有用了，所以我直接用了全都是1的矩阵来跑答案

 

由于时间实在卡得太紧，我在Wikioi下了数据（可惜Wikioi没有spj）然后当提答题在bzoj上交了233

const
    maxn=100100;
    maxd=110;
var
    a:array[0..maxn,0..maxd]of longint;
    b,c,x,y:array[0..maxn]of longint;
    n,d,k:longint;
 
procedure work2;
var
    i,j,k,s:longint;
begin
    s:=0;
    for i:=1 to n do s:=s xor x[i];
    for i:=1 to n do c[i]:=s xor x[i] xor(x[i] and y[i]);
    for i:=1 to n do
        for j:=1 to d do
            b[j]:=b[j] xor (x[i] and a[i,j]);
    for i:=1 to d do x[i]:=b[i];
    for i:=1 to d do b[i]:=0;
    for i:=1 to d do
        for j:=1 to n do
            b[j]:=b[j] xor (x[i] and a[j,i]);
    for i:=1 to n do
        if b[i]<>c[i] then
        begin
            for j:=1 to n do
                if i<>j then
                begin
                    s:=0;
                    for k:=1 to d do
                        s:=s xor (a[i,k] and a[j,k]);
                    if s=0 then
                    begin
                        writeln(i,' ',j);
                        exit;
                    end;
                end;
        end;
    writeln('-1 -1');
end;
 
procedure work3;
var
    i,j,k,s:longint;
begin
    s:=0;
    for i:=1 to n do if y[i]>0 then y[i]:=1;
    for i:=1 to n do inc(s,x[i]);
    for i:=1 to n do c[i]:=(s-x[i]+x[i]*y[i])mod 3;
    for i:=1 to n do
        for j:=1 to d do
            for k:=1 to d do
                inc(b[(j-1)*d+k],x[i]*a[i,j]*a[i,k]);
    for i:=1 to d*d do
        begin
            x[i]:=b[i]mod 3;
            b[i]:=0;
        end;
    for i:=1 to d do
        for j:=1 to d do
            for k:=1 to n do
                inc(b[k],x[(i-1)*d+j]*a[k,i]*a[k,j]);
    for i:=1 to n do b[i]:=b[i]mod 3;
    for i:=1 to n do
        if b[i]<>c[i] then
        begin
            for j:=1 to n do
                if i<>j then
                begin
                    s:=0;
                    for k:=1 to d do
                        s:=s+a[i,k]*a[j,k];
                    if s mod 3=0 then
                    begin
                        writeln(i,' ',j);
                        exit;
                    end;
                end;
        end;
    writeln('-1 -1')
end;
 
procedure main;
var
    i,j:longint;
begin
    read(n,d,k);
    for i:=1 to n do
        for j:=1 to d do
            begin
                read(a[i,j]);
                a[i,j]:=a[i,j]mod k;
            end;
    for i:=1 to n do x[i]:=random(k);
    for i:=1 to n do
        for j:=1 to d do
            y[i]:=y[i]+a[i,j]*a[i,j];
    for i:=1 to n do y[i]:=y[i]mod k;
    if k=2 then work2
    else work3;
end;
 
begin
    randomize;
    main;
end.