寻找道路（codevs 3731）题解

【问题描述】

在有向图 G 中，每条边的长度均为 1，现给定起点和终点，请你在图中找一条从起点到 终点的路径，该路径满足以下条件：

1. 路径上的所有点的出边所指向的点都直接或间接与终点连通。
2. 在满足条件 1 的情况下使路径最短。

注意：图 G 中可能存在重边和自环，题目保证终点没有出边。 请你输出符合条件的路径的长度。

【样例输入1】

    3 2
    1 2
    2 1
    1 3

【样例输出1】

    -1

【样例输入2】

    6 6
    1 2
    1 3
    2 6
    2 5
    4 5
    3 4
    1 5

【样例输出2】

    3

【解题思路】

     又是要用邻接表的题，我又华丽丽地用了邻接矩阵，加上当初SB一般的用广搜+深搜去搜能到的顶点，用了两个布尔型数组，求最短路的时候用了floyed（其实这个都没什么了，之前的就足够MLE了……），再次爆零……

    OK，吐槽完之后，继续来说正解。

    邻接表，不多说了，以后看到需要存储边的题目都去用邻接表！管你有没有权。由于这题需要判断能否到达终点，于是我们需要反向存储。一遍DFS找到所有不能直接或间接到达的点，将它们的所有的入边的点全部删掉，如果起点无法到达的话，就输出-1，否则就是求最短路了。

【代码实现】

type rec=record
     c,next:longint;
end;
var e:array[1..200000] of rec;
    g:array[1..10000] of longint;
    efree,i,n,m,k,x,y,s,t,j:longint;
    a:array[1..10000] of longint;
    f,flag:array[1..10000] of boolean;
procedure add;
begin
 e[efree].c:=x;
 e[efree].next:=g[y];
 g[y]:=efree;
 inc(efree);
end;
procedure dfs(x:longint);
var j:longint;
begin
 f[x]:=true;
 j:=g[x];
 while j<>0 do
  begin
   if not f[e[j].c] then
    dfs(e[j].c);
   j:=e[j].next;
  end;
end;
procedure dijkstra;
var i,j,min,pos:longint;
begin
 fillchar(f,sizeof(f),false);
 f[t]:=true;
 a[t]:=0;
 for j:=1 to n do
  begin
   pos:=t;
   min:=maxint;
   for i:=1 to n do
    if (not f[i])and(a[i]<min)and(flag[i]) then
     begin
      pos:=i;
      min:=a[i];
     end;
   f[pos]:=true;
   i:=g[pos];
   while i<>0 do
    begin
     if flag[e[i].c] then
      if a[e[i].c]>a[pos]+1 then
       a[e[i].c]:=a[pos]+1;
     i:=e[i].next;
    end;
  end;
end;
begin
 readln(n,m);
 efree:=1;
 for i:=1 to m do
  begin
   readln(x,y);
   add;
  end;
 readln(s,t);
 dfs(t);
 flag:=f;
 for i:=1 to n do
  if not f[i] then
   begin
    j:=g[i];
    while j<>0 do
     begin
      flag[e[j].c]:=false;
      j:=e[j].next;
     end;
   end;
 if not flag[s] then
  begin
   writeln(-1);
   halt;
  end;
 for i:=1 to n do
  a[i]:=maxint;
 dijkstra;
 writeln(a[s]);
end.