1934: [Shoi2007]Vote 善意的投票 - BZOJ

Description
幼儿园里有n个小朋友打算通过投票来决定睡不睡午觉。对他们来说，这个问题并不是很重要，于是他们决定发扬谦让精神。虽然每个人都有自己的主见，但是为了照顾一下自己朋友的想法，他们也可以投和自己本来意愿相反的票。我们定义一次投票的冲突数为好朋友之间发生冲突的总数加上和所有和自己本来意愿发生冲突的人数。 我们的问题就是，每位小朋友应该怎样投票，才能使冲突数最小？
Input
第一行只有两个整数n，m，保证有2≤n≤300，1≤m≤n(n-1)/2。其中n代表总人数，m代表好朋友的对数。文件第二行有n个整数，第i个整数代表第i个小朋友的意愿，当它为1时表示同意睡觉，当它为0时表示反对睡觉。接下来文件还有m行，每行有两个整数i，j。表示i，j是一对好朋友，我们保证任何两对i，j不会重复。
Output
只需要输出一个整数，即可能的最小冲突数。
Sample Input
3 3
1 0 0
1 2
1 3
3 2
Sample Output
1
HINT

在第一个例子中，所有小朋友都投赞成票就能得到最优解

 

经典的最小割模型，见算法合集之《最小割模型在信息学竞赛中的应用》.pdf

本来的意愿就是固定的点，然后每个都是不确定的点

从s向固定的0连容量inf的边，从固定的1向t连容量inf的边

从固定的0向自己对应的节点连容量1的边，从对应的节点向固定的1连容量1的边

朋友之间就互相连容量1的边

很囧的建错了两次图

1.固定的点我只连了容量1的边

2.固定的0和1向每个节点都连了边

但是有90分，应该是因为每个人都选同一种代价小于n吧（这个90分好奇葩的样子）

const
        maxn=610;
        inf=1000000;
var
        map:array[0..maxn,0..maxn]of longint;
        n,m,s,t:longint;

procedure init;
var
        i,x,y:longint;
begin
        read(n,m);
        s:=0;
        t:=n*2+1;
        for i:=1 to n do
          begin
            read(x);
            if x=0 then
              begin
                map[s,i+n]:=inf;
                map[i+n,i]:=1;
              end
            else
              begin
                map[i+n,t]:=inf;
                map[i,i+n]:=1;
              end;
          end;
        for i:=1 to m do
          begin
            read(x,y);
            map[x,y]:=1;
            map[y,x]:=1;
          end;
end;

var
        dis,vh,pre,his:array[0..maxn]of longint;
        flow,aug:longint;

procedure sap;
var
        i,j,min:longint;
        flag:boolean;
begin
        vh[0]:=t+1;
        i:=s;
        aug:=inf;
        while dis[i]<=t do
          begin
            his[i]:=aug;
            flag:=false;
            for j:=s to t do
              if (map[i,j]>0) and (dis[i]=dis[j]+1) then
              begin
                flag:=true;
                if aug>map[i,j] then aug:=map[i,j];
                pre[j]:=i;
                i:=j;
                if i=t then
                begin
                  inc(flow,aug);
                  while i<>s do
                    begin
                      inc(map[i,pre[i]],aug);
                      dec(map[pre[i],i],aug);
                      i:=pre[i];
                    end;
                  aug:=inf;
                end;
                break;
              end;
            if flag then continue;
            min:=t;
            for j:=s to t do
              if (map[i,j]>0) and (dis[j]<min) then min:=dis[j];
            dec(vh[dis[i]]);
            if vh[dis[i]]=0 then break;
            dis[i]:=min+1;
            inc(vh[min+1]);
            if i<>s then
            begin
              i:=pre[i];
              aug:=his[i];
            end;
          end;
        writeln(flow);
end;

begin
        init;
        sap;
end.