树网的核（codevs 1167）题解

【问题描述】

设T=(V, E, W) 是一个无圈且连通的无向图（也称为无根树），每条边到有正整数的权，我们称T为树网（treebetwork），其中V，E分别表示结点与边的集合，W表示各边长度的集合，并设T有n个结点。

路径：树网中任何两结点a，b都存在唯一的一条简单路径，用d(a, b)表示以a, b为端点的路径的长度，它是该路径上各边长度之和。我们称d(a, b)为a, b两结点间的距离。

D(v, P)=min{d(v, u), u为路径P上的结点}。

树网的直径：树网中最长的路径成为树网的直径。对于给定的树网T，直径不一定是唯一的，但可以证明：各直径的中点（不一定恰好是某个结点，可能在某条边的内部）是唯一的，我们称该点为树网的中心。

偏心距ECC(F)：树网T中距路径F最远的结点到路径F的距离，即

ECC(F)=max{d(v, F)，v∈V}

任务：对于给定的树网T=(V, E, W)和非负整数s，求一个路径F，他是某直径上的一段路径（该路径两端均为树网中的结点），其长度不超过s（可以等于s），使偏心距ECC(F)最小。我们称这个路径为树网T=(V, E, W)的核（Core）。必要时，F可以退化为某个结点。一般来说，在上述定义下，核不一定只有一个，但最小偏心距是唯一的。

下面的图给出了树网的一个实例。图中，A-B与A-C是两条直径，长度均为20。点W是树网的中心，EF边的长度为5。如果指定s=11，则树网的核为路径DEFG（也可以取为路径DEF），偏心距为8。如果指定s=0（或s=1、s=2），则树网的核为结点F，偏心距为12。

【样例输入1】

    5 2
    1 2 5
    2 3 2
    2 4 4
    2 5 3

【样例输出1】

    5

【样例输入2】

    8 6
    1 3 2
    2 3 2
    3 4 6
    4 5 3
    4 6 4
    4 7 2
    7 8 3

【样例输出2】

    5

【解题思路】

    本题为NOIP2007提高组第四题，是不是感觉题目都不想看？各种专有名词，篇幅极长，总会有点抵触心理的。但是，说实话这道题真不难，把题目的意思浓缩一下就是要你求一段最长的路径，然后在整个图中的每一个点到该路径上的点的最大长度的最小值即是答案。而且这段路径上长度不超过s的路径才可以去找，甚至这条路径可能是一个点。

    明白题目之后就很好办了，首先floyed把所有路径长求出来，然后在其中找最大值，那么怎么判断我们要找的路径（点）在直径上呢？可以这么做：如果从直径的起点出发到该路径（点）的距离与该路径到直径的终点的距离相加为直径的距离则说明该路径（点）在直径上。那么，怎么确定一条路径上所有的点呢？这里，我用road[i,j]记录i-j这条路径上j的前一个节点，至于怎么更新，详见代码，大家可以把这个方法记下来。然后就是求最大值和求最小值的问题了。

【代码实现】

var n,s,i,j,x,y,z,k,max,min,maxlen,maxi,maxj,q,minx:longint;
    a,road:array[1..300,1..300] of longint;
begin
 readln(n,s);
 for i:=1 to n do
  for j:=1 to n do
   a[i,j]:=maxint;
 for i:=1 to n-1 do
  begin
   readln(x,y,z);
   a[x,y]:=z;
   a[y,x]:=z;
   road[x,y]:=x;
   road[y,x]:=y;//road数组初始化
  end;
 for k:=1 to n do
  for i:=1 to n do
   for j:=1 to n do
    if a[i,k]+a[k,j]<a[i,j] then
     begin
      a[i,j]:=a[i,k]+a[k,j];
      road[i,j]:=road[k,j];//随floyed的更新而更新
     end;
 min:=maxlongint;
 for i:=1 to n do
  begin
   road[i,i]:=0;
   a[i,i]:=0;
  end;
 for i:=1 to n do
  for j:=1 to n do
   if a[i,j]>maxlen then
    begin
     maxlen:=a[i,j];
     maxi:=i;
     maxj:=j;
    end;
 for i:=1 to n do
  for j:=1 to n do
   if (a[i,j]<=s)and(a[maxi,i]+a[i,j]+a[j,maxj]=maxlen) then
    begin
     max:=0;
     for q:=1 to n do
      begin
       k:=j;
       minx:=maxlongint;
       while k<>0 do
        begin
         if a[q,k]<minx then
          minx:=a[q,k];
         k:=road[i,k];
        end;
       if minx>max then
        max:=minx;
      end;
     if max<min then
      min:=max;
    end;
 writeln(min);
end.