弱爆了...

发现我的代码实现能力太弱了...

今天打阿里的打字机，调了2个小时...

总结一下

1.用两个链表，一个实现离线处理，一个实现fail树，采用link,next,value(保存关键信息):array[0..Maxn] of longint 的形式可以只写一个insert过程

2.代码中的sum多次重复使用，所以养成重复变量使用完后初始化的习惯(就在这儿坑了无数次...)

3.AC-automation用数组写比链表方便许多

4.树状数组可以用来动态统计子树的某一类子节点个数

贴一下苦逼的代码:

Program print;

Const Maxn=100000;

var
    s:ansistring;
    m,sum:longint;
    link,next,value:array[0..1,0..Maxn] of longint;

    root:longint;
    node:array[0..Maxn,'a'..'z'] of longint;
    fail,pre,ask:array[0..Maxn] of longint;
    ans:array[0..Maxn] of longint;

    time:longint;
    enter,leave:array[0..Maxn] of longint;
    c:array[0..2*Maxn] of longint;

    procedure insert(u,v,w:longint);
    begin
        inc(sum);
        next[w,sum]:=link[w,u]; link[w,u]:=sum; value[w,sum]:=v;
    end;

    Procedure Init;
    var i,x,y:longint;
    begin
        readln(s);
        readln(m);
        for i:=1 to m do
            begin
                readln(x,y);
                insert(y,x,0);
            end;
        sum:=0;
    end;

    Procedure Build_AC_automation;
    var t,p,i:longint;
        head,tail:longint;
        q:array[0..Maxn] of longint;
        now,v:longint;
        ch:char;

    begin
        sum:=1; root:=1; t:=root;
        for i:=1 to length(s) do
            case s[i] of
                'P':begin
                        inc(ask[0]);
                        ask[ask[0]]:=t;
                    end;
                'B':t:=pre[t];
                else
                    if node[t,s[i]]=0 then
                        begin
                            inc(sum); node[t,s[i]]:=sum;
                            pre[node[t,s[i]]]:=t; t:=sum;
                        end else t:=node[t,s[i]];
            end;
        head:=1; tail:=1; q[1]:=root; fail[root]:=root; sum:=0;
        while head<=tail do
            begin
                now:=q[head]; inc(head);
                for ch:='a' to 'z' do
                    begin
                        if node[now,ch]=0 then continue;
                        v:=fail[now];
                        while (v<>root) and (node[v,ch]=0) do v:=fail[v];
                        if (now<>root) and (node[v,ch]>0) then v:=node[v,ch];
                        fail[node[now,ch]]:=v;
                        insert(v,node[now,ch],1);
                        inc(tail); q[tail]:=node[now,ch];
                    end;
            end;
    end;

    Procedure DFS(t:longint);
    var p:longint;
    begin
        inc(time); enter[t]:=time;
        p:=link[1,t];
        while p>0 do
            begin
                //writeln(t,'-->',value[1,p]);
                DFS(value[1,p]);
                p:=next[1,p];
            end;
        leave[t]:=time;
    end;

    Function lowbit(t:longint):longint;
    begin
        exit(t and  (t xor (t-1)));
    end;

    Procedure Update(t,v:longint);
    begin
        while t<=time do
            begin
                inc(c[t],v);
                t:=t+lowbit(t);
            end;
    end;

    Function Getsum(t:longint):longint;
    var sum:longint;
    begin
        sum:=0;
        while t>0 do
            begin
                sum:=sum+c[t];
                t:=t-lowbit(t);
            end;
        exit(sum);
    end;

    Procedure Work;
    var t,p,i:longint;
    begin
        sum:=0; t:=root;
        for i:=1 to length(s) do
            case s[i] of
                'P':begin
                        inc(sum);
                        p:=link[0,sum];
                        while p>0 do
                            begin
                                ans[p]:=getsum(leave[ask[value[0,p]]])-getsum(enter[ask[value[0,p]]]-1);
                                p:=next[0,p];
                            end;
                    end;
                'B':begin
                        Update(enter[t],-1);
                        t:=pre[t];
                    end
                else
                    begin
                        t:=node[t,s[i]];
                        Update(enter[t],1);
                    end;
            end;
        for i:=1 to m do writeln(ans[i]);
    end;

begin
    Init;
    Build_AC_automation;
    time:=0; DFS(root);
    Work;
end.