Tower /点的移动（洛谷 1632）题解

【问题描述】

    平面上有N个整数坐标点。如果将点（x0,y0）移动到（x1,y1），则需要的代价为|x0-x1|+|y0-y1|。求使得K(K=1,…,N)个点在同一位置上最少需要的代价。

【样例输入】

    4 
    15 14
    15 16
    14 15
    16 15

【样例输出】 

    0
    2
    3
    4

【解题思路】

    初看这道题，还以为是只能移动到有点的地方，即把别的点移动到一个点上，移动（k-1）个点所需要的最小代价，结果发现样例都过不去……接着分析了一下样例，发现样例是将k个点都移动到了（15，15）上去，当然，k=1的时候不需要移动，于是我就去找所有x,y的中位数，结果过了样例，但是OJ上为0分，那我们再重新来分析一下题目。

    题目中是可以移到任意一个点的，我们不难发现这个点的x必定在所有x坐标之间，同理，y也如此，因此，我们只要枚举每一个x,y然后将每一个点都去移动一次，找出移动k个点的时候，最小的移动代价即可。

    那么我们在这题中可以用一个三重循环，因为N的值并不大，只有50，三重循环并不会TLE。这里用三重循环的作用是方便计算每一个点移动的代价，详见代码。

【代码实现】

type rec=record  
     x,y:longint;  
end;  
var a:array[0..55] of rec;  
    f:array[0..55,0..55] of longint;  
    d,ans:array[0..55] of longint;  
    i,j,n,k,s:longint;  
procedure sort(l,r:longint);  
var i,j,x,y:longint;  
begin  
 i:=l;  
 j:=r;  
 x:=d[(l+r) shr 1];  
 repeat  
  while d[i]<x do  
   inc(i);  
  while x<d[j] do  
   dec(j);  
  if not(i>j) then  
   begin  
    y:=d[i];  
    d[i]:=d[j];  
    d[j]:=y;  
    inc(i);  
    j:=j-1;  
   end;  
 until i>j;  
 if l<j then  
  sort(l,j);  
 if i<r then  
  sort(i,r);  
end;  
begin  
 readln(n);  
 for i:=1 to n do  
  with a[i] do  
   readln(x,y);  
 for i:=1 to n do  
  ans[i]:=maxlongint;  
 for i:=1 to n do  
  for j:=1 to n do  
   begin  
    for k:=1 to n do  
     d[k]:=abs(a[k].x-a[i].x)+abs(a[k].y-a[j].y);  //枚举每一个点移动到xi,yj上需要的代价。
    sort(1,n);  
    s:=0;  
    for k:=1 to n do  
     begin  
      s:=s+d[k];  
      if s<ans[k] then  
       ans[k]:=s;  
     end;  //更新最优解
   end;  
 for i:=1 to n do  
  writeln(ans[i]);  
end.