IOS 本地通知 UILocalNotification

IOS 本地通知 UILocalNotification

【本文章第四部分中的代码逻辑来自网上的借鉴，并非我自己原创】

大概一个月前，我开始跟着做IOS项目了。学习C++，了解Objective-C，等等。这两天做了游戏的本地通知，当然是从网上查了很多资料。

但资料有很多的偏差，不过最终还是解决了问题，很幸运。所以总结了一下下。

用到的重点就是Objective-C 的UILocalNotification对象。其实加入通知的代码很简单，但重要的是你要理顺Notification的逻辑。

首先我要声明的是我的开发环境：

首先在windows下面用Visual studio开发，调试，编译通过了以后。再在Mac下面用Xcode编译，导到Ipad4上面运行的。所以我的混编文件是Objective-C和C++的混合。

 

 1 UILocalNotification *notification=[[UILocalNotification alloc] init];
 2         if (notification!=nil) {
 3             NSDate *now = [NSDate date];
 4             //从现在开始，10秒以后通知
 5             notification.fireDate=[now dateByAddingTimeInterval:10];
 6             //使用本地时区
 7             notification.timeZone=[NSTimeZone defaultTimeZone];
 8             notification.alertBody=@"顶部提示内容，通知时间到啦";
 9             //通知提示音 使用默认的
10             notification.soundName= UILocalNotificationDefaultSoundName;
11             notification.alertAction=NSLocalizedString(@"你锁屏啦，通知时间到啦", nil);
12             //这个通知到时间时，你的应用程序右上角显示的数字。
13             notification.applicationIconBadgeNumber = 1;
14             //add key  给这个通知增加key 便于半路取消。nfkey这个key是我自己随便起的。
15             // 假如你的通知不会在还没到时间的时候手动取消 那下面的两行代码你可以不用写了。
16             NSDictionary *dict =[NSDictionary dictionaryWithObjectsAndKeys:[NSNumber numberWithInt:notificationtag],@"nfkey",nil];
17             [notification setUserInfo:dict];
18             //启动这个通知
19             [[UIApplication sharedApplication]   scheduleLocalNotification:notification];
20             //这句真的特别特别重要。如果不加这一句，通知到时间了，发现顶部通知栏提示的地方有了，然后你通过通知栏进去，然后你发现通知栏里边还有这个提示
21             //除非你手动清除，这当然不是我们希望的。加上这一句就好了。网上很多代码都没有，就比较郁闷了。
22             [notification release];
23         }

首先，这是一段Objective-C的代码，所以这段代码肯定也必须处在一个混编文件中，也就是后缀为.mm的文件里边。里面的内容我已经注释的很清楚，太详细的大家去查文档就可以了。
其中要特别注意的是第13行和22。

这段代码是从现在开始，多长时间后触发，并且只触发一次，这是我的需求，如果你需要固定时间触发，循环触发，也可以实现，google一下就可以了。

就这么简单，你调用了这段代码后，将app切到后台或者直接Kill掉，10秒后，就会看到顶部通知栏的通知，并且图标右上角显示红色的1。然后你通过通知栏点进去，会启动app，然后你再看，通知栏没有这个通知了，但是，app图标的右上角的那个1还是在的。

所以，这段代码很简单，但是你重要的还是逻辑。我介绍一下我的逻辑，当然我只是一个菜鸟，你取其中自认为有价值的地方即可。

1 创建一个基类CCNotificationUtil，便于在C++代码中调用。这个我是放在cocos2d命名空间下的。这样在C++代码里面，需要增加通知的地方，比如你的建筑开始升级了，你收到服务器传来的升级时间，你只需要调用

cocos2d::CCNotificationUtil::shareNotificationUtil()->addNotification(str_Alert,notificatioTag,timesec);*/

