1972: [Sdoi2010]猪国杀 - BZOJ

题目太长，我只发链接吧

wikioi（排版看起来舒服一点）：http://www.wikioi.com/problem/1834/

bzoj：http://www.lydsy.com:808/JudgeOnline/problem.php?id=1972

首先是题目的样例错了，第三个人有6个J

还有，数据有问题，第1,2个点牌不够用，抽完了就一直抽最后一张牌

调了一天多，我的模拟能力真TM差啊

犯了几个傻逼错误

1.让死人（反贼）继续出牌，用南蛮入侵杀死队友，导致主公获胜

2.主公杀死忠臣没有弃装备，后来用诸葛连杀掉反贼获胜

3.最烦的就是无懈可击的顺序了，先从出锦囊的人开始逆时针献殷勤，如果被无懈可击了，就回到上一个献殷勤的人的下家开始献殷勤（一开始直接往后，点都是交替错的（A对B就错），就是没有全对）

type
        aa=array[0..2010]of char;
        pig=record
          pai:aa;
          blood,num:longint;
          zhuge,tiaozhong,tiaofan,leifan,sha:boolean;
          shenfen:char;
        end;
var
        a:array[0..10]of pig;
        p:array[0..2010]of char;
        n,m,now,fanzeishu:longint;
 
procedure print;
var
        i,j:longint;
begin
        for i:=1 to n do
          with a[i] do
            begin
              if blood>0 then
                begin
                  for j:=1 to num do
                    if j<num then write(pai[j],' ')
                    else write(pai[j]);
                end
              else write('DEAD');
              writeln;
            end;
        halt;
end;
 
procedure MPwin;
begin
        writeln('MP');
        print;
end;
 
procedure FPwin;
begin
        writeln('FP');
        print;
end;
 
procedure init;
var
        i,j:longint;
begin
        readln(n,m);
        for i:=1 to n do
          with a[i] do
          begin
            read(shenfen,pai[0]);
            if shenfen='F' then inc(fanzeishu);
            for j:=1 to 4 do
              read(pai[j+1],pai[j]);
            blood:=4;
            num:=4;
            readln;
          end;
        a[1].tiaozhong:=true;
        if fanzeishu=0 then MPwin;
        for i:=1 to m do
          read(p[i],p[i+1]);
        now:=1;
end;
 
procedure delete(var pai:aa;x:longint;var num:longint);
var
        i:longint;
begin
        for i:=x to num-1 do
          pai[i]:=pai[i+1];
        dec(num);
end;
 
function next(x:longint):longint;
begin
        while true do
          begin
            x:=x mod n+1;
            if a[x].blood>0 then exit(x);
          end;
end;
 
function diyi(x,y:longint):boolean;
begin
        exit(((a[x].shenfen='F') and (a[y].tiaozhong)) or ((a[x].shenfen<>'F') and (a[y].tiaofan)) or ((x=1) and (a[y].leifan)));
end;
 
function youjun(x,y:longint):boolean;
begin
        exit(((a[x].shenfen='F') and (a[y].tiaofan)) or ((a[x].shenfen<>'F') and (a[y].tiaozhong)));
end;
 
procedure mopai(x:longint);
begin
        if now>m then now:=m;
        with a[x] do
          begin
            inc(num);
            pai[num]:=p[now];
            inc(now);
          end;
end;
 
procedure tiao(x:longint);
begin
        with a[x] do
          begin
            if shenfen='F' then tiaofan:=true
            else tiaozhong:=true;
            leifan:=false;
          end;
end;
 
function chupai(x:longint;c:char):boolean;
var
        i:longint;
begin
        with a[x] do
          begin
            for i:=1 to num do
              if pai[i]=c then
              begin
                delete(pai,i,num);
                exit(true);
              end;
            exit(false);
          end;
end;
 
procedure kill(x,y:longint);
begin
        if a[y].shenfen='F' then
        begin
          mopai(x);
          mopai(x);
          mopai(x);
        end;
        if (x=1) and (a[y].shenfen='Z') then
        begin
          a[x].num:=0;
          a[x].zhuge:=false;
        end;
end;
 
procedure decblood(x:longint);
begin
        with a[x] do
          begin
            dec(blood);
            if blood=0 then
            begin
              if chupai(x,'P')=false then
                begin
                  if shenfen='F' then dec(fanzeishu);
                  if fanzeishu=0 then MPwin;
                  if shenfen='M' then FPwin;
                end
              else blood:=1;
            end;
          end;
end;
 
function dixiao(x:longint):boolean;
var
        i:longint;
