邮递员送信（luogu 1629）题解

【问题描述】

有一个邮递员要送东西，邮局在节点1.他总共要送N-1样东西，其目的地分别是2~N。由于这个城市的交通比较繁忙，因此所有的道路都是单行的，共有M条道路，通过每条道路需要一定的时间。这个邮递员每次只能带一样东西。求送完这N-1样东西并且最终回到邮局最少需要多少时间。

【样例输入】

    5 10
    2 3 5
    1 5 5
    3 5 6
    1 2 8
    1 3 8
    5 3 4
    4 1 8
    4 5 3
    3 5 6
    5 4 2

【样例输出】

    83

【解题思路】

    看到这题……这不明摆着赤裸裸的最短路嘛，而且还要往返走，还是单向的，n<=1000，还用说什么？邻接矩阵+floyed搞起啊！然而……交上OJ后发现，仅仅AC了4个点……TLE6个……算了算复杂度，嗯……不错，最大可以到O(10^9)不爆才怪了……于是换一种思路……那么只能求单源最短路了，怎么求呢？两边dijkstra一边算过去的，一边算回来的……然后顺便注意一下重边，于是AC了……

    下面我们来总结一下求最短路的方法，求多源最短路……不用说，只能floyed，如果数据给大了的话肯定就是你想错了，比如今天这道题……由一点出发回到同一点的题可以看做单源最短路，如果没有负权边的话能用dijkstra尽量用dijkstra，（自我感觉dijkstra最好写……）当然愿意写SPFA是最佳选择，SPFA的时间复杂度是最低的。然后，对于存储图的问题，能用邻接矩阵尽量用邻接矩阵，邻接矩阵比邻接表还是方便许多的，（便于debug，便于观察），如果实在不行的话那就只能用邻接表了，愿意用邻接表的用邻接表也可以。（自我感觉不愿意去写……）

【代码实现】

var a:array[-1..1010,-1..1010] of longint;  
    i,j,n,m,u,v,w,ans,k:longint;  
    f:array[-1..1010] of boolean;  
    s1,s2:array[-1..1010] of longint;  
procedure dijkstra;  
var i,j,min,pos:longint;  
begin  
 f[1]:=true;  
 for i:=2 to n do  
  begin  
   min:=maxlongint;  
   pos:=-1;  
   for j:=1 to n do  
    if not(f[j])and(s1[j]<min) then  
     begin  
      min:=s1[j];  
      pos:=j;  
     end;  
   if pos=-1 then  
    break;  
   f[pos]:=true;  
   for j:=1 to n do  
    if not(f[j])and(s1[pos]+a[pos,j]<s1[j]) then  
     s1[j]:=s1[pos]+a[pos,j];  
  end;  
end;  
procedure dijkstra1;  
var i,j,min,pos:longint;  
begin  
 f[1]:=true;  
 for i:=2 to n do  
  begin  
   min:=maxlongint;  
   pos:=-1;  
   for j:=1 to n do  
    if not(f[j])and(s2[j]<min) then  
     begin  
      min:=s2[j];  
      pos:=j;  
     end;  
   if pos=-1 then  
    break;  
   f[pos]:=true;  
   for j:=1 to n do  
    if not(f[j])and(s2[pos]+a[j,pos]<s2[j]) then  
     s2[j]:=s2[pos]+a[j,pos];  
  end;  
end;  
begin  
 readln(n,m);  
 for i:=1 to n do  
  for j:=1 to n do  
   a[i,j]:=maxint+100000;  
 for i:=2 to n do  
  begin  
   s1[i]:=maxint+100000;  
   s2[i]:=maxint+100000;  
  end;  
 for i:=1 to m do  
  begin  
   readln(u,v,w);  
   if w<a[u,v] then  
    a[u,v]:=w;  
   if (u=1)and(w<s1[v]) then  
    s1[v]:=w;  
   if (v=1)and(w<s2[u]) then  
    s2[u]:=w;  
  end;  
 dijkstra;  
 fillchar(f,sizeof(f),false);  
 dijkstra1;  
 for i:=2 to n do  
  ans:=ans+s1[i]+s2[i];  
 writeln(ans);  
end.