1734: [Usaco2005 feb]Aggressive cows 愤怒的牛

1734: [Usaco2005 feb]Aggressive cows 愤怒的牛

Time Limit: 5 Sec  Memory Limit: 64 MB
Submit: 217  Solved: 175
[Submit][Status][Discuss]

Description

Farmer John has built a new long barn, with N (2 <= N <= 100,000) stalls. The stalls are located along a straight line at positions x1,...,xN (0 <= xi <= 1,000,000,000). His C (2 <= C <= N) cows don't like this barn layout and become aggressive towards each other once put into a stall. To prevent the cows from hurting each other, FJ want to assign the cows to the stalls, such that the minimum distance between any two of them is as large as possible. What is the largest minimum distance?

农夫 John 建造了一座很长的畜栏，它包括NN (2 <= N <= 100,000)个隔间，这些小隔间依次编号为x1,...,xN (0 <= xi <= 1,000,000,000). 但是，John的C (2 <= C <= N)头牛们并不喜欢这种布局，而且几头牛放在一个隔间里，他们就要发生争斗。为了不让牛互相伤害。John决定自己给牛分配隔间，使任意两头牛之间的最小距离尽可能的大，那么，这个最大的最小距离是什么呢

Input

* Line 1: Two space-separated integers: N and C * Lines 2..N+1: Line i+1 contains an integer stall location, xi

第一行：空格分隔的两个整数N和C

第二行---第N+1行：i+1行指出了xi的位置

Output

* Line 1: One integer: the largest minimum distance

第一行：一个整数，最大的最小值

Sample Input

5 3
1
2
8
4
9

Sample Output

3

把牛放在1，4，8这样最小距离是3

HINT

 

Source

Gold

 

题解：一道经典的二分答案题，对于可行的解的可能范围进行二分求最大合法值，然后再check函数里面采取的是 $O\left(N \right)$ 的判断法，最坏情况下将会将整个数列跑一遍，这样一来复杂度为 $O\left(N\log \frac{X_N-X_1}{C-1} \right)$ ，于是这样子就A掉了

实际上更好的办法是在check里面再套一个二分查找数字，实际效果将强于直接跑，复杂度 $O\left(C\log N \log \frac{X_N-X_1}{C-1} \right)$

 

/**************************************************************
    Problem: 1734
    User: HansBug
    Language: Pascal
    Result: Accepted
    Time:140 ms
    Memory:616 kb
****************************************************************/
 
var
   i,j,k,l,m,n,r:longint;
   a:array[0..100000] of longint;
procedure sort(l,r:longint);
          var i,j,x,y:longint;
          begin
               i:=l;j:=r;x:=a[(l+r) div 2];
               repeat
                     while a[i]<x do inc(i);
                     while a[j]>x do dec(j);
                     if i<=j then
                        begin
                             y:=a[i];a[i]:=a[j];a[j]:=y;
                             inc(i);dec(j);
                        end;
               until i>j;
               if i<r then sort(i,r);
               if l<j then sort(l,j);
          end;
function check(x:longint):boolean;
         var i,j,k,l:longint;
         begin
              a[0]:=-x-1;l:=0;j:=0;
              for i:=1 to n do
                  begin
                       if (a[i]-a[l])>=x then
                          begin
                               inc(j);
                               if j>=m then exit(true);
                               l:=i;
                          end;
                  end;
              exit(false);
         end;
begin
     readln(n,m);
     for i:=1 to n do readln(a[i]);
     sort(1,n);
     l:=0;r:=(a[n]-a[1]) div (m-1);
     while l<r do
           begin
                k:=(l+r+1) div 2;
                if check(k) then
                   l:=k
                else
                    r:=k-1;
           end;
     writeln(l);
     readln;
end.