begin
        i:=next(x);
        while i<>x do
          begin
            if diyi(i,x) and chupai(i,'J') then
            begin
              tiao(i);
              exit(true);
            end;
            i:=next(i);
          end;
        exit(false);
end;
 
procedure gongji(x,y:longint);
begin
        if chupai(y,'D')=false then
        begin
          decblood(y);
          if a[y].blood=0 then kill(x,y);
        end;
end;
 
function jiuyuan(x,k:longint):boolean;
var
        i:longint;
flag:boolean;
begin
        i:=k;
        flag:=true;
        while true do
          begin
            if (i=k) and (flag=false) then break;
            if i=k then flag:=false;
            if (youjun(i,x)) and (chupai(i,'J')) then
            begin
              tiao(i);
              flag:=true;
              if not dixiao(i) then exit(true);
            end;
            i:=next(i);
          end;
        exit(false);
end;
 
procedure fight(x,y:longint);
begin
        if (x=1) and (a[y].shenfen='Z') then
          begin
            decblood(y);
            if a[y].blood=0 then kill(x,y);
          end
        else
          if jiuyuan(y,x)=false then
            begin
              while true do
                begin
                  if chupai(y,'K')=false then
                  begin
                    decblood(y);
                    if a[y].blood=0 then kill(x,y);
                    exit;
                  end;
                  if chupai(x,'K')=false then
                  begin
                    decblood(x);
                    if a[x].blood=0 then kill(y,x);
                    exit;
                  end;
                end;
            end;
end;
 
procedure nanman(x:longint);
var
        i:longint;
begin
        i:=next(x);
        while i<>x do
          begin
            if jiuyuan(i,x)=false then
            begin
              if chupai(i,'K')=false then
              begin
                decblood(i);
                if (i=1) and (not a[x].tiaozhong) and (not a[x].tiaofan) then a[x].leifan:=true;
                if a[i].blood=0 then kill(x,i);
              end;
            end;
            i:=next(i);
          end;
end;
 
procedure wanjian(x:longint);
var
        i:longint;
begin
        i:=next(x);
        while i<>x do
          begin
            if jiuyuan(i,x)=false then
            begin
              if chupai(i,'D')=false then
              begin
                decblood(i);
                if (i=1) and (not a[x].tiaozhong) and (not a[x].tiaofan) then a[x].leifan:=true;
                if a[i].blood=0 then kill(x,i);
              end;
            end;
            i:=next(i);
          end;
end;
 
procedure xingdong(x:longint);
var
        i,k:longint;
begin
        i:=1;
        with a[x] do
          while i<=num do
            begin
              if a[x].blood=0 then exit;
              if pai[i]='N' then
              begin
                delete(pai,i,num);
                nanman(x);
                i:=1;
                continue;
              end;
              if pai[i]='W' then
              begin
                delete(pai,i,num);
                wanjian(x);
                i:=1;
                continue;
              end;
              if (pai[i]='K') and ((not sha) or zhuge) then
              begin
                k:=next(x);
                if diyi(x,k) then
                begin
                  delete(pai,i,num);
                  tiao(x);
                  gongji(x,k);
                  sha:=true;
                  i:=1;
                  continue;
                end;
              end;
              if pai[i]='F' then
              begin
                k:=next(x);
                if x=1 then
                begin
                  while k<>x do
                    begin
                      if diyi(x,k) then
                      begin
                        delete(pai,i,num);
                        break;
                      end;
                      k:=next(k);
                    end;
                  if k<>x then
                  begin
                    fight(x,k);
                    i:=1;
                    continue;
                  end;
                end;
                if shenfen='F' then
                begin
                  delete(pai,i,num);
                  tiao(x);
                  fight(x,1);
                  i:=1;
                  continue;
                end;
                if shenfen='Z' then
                begin
                  while k<>x do
                    begin
                      if diyi(x,k) then
                      begin
                        delete(pai,i,num);
                        break;
                      end;
                      k:=next(k);
                    end;
                  if k<>x then
                  begin
                    tiao(x);
                    fight(x,k);
                    i:=1;
                    continue;
                  end;
                end;
              end;
              if (pai[i]='P') and (blood<4) then
              begin
                inc(blood);
                delete(pai,i,num);
                i:=1;
                continue;
              end;
              if pai[i]='Z' then
              begin
                zhuge:=true;
                delete(pai,i,num);
                i:=1;
                continue;
              end;
              inc(i);
            end;
end;
 
procedure work;
var
        i:longint;
begin
        i:=0;
        while true do
          begin
            i:=i mod n+1;
            if a[i].blood=0 then continue;
            mopai(i);
            mopai(i);
            a[i].sha:=false;
            xingdong(i);
          end;
end;
 
begin
        init;
        work;
end.