其中的三个参数，分别是通知栏显示的内容，通知的key，从现在开始多长时间以后触发。再重复一下，只会触发一次。这个类里面还有一个removeNotification方法，这个就是你半路取消通知时需要调用的方法，参数是创建时传入的tag。比如你点了升级建筑，开始生了，一个小时后完成。过了半个小时，你觉得时间太长了，用钱加速吧，这个时候，就需要调用这个方法了，因为你之前已经加了通知，告诉IOS一个小时后提示，这个时候你就的从IOS的通知里面把它给去掉了，所以这个方法就是满足这个需求的。

 CCNotificationUtil.h代码：

 1 #ifndef _CC_NotificationUtil_H__
 2 #define _CC_NotificationUtil_H__
 3 
 4 #include "ccTypes.h"
 5 #include "ccTypeInfo.h"
 6 
 7 NS_CC_BEGIN
 8 class CC_DLL CCNotificationUtil : public TypeInfo
 9 {
10 protected:
11     CCNotificationUtil();
12     static CCNotificationUtil* s_sharedNotificationUtil;
13     int m_pIconBadgeNumber;
14 public:
15     virtual long getClassTypeInfo() {
16         static const long id = cocos2d::getHashCodeByString(typeid(cocos2d::CCNotificationUtil).name());
17         return id;
18     }
19     static CCNotificationUtil * shareNotificationUtil();
20     virtual ~CCNotificationUtil();
21     virtual bool addNotification(std::string alerttext,int notificationtag,int timeinterval);
22     virtual bool init();
23     virtual bool removeNotification(int notificationtag);
24 };
25 NS_CC_END
26 #endif // !_CC_NotificationUtil_H_

CCNotificationUtil.app代码

 1 #include "CCNotificationUtil.h"
 2 
 3 NS_CC_BEGIN
 4 
 5 CCNotificationUtil* CCNotificationUtil::s_sharedNotificationUtil = NULL;
 6 
 7 CCNotificationUtil::CCNotificationUtil()
 8     :m_pIconBadgeNumber(0)
 9 {
10 
11 }
12 CCNotificationUtil::~CCNotificationUtil()
13 {
14 
15 }
16 bool CCNotificationUtil::init()
17 {
18     return true;
19 }
20 bool CCNotificationUtil::addNotification(std::string alerttext,int notificationtag,int timeinterval)
21 {
22     return true;
23 }
24 bool CCNotificationUtil::removeNotification(int notificationtag)
25 {
26     return ( true );
27 }
28 
29 NS_CC_END

2 创建和IOS平台相关的子类。这个才是做实际操作的类，因为会使用Objective-C，所以这是个混编文件。在你的项目中和平台相关的文件夹platform/ios/下面创建CCNotificationUtilIOS类。其中传入的参数会有C++和Objective-C的相互转换。
CCNotificationUtilIOS.h

#ifndef _CC_NotificationUtilIOS_H__
#define _CC_NotificationUtilIOS_H__

#include "ccTypes.h"
#include "ccTypeInfo.h"
#include "CCNotificationUtil.h"
NS_CC_BEGIN
class CC_DLL CCNotificationUtilIOS: public CCNotificationUtil
{
public:
    // override function
    virtual bool addNotification(std::string alerttext,int notificationtag,int timeinterval);
    virtual bool init();
    virtual bool removeNotification(int notificationtag);
};
NS_CC_END
#endif //_CC_NotificationUtilIOS_H__

CCNotificationUtilIOS.mm

#import "cocos2d.h"


#include "CCNotificationUtil.h"
#include "CCNotificationUtilIOS.h"
NS_CC_BEGIN

