算法模板——计算几何2（二维凸包——Andrew算法）

实现功能：求出二维平面内一对散点的凸包（详见Codevs 1298）

很神奇的算法——先将各个点按坐标排序，然后像我们所知的那样一路左转，求出半边的凸包，然后反过来求另一半的凸包

我以前正是因为总抱着想一步到位的想法，所以每次都跪得很惨（HansBug：事实上这次是我这辈子第一次A掉凸包题）

然后别的没了，就是凸包的基本思想

（顺便输出凸包周长C和面积S）

type arr=array[0..100005] of longint;
var
   i,j,k,l,m,n,m1,m2:longint;
   a:array[0..100005,1..2] of longint;
   b,c,d:arr;ans,are:extended;
procedure swap(var x,y:longint);
          var z:longint;
          begin
               z:=x;x:=y;y:=z;
          end;
procedure sort(l,r:longint);
          var i,j,x,y:longint;
          begin
               i:=l;j:=r;x:=a[(l+r) div 2,1];y:=a[(l+r) div 2,2];
               repeat
                     while (a[i,1]<x) or ((a[i,1]=x) and (a[i,2]<y)) do inc(i);
                     while (a[j,1]>x) or ((a[j,1]=x) and (a[j,2]>y)) do dec(j);
                     if i<=j then
                        begin
                             swap(a[i,1],a[j,1]);
                             swap(a[i,2],a[j,2]);
                             inc(i);dec(j);
                        end;
               until i>j;
               if i<r then sort(i,r);
               if l<j then sort(l,j);
          end;
function right(x1,y1,x2,y2:longint):boolean;
         begin
              exit((x1*y2)>(x2*y1));
         end;
function trip(x1,y1,x2,y2,x3,y3:longint):boolean;
         begin
              exit(right(x2-x1,y2-y1,x3-x2,y3-y2));
         end;
function check(x,y,z:longint):boolean;
         begin
              exit(trip(a[x,1],a[x,2],a[y,1],a[y,2],a[z,1],a[z,2]));
         end;
procedure doit(var b:arr;var m:longint);
          begin
               b[1]:=d[1];b[2]:=d[2];j:=2;
               for i:=3 to n do
                   begin
                        while (j>1) and not(check(b[j-1],b[j],d[i])) do dec(j);
                        inc(j);b[j]:=d[i];
                   end;
               m:=j;
          end;
begin
     readln(n);
     for i:=1 to n do readln(a[i,1],a[i,2]);
     sort(1,n);j:=1;
     for i:=2 to n do  //去重
         begin
              if (a[i,1]<>a[j,1]) or (a[i,2]<>a[j,2]) then
                 begin
                      inc(j);
                      a[j,1]:=a[i,1];a[j,2]:=a[i,2];
                 end;
         end;
     n:=j;
    //求凸包
     for i:=1 to n do d[i]:=i;doit(b,m1);
     for i:=1 to n do d[i]:=n+1-i;doit(c,m2);
    //两个半边整合
     for i:=1 to m1 do d[i]:=b[i];
     for i:=2 to m2 do d[i+m1-1]:=c[i];
    //开始计算周长+面积
     m:=m1+m2-2;ans:=0;are:=0;
     for i:=1 to m do ans:=ans+sqrt(sqr(a[d[i],1]-a[d[i+1],1])+sqr(a[d[i],2]-a[d[i+1],2]));  //周长
     for i:=1 to m do are:=are+a[d[i],1]*a[d[i+1],2]-a[d[i],2]*a[d[i+1],1];  //面积
     are:=abs(are)/2;
     writeln('Convex Hull:');
     for i:=1 to m do writeln(a[d[i],1],' ',a[d[i],2]);
     writeln('C = ',ans:0:1);
     writeln('S = ',are:0:1);
     readln;
end.