1044: [HAOI2008]木棍分割 - BZOJ

Description

有n根木棍, 第i根木棍的长度为Li,n根木棍依次连结了一起, 总共有n-1个连接处. 现在允许你最多砍断m个连接处, 砍完后n根木棍被分成了很多段,要求满足总长度最大的一段长度最小, 并且输出有多少种砍的方法使得总长度最大的一段长度最小. 并将结果mod 10007。。。
Input

输入文件第一行有2个数n,m. 接下来n行每行一个正整数Li,表示第i根木棍的长度.
Output

输出有2个数, 第一个数是总长度最大的一段的长度最小值, 第二个数是有多少种砍的方法使得满足条件.
Sample Input
3 2
1
1
10
Sample Output
10 2

两种砍的方法: (1)(1)(10)和(1 1)(10)
数据范围
n<=50000, 0<=m<=min(n-1,1000).
1<=Li<=1000.

 

第一问就直接二分答案

第二问我们动态规划，f[i,j]表示前i个分成j段有多少种方案

f[i,j]=sigema(f[k,j-1])(sum[i]-sum[k]<=lim)

数组要滚动，每次计算f[i,j]时先继承f[i+1,j]的值（因为我是倒着做的），然后把多的减去少的加上就行了

const
    maxn=100010;
    h=10007;
var
    f,a,s:array[0..maxn]of longint;
    n,m,lim,ans:longint;
 
function flag(x:longint):boolean;
var
    i,k,sum:longint;
begin
    k:=0;
    sum:=0;
    for i:=1 to n do
      begin
        if a[i]>x then exit(false);
        if sum+a[i]>x then
          begin
            inc(k);
            sum:=a[i];
          end
        else inc(sum,a[i]);
      end;
    if sum>0 then inc(k);
    if k>m then exit(false);
    exit(true);
end;
 
procedure init;
var
    i,l,r,mid:longint;
begin
    read(n,m);
    inc(m);
    for i:=1 to n do
      begin
        read(a[i]);
        s[i]:=s[i-1]+a[i];
      end;
    l:=1;
    r:=500000000;
    while l<>r do
      begin
        mid:=(l+r)>>1;
        if flag(mid) then r:=mid
        else l:=mid+1;
      end;
    lim:=l;
    f[0]:=1;
    write(lim,' ');
end;
 
procedure work;
var
    i,j,l,sum:longint;
begin
    for i:=1 to m do
      begin
        sum:=f[n];
        l:=n-1;
        for j:=n downto 0 do
          begin
            dec(sum,f[j]);
            f[j]:=0;
            while (l>=0) and (s[j]-s[l]<=lim) do
              begin
                inc(sum,f[l]);
                dec(l);
              end;
            f[j]:=sum mod h;
          end;
        ans:=(ans+f[n])mod h;
      end;
    write(ans);
end;
 
begin
    init;
    work;
end.