CCNotificationUtil* CCNotificationUtil::shareNotificationUtil()
{
    if(s_sharedNotificationUtil== NULL)
    {
        s_sharedNotificationUtil = new CCNotificationUtilIOS();
        s_sharedNotificationUtil->init();
    }
    return s_sharedNotificationUtil;
}
bool CCNotificationUtilIOS::init()
{
    if(CCNotificationUtil::init()==true)
    {
        [[UIApplication sharedApplication] cancelAllLocalNotifications];
        return true;
    }
    return false;
}
bool CCNotificationUtilIOS::addNotification(std::string alerttext,int notificationtag,int mytimeinterval)
{
    if(CCNotificationUtil::addNotification(alerttext,notificationtag,mytimeinterval)==true)
    {
        UILocalNotification *notification=[[UILocalNotification alloc] init];
        if (notification!=nil) {
            NSDate *now = [NSDate date];
            notification.fireDate=[now dateByAddingTimeInterval:mytimeinterval];
            notification.timeZone=[NSTimeZone defaultTimeZone];
            notification.alertBody=[NSString stringWithUTF8String:alerttext.c_str()];
            notification.soundName= UILocalNotificationDefaultSoundName;
            notification.alertAction=NSLocalizedString([NSString stringWithUTF8String:alerttext.c_str()], nil);
            notification.applicationIconBadgeNumber = [[[UIApplication sharedApplication] scheduledLocalNotifications] count]+1;
            //add key
            NSDictionary *dict =[NSDictionary dictionaryWithObjectsAndKeys:[NSNumber numberWithInt:notificationtag],@"nfkey",nil];
            [notification setUserInfo:dict];
            [[UIApplication sharedApplication]   scheduleLocalNotification:notification];
            [notification release];
            return true;
        }
    }
    return false;
}
bool CCNotificationUtilIOS::removeNotification(int notificationtag)
{
    NSArray *narry=[[UIApplication sharedApplication] scheduledLocalNotifications];
    NSUInteger acount=[narry count];
    if (acount<1) {
        return false;
    }
    for (int i=0; i<acount; i++) {
        UILocalNotification *myUILocalNotification = [narry objectAtIndex:i];
        NSDictionary *userInfo = myUILocalNotification.userInfo;
        NSNumber *obj = [userInfo objectForKey:@"nfkey"];
        int mytag=[obj intValue];
        if (mytag==notificationtag) {
            [[UIApplication sharedApplication] cancelLocalNotification:myUILocalNotification];
            return true;
        }
    }
    return false;
}

NS_CC_END

特别注意的是设置右上角图标个数的代码，如下。就是说当我这个通知到时间时，显示的个数，应该是在我之前加入到通知schedule里面的数量，当然这个不是绝对的，比如你第一个通知是一个小时后提示，紧接这触发了第二个通知，而第二个是10分钟，显然10分钟通知提示时，右上角会显示2，但其实应该是1。这个问题需要考虑，后面第4步我会说我的解决方法。

 notification.applicationIconBadgeNumber = [[[UIApplication sharedApplication] scheduledLocalNotifications] count]+1;

 

 

3 因为我开的需求之前介绍过在Win32上调试的，所以需要一个win32平台实现的子类，保证编译通过，但实际上这个类什么也不做。如果你不需要在win32上调试，这步可以省略了。在ios平级目录win32下创建CCNotificationUtilWin32子类。

CCNotificationUtilWin32.h

#ifndef _CC_NotificationUtilWin32_H__
#define _CC_NotificationUtilWin32_H__
#include "platform/CCNotificationUtil.h"
#include "platform/CCPlatformMacros.h"
#include "ccTypes.h"
#include "ccTypeInfo.h"

NS_CC_BEGIN
    
/**
 * @addtogroup platform
 * @{
 */

//! @brief  Helper class to handle file operations
class CCNotificationUtilWin32 : public CCNotificationUtil
{
    friend class CCNotificationUtil;
    CCNotificationUtilWin32();
public:
    // override function
    virtual bool addNotification();
    virtual bool init();
    virtual bool removeNotification(int notificationtag);
};
NS_CC_END

    // end of platform group
    /// @}


#endif // !_CC_NotificationUtilWin32_H__

CCNotificationUtilWin32.app

#include "CCNotificationUtilWin32.h"
#include "platform/CCCommon.h"
#include <Shlobj.h>
NS_CC_BEGIN
CCNotificationUtil* CCNotificationUtil::shareNotificationUtil()
{
    if(s_sharedNotificationUtil== NULL)
    {
        s_sharedNotificationUtil = new CCNotificationUtilWin32();
        s_sharedNotificationUtil->init();
    }
    return s_sharedNotificationUtil;
}

CCNotificationUtilWin32::CCNotificationUtilWin32()
{
}

bool CCNotificationUtilWin32::init()
{
    return CCNotificationUtil::init();
}
bool CCNotificationUtilWin32::addNotification()
{
    return true;
}
bool CCNotificationUtilWin32::removeNotification(int notificationtag)
{
    return true;
}
NS_CC_END

