算法模板——并查集 2（支持快速即时查询本连通块内容，纯原创！）

实现功能：输入N，现在有N个数；接下来输入任意行，如果是"1 x y"则表示把x和y所在的块合并；如果是"2 x"则表示输出x所在的块的全部内容

原理：其实主要是自己创造了一个可并链line，he表示链头，ta表示链尾，然后对于不同块之间的合并就是直接把两条链对接，也就是一个的尾巴接到另一个的头上，构成新链（由于是链的直接叠加，所以可以做到严格的O(1)，并且输出时输出多少复杂度就是多少，完全不存在额外复杂度）。然后同时用原本的普通数组并查集进行维护和追踪（理论值为O(logn)但实际上由于c[x]:=getfat(c[x])的优化导致实际测试结果远远小于这一复杂度）

复杂度：【合并操作O(1),查询O(块大小)（意味着复杂度几乎完全用来输出）】×N，相比于之前的算法对于即时处理的性能有所提高，但是只需要最终进行静态的全局处理时，两者差不太多，这个会略快些，传统程序代码略少些

（PS：值得注意的是，这种新的数据结构中千万要特判两个数字处于同一块的情况，必须避免同一条链首尾相接导致产生环！！！本程序41行continue那里有所体现。同时c[x]:=y之类的合并块语句以及merge(x,y)操作是有顺序之分的，两者顺序必须保持一致，不想原来的并查集顺序任意）

 

type
    point=^node;
    node=record
               g:longint;
               next:point;
    end;
    line=record
               he,ta:point;
    end;
var
   a:array[0..100000] of line;
   c:array[0..100000] of longint;
   i,j,k,l,m,n:longint;
   p:point;
procedure merge(var p1,p2:line);inline;
          begin
               p1.ta^.next:=p2.he;
               p1.ta:=p2.ta;
               p2.he:=nil;p2.ta:=nil;
          end;
function getfat(x:longint):longint;inline;
         begin
              if x<>c[x] then c[x]:=getfat(c[x]);
              exit(c[x]);
         end;
begin
     readln(n);
     for i:=1 to n do
         begin
              c[i]:=i;
              new(p);p^.g:=i;p^.next:=nil;
              a[i].he:=p;a[i].ta:=p;
         end;
     while true do
           begin
                read(l);
                case l of
                     1:begin
                            readln(j,k);
                            j:=getfat(j);k:=getfat(k);
                            if j=k then continue;
                            c[k]:=j;
                            merge(a[j],a[k]);
                     end;
                     2:begin
                            readln(j);
                            j:=getfat(j);
                            p:=a[j].he;
                            while p<>nil do
                                  begin
                                       write(p^.g,' ');
                                       p:=p^.next;
                                  end;
                            writeln;
                     end;
                end;

           end;
end.