P3383: [Usaco2004 Open]Cave Cows 4 洞穴里的牛之四

这个系列总算是做完了，这是我第一次高效率做完四道题，虽然中间有两道水题，但是第一和第四题还是蛮好的，但是只要能想到思路就很快能打完的。

像这道题，刚开始在想能不能用DP？但是苦于不知道怎么实施，后来又想，这么多点，有点像最短路径，但是总共有50000个点，边数有可能N*N吗？

于是我拿起笔算了一下，发现连边的话，先按X轴由小到大排序一遍，然后往后找 X 比当前点大 <=2 的 X，再通过比较 Y 之间的关系，只要相差不超过 2 就连接一条双向边，这样后面的点就不需要往前找了，但有人会问，会不会是 50001*25000 而超时呢？我也想过，但是发现根本不可能，因为一个点最多能连接24条边，儿往后最多能找到14个点，也就是时间最多也就 50000*14 而事实上，这也是根本不可能达到的。所以我们连好边后做一遍 spfa 就行了。

const maxn=50001;
type
  node=record
    f,t:longint;
  end;
  position=record
    x,y:longint;
  end;
var n,t,i,j,num,now,ans:longint;
b:array[0..750000] of node;
d,head:array[0..50001] of longint;
pos:array[0..50001] of position;
p:array[0..50001] of boolean;
f:array[0..5000000] of longint;
procedure qs(t,w:longint);
var l,r,mid:longint;
tem:position;
begin
  l:=t; r:=w; mid:=pos[(l+r) shr 1].x;
  repeat
    begin
      while pos[l].x<mid do inc(l);
      while pos[r].x>mid do dec(r);
      if l<=r then
        begin
          tem:=pos[l];
          pos[l]:=pos[r];
          pos[r]:=tem;
          inc(l);
          dec(r);
        end;
    end;
  until l>r;
  if t<r then qs(t,r);
  if l<w then qs(l,w);
end;
procedure spfa;
var l,r,now,nowe:longint;
begin
  fillchar(p,sizeof(p),true);
  for l:=1 to n do d[l]:=maxn;
  l:=1; r:=1; f[1]:=0; d[0]:=0; p[0]:=false;
  while l<=r do
    begin
      now:=f[l];
      nowe:=head[now];
      while nowe<>0 do
        begin
           if d[now]+1<d[b[nowe].t] then
             begin
               d[b[nowe].t]:=d[now]+1;
               if p[b[nowe].t] then
                 begin
                   p[b[nowe].t]:=false;
                   inc(r);
                   f[r]:=b[nowe].t;
                 end;
             end;
           nowe:=b[nowe].f;
        end;
      inc(l);
      p[now]:=true;
    end;
end;
procedure insert(f,t:longint);
begin
  inc(num);
  b[num].f:=head[f];
  b[num].t:=t;
  head[f]:=num;
end;
begin
  readln(n,t);
  for i:=1 to n do
    with pos[i] do readln(x,y);
  qs(1,n);
  pos[0].x:=0; pos[0].y:=0;
  for i:=0 to n-1 do
    begin
      now:=i+1;
      while (pos[now].x-pos[i].x<=2) and (now<=n) do
        begin
          if abs(pos[now].y-pos[i].y)<=2 then
            begin
              insert(i,now);
              insert(now,i);
            end;
          inc(now);
        end;
    end;
  spfa;
  ans:=maxn;
  for i:=1 to n do
    if (ans>d[i]) and (pos[i].y=t) then ans:=d[i];
  if ans<>maxn then writeln(ans)
    else writeln(-1);
end.

   (转载请注明出处：http://www.cnblogs.com/Kalenda/)