AS3获取SWF文件中AS链接

游戏中经常使用到SWF美术，但SWF文件中，会有多个元件，每个元件对应一个指定AS链接，一个元件还会有多个图层。在实际操作中，会出现要求显示一个指定元件，并在该动画资源中，有的动画要求加鼠标事件，有的则不加任何事件，即指定图层的调用。既要求过场动画的欢洽，又要求交互事件的鼠标点击时的动画效果以及配音，这里提供一个简单范例，实现代码如下：

SWF文件加载类，LoaderSwf：

package  
{  
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.MovieClip;
    import flash.display.SimpleButton;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.system.LoaderContext;

    // 参考网址：http://blog.csdn.net/jrg_2008/article/details/49496185
    
    [SWF(frameRate='25',width="1280", height="793")]
    public class LoaderSwf extends Sprite  
    {  
        private var _MovLoader:Loader;    //    加载swf文件  
        private var _Skin:MovieClip;    //    指定AS链接  
        private var _audio:VoicePlay = new VoicePlay();
        private var _xmlList:XmlProject = new XmlProject();
        private var count:int = 0;

        
        //构造函数  
        public function LoaderSwf()  
        {  
            loadMcSWF();
        }  
        
        //加载swf  
        private function loadMcSWF():void  
        {  
            _MovLoader = new Loader;  
             
            /*    新建应用程序域    */  
            var context:LoaderContext = new LoaderContext();  
            context.applicationDomain = new ApplicationDomain();  
            
            /*    开始加载swf      */  
            _MovLoader.load(new URLRequest("U2_amazed.swf"),context); 
            
            /*    添加事件响应，在swf加载完毕后再获取里面的资源        */  
            _MovLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,onComplete); 
        }  
        
        private function onComplete(e:Event):void  
        {  
            /*    获得加载器的应用程序域    */  
            var domain:ApplicationDomain = (e.currentTarget as LoaderInfo).applicationDomain;
            
            /*    获取指定（b3u3p2_1a）的AS链接的影片剪辑  */  
            var cls:Class = domain.getDefinition("b3u2p2_1a") as Class;  
            _Skin = new cls() as MovieClip;  
            _Skin.x = 140;
            _Skin.y = 0;
            _Skin.addEventListener(Event.ENTER_FRAME,onFrame);
            
            _Skin.addFrameScript(100,function():void
            {
                // 第一种调用图层写法
                var myChildMc_0 : MovieClip = _Skin.getChildByName("myChildMc_0") as MovieClip;
                //    添加点击事件
                myChildMc_0.addEventListener(MouseEvent.CLICK,onClick);
                myChildMc_0.buttonMode = true; 
                
                // 第二种调用图层写法
                var myChildMc_1 : MovieClip = _Skin["myChildMc_1"] as MovieClip;
                myChildMc_1.addEventListener(MouseEvent.CLICK,onClick);
                myChildMc_1.buttonMode = true; 
                _Skin.stop();
            })
            
            addChild(_Skin);  
            
        }  
        
        
        /**
         *     点击播放动画，并播放配音
         * @param e
         * 
         */        
        public function onClick(e:MouseEvent):void
        {
            var myclickMc:MovieClip  = e.currentTarget as MovieClip;
            var soundnum:int = myclickMc.name.split('_')[1];
            _audio.init(soundnum);
            myclickMc.gotoAndPlay(2);
        }
        
        
        /**
         *开场动画时，指定帧播放对应配音 
         * @param e
         * 
         */        
        public function onFrame(e:Event):void
        {
            if(_xmlList.FrameDict[count])
            {
                _audio.init(_xmlList.FrameDict[count]);
            }
            count++;
        }
        
    }  
}  

配音控制类，VoicePlay：

package
{
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;

    
    /**
     *    声音控制类 
     * @ add hunter
     * 
     */    
    public class VoicePlay extends Sprite
    {
        public var arr:Array = ['audio/are you ok.mp3','audio/Yes, I am. I’m amazed.mp3'];
        public function VoicePlay()
        {
        }
        
        public function init(count:int):void
        {
            var snd:Sound = new Sound(new URLRequest(arr[count]));
            snd.play();
        }
        
    }
}

过场动画配音播放帧类，XmlProject：

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.utils.Dictionary;
    
    
    /**
     * 播放序列帧对应的配音
     * @author 
     * 
     */    
    public class XmlProject extends Sprite
    {
        public var FrameDict:Dictionary = new Dictionary();
        public function XmlProject()
        {
            var xmlLoad:URLLoader = new URLLoader(new URLRequest("PlayList.xml"));
            xmlLoad.addEventListener(Event.COMPLETE,XMLloaded);
        }
        
        // 在Dictionary存储数据，播放配音对应帧数，以及帧对应的配音编号
        public function XMLloaded(e:Event):void
        {
            var myxml:XML = new XML(e.currentTarget.data);
            trace(myxml);
            for(var i:int=0;i<myxml.frame.length();i++)
            {
                trace("@n = " + myxml.frame[i].@n + ", event = " + myxml.frame[i].@event);
                FrameDict[int(myxml.frame[i].@n)]=myxml.frame[i].@event;
            }

        }
        
    }
}

过场动画配音xml表，PlayList：

<play>
    <frame n="43" event="0"></frame>    
    <frame n="86" event="1"></frame>
</play>