4 一个右上角提示的问题。你触发了5个通知，后台运行的情况下，3个已经到了，所以你的app右上角此时显示3。那么你通过通知栏或者直接点app进去以后，app右上角应该变为0。按照之前在addNotification里面的设置，等到第4个通知到了以后，app右上角会显示4，第五个到了以后，会显示5，很明显这是不对的。所以我们需要在通过通知栏进去，或者直接点app进去以后，重新去设置第四个第五个通知到了以后，app右上角的数字。
这个当然也需要在混编文件中。我是在实现UIApplicationDelegate的混编文件中重写了两个方法didReceiveLocalNotification和applicationDidBecomeActive。

didReceiveLocalNotification是app在前台运行，通知时间到了，调用的方法。如果程序在后台运行，时间到了以后是不会走这个方法的。

applicationDidBecomeActive是app在后台运行，通知时间到了，你从通知栏进入，或者直接点app图标进入时，会走的方法。

里面的逻辑，就是找到所有加入schedule的通知，重新设置通知时间到时，app右上角的数字。

 

 1     - (void)applicationDidBecomeActive:(UIApplication *)application {
 2     /*
 3      Restart any tasks that were paused (or not yet started) while the application was inactive. If the application was previously in the background, optionally refresh the user interface.
 4      */
 5     //reset applicationIconBadgeNumber;
 6     application.applicationIconBadgeNumber=0;
 7     int count =[[[UIApplication sharedApplication] scheduledLocalNotifications] count];
 8     if(count>0)
 9     {
10         NSMutableArray *newarry= [NSMutableArray arrayWithCapacity:0];
11         for (int i=0; i<count; i++) {
12             UILocalNotification *notif=[[[UIApplication sharedApplication] scheduledLocalNotifications] objectAtIndex:i];
13             notif.applicationIconBadgeNumber=i+1;
14             [newarry addObject:notif];
15         }
16         [[UIApplication sharedApplication] cancelAllLocalNotifications];
17         if (newarry.count>0) {
18             for (int i=0; i<newarry.count; i++) {
19                 UILocalNotification *notif = [newarry objectAtIndex:i];
20                 [[UIApplication sharedApplication] scheduleLocalNotification:notif];
21             }
22         }
23     }
24     
25     cocos2d::CCDirector::sharedDirector()->resume();
26 }
27 - (void)application:(UIApplication *)application didReceiveLocalNotification:(UILocalNotification *)notification{
28     if (notification)
29     {
30         application.applicationIconBadgeNumber=0;
31         int count =[[[UIApplication sharedApplication] scheduledLocalNotifications] count];
32         if(count>0)
33         {
34             NSMutableArray *newarry= [NSMutableArray arrayWithCapacity:0];
35             for (int i=0; i<count; i++) {
36                 UILocalNotification *notif=[[[UIApplication sharedApplication] scheduledLocalNotifications] objectAtIndex:i];
37                 notif.applicationIconBadgeNumber=i+1;
38                 [newarry addObject:notif];
39             }
40             [[UIApplication sharedApplication] cancelAllLocalNotifications];
41             if (newarry.count>0) {
42                 for (int i=0; i<newarry.count; i++) {
43                     UILocalNotification *notif = [newarry objectAtIndex:i];
44                     [[UIApplication sharedApplication] scheduleLocalNotification:notif];
45                 }
46             }
47         }
48     }
49 }

5 我们在实现UIApplicationDelegate的混编文件中还要实现一个方法didFinishLaunchingWithOptions。这是程序首次启动时，会走的地方。在这里，我们需要设置app右上角的数字为0，并且要清空所有的本地通知。为什么？比如，还是你升那个1小时的建筑，你点了以后，然后kill掉app了，但是那个通知已经放到本地了。然后你重新启动了程序，你收到服务器来的数据，显示建筑还有30分钟才到，你又给本地加了一个Notification。这样的话，你在30分钟和一个小时后，都会收到通知，这个肯定不会的吧。所以，加入这两行代码就可以了。

当然也有一种解决方法时，你加入的时候根据tag判断一下，如果有了，删除，重加。只是这个个人感觉比较麻烦，也不通用。

   // about notification
    application.applicationIconBadgeNumber = 0;
    [[UIApplication sharedApplication] cancelAllLocalNotifications];

好了，这就大功告成了。