Delphi格式化字符串函数

var
  s: string;
begin
  //指令类型 type

  s := Format('最大整数是: %d; 最小整数是: %d',[MaxInt,Low(Integer)]);
  //返回: 最大整数是: 2147483647; 最小整数是: -2147483648
  { 提示: 格式指令必须以 % 开始, 不区分大小写, %d 代表一个整数; 第二个参数是一个变体数组 }

  s := Format('最大的无负号整数是: %u',[High(Cardinal)]);
  //返回: 最大的无负号整数是: 4294967295
  { %u表示一个无负号整数 }

  s := Format('输入-2的结果是: %u',[-2]);
  //返回: 输入-2的结果是: 4294967294
  { 如果对应 %u 的是个负数, 则返回: 无负号整数最大值 - 这个数的绝对值 + 1 }

  s := Format('%s! %s',['你好','我是万一']);
  //返回: 你好! 我是万一
  { %s 表示字符串 }

  s := Format('%f',[Pi]);
  //返回: Pi的值是: 3.14
  { %f 表示浮点数, 保留或凑够两位小数点 }

  s := Format('%g',[01.2345000]);
  //返回: 1.2345
  { %g 表示浮点数, 会去掉多余的 0 }

  s := Format('%n',[12345.6789]);
  //返回: 12,345.68
  { %n 表示浮点数, 整数部分使用千位分隔符, 保留两位小数点 }

  s := Format('%m',[12345.6789]);
  //返回: ￥12,345.68
  { %m 表示浮点数, 加货币记号, 转换结果取决于系统的地域设置 }

  s := Format('%e',[12345.6789]);
  //返回: 1.23456789000000E+004
  { %e 用科学计数法表示整数或浮点数 }

  s := Format('%p',[@Self]);
  //返回: 0012F5BC
  { %p 表示指针地址, 用十六进制表示 }

  s := Format('%x',[255]);
  //返回: FF
  { %x 用十六进制表示一个整数 }

  //Index

  s := Format('%s%s',['万','一']);
  s := Format('%0:s%1:s',['万','一']);
  //返回: 万一
  { 上面两行的结果是一样的, 0: 对应数组中的第一个值; 1: 对应数组中的第二个值 }

  s := Format('%1:s%0:s',['万','一']);
  //返回: 一万
  { 翻转了一下顺序 }

  s := Format('%1:s%0:s%0:s%1:s',['万','一']);
  //返回: 一万万一
  { 反复使用 }

  //Width 与对齐方式

  s := Format('%d,%8d,%d',[1,2,3]);
  //返回: 1,       2,3
  { 给第二个值指定了8个字符的宽度, 缺少的用空格填充; 如果指定少了则无效 }

  s := Format('%d,%-8d,%d',[1,2,3]);
  //返回: 1,2       ,3
  { - 表示左对齐, 默认是右对齐的; - 符号在 Width 前面、Index 后面 }

  //指定精度 prec

  s := Format('%.9f',[Pi]);
  //返回: 3.141592654
  { 指定小数点的位数, 取值范围1-9, 输入0也当1用 }

  s := Format('%.5d',[12]);
  //返回: 00012
  { 这是给整数指定位数, 如果小了则无效 }

  s := Format('%.3s',['Format']);
  //返回: For
  { 给字符串指定位数, 如果大了则无效 }

  s := Format('%.3e',[123.456]);
  //返回: 1.23E+002
  { 给科学计数法指定位数 }

  //指令顺序:

  { "%" [index ":"] ["-"] [width] ["." prec] type }

  ShowMessage(s);
end;