算法模板——左偏树（可并堆）

实现的功能——输入1 x，将x加入小根堆中；输入2，输出最小值并去在堆中除掉

实现原理——左偏树，这里面维护的是一个小根堆，个人认为其还是没有发挥出左偏树的真正威力——其真正威力在于堆与堆之间可以直接合并，而且复杂度仅为O(logN)，在零散插入元素时可以采用本程序中一个个加入的方法，但是当有些题目中预处理多个元素时，则建议通过队列进行合并（别忘了堆与堆之间可以直接合并哦～～～），这样子快一点（详见：《左偏树的特点及其应用》By黄源河），代码量嘛，估计是这几棵常用树里面最短的了，都快和最小生成树差不多了，甚至还可以更短

var
   i,j,k,l,m,n,head:longint;
   a,lef,rig,fix:array[0..100000] of longint;
function min(x,y:longint):longint;inline;
         begin
              if x<y then min:=x else min:=y;
         end;
function max(x,y:longint):longint;inline;
         begin
              if x>y then max:=x else max:=y;
         end;
procedure swap(var x,y:longint);inline;
          var z:longint;
          begin
               z:=x;x:=y;y:=z;
          end;
procedure merge(var x,y:longint);
          begin
               if x=0 then swap(x,y);
               if y=0 then exit;
               if a[x]>a[y] then swap(x,y);
               merge(rig[x],y);
               fix[x]:=min(fix[lef[x]],fix[rig[x]])+1;
               if fix[lef[x]]<fix[rig[x]] then swap(lef[x],rig[x]);
          end;
function cuthead(var x:longint):longint;
         var a1:longint;
          begin
               a1:=a[x];
               merge(lef[x],rig[x]);
               x:=lef[x];
               exit(a1);
          end;
begin
     readln(n);m:=0;head:=0;
     for i:=1 to n do
         begin
              read(j);
              case j of
                   1:begin
                          readln(k);
                          inc(m);a[m]:=k;l:=m;
                          merge(head,l);
                   end;
                   2:begin
                          readln;
                          writeln(cuthead(head));
                   end;
              end;
         end;
end.