混乱的奶牛（mix up2）

http://61.187.179.132/JudgeOnline/problem.php?id=1231

问题描述

Farmer John的N(4 <= N <= 16)头奶牛中的每一头都有一个唯一的编号S_i(1 <= S_i <= 25,000). 奶牛为她们的编号感到骄傲, 所以每一头奶牛都把她的编号刻在一个金牌上, 并且把金牌挂在她们宽大的脖子上. 奶牛们对在挤奶的时候被排成一支\"混乱\"的队伍非常反感. 如果一个队伍里任意两头相邻的奶牛的编号相差超过K (1 <= K <= 3400), 它就被称为是混乱的. 比如说，当N = 6, K = 1时,1, 3, 5, 2, 6, 4 就是一支\"混乱\"的队伍, 但是 1, 3, 6, 5, 2, 4 不是(因为5和6只相差1).那么, 有多少种能够使奶牛排成\"混乱\"的队伍的方案呢?
数据输入

* 第 1 行: 用空格隔开的两个整数N和K* 第 2..N+1 行: 第i+1行包含了一个用来表示第i头奶牛的编号的整数: S_i
数据输出

* 第 1 行: 只有一个整数, 表示有多少种能够使奶牛排成\"混乱\"的队伍的方案. 答案保证是 一个在64位范围内的整数.
样例



input output

4 1
3
4
2
1

解析：
数据范围只有16，因此不是搜索就是状态压缩。如果是搜索，那么就需要枚举所有的排列方式，一定超时。所以考虑状态压缩，总共16个数字，用二进制表示，最多才有2^16=65536种状态。用f[I,j]表示i的状态下，最后一位排列的数字是第j大的数字时的方案，那么状态的转移之和最后两位有关，因为前面的一定符合要求，所以枚举后两位，如果满足条件就inc(f[I,j])

program haha;
var
   n,i,j,k,m,tot : longint;
   f         : array[0..70000,0..25] of int64;
   a,d         : array[1..20] of longint;
procedure swap(var x,y: longint);
var
   t : longint;
begin
   t:=x;
   x:=y;
   y:=t;
end; { swap }
procedure init;
begin
   readln(n,m);
   for i:=1 to n do
      readln(a[i]);
   for i:=1 to n-1 do
      for j:=i+1 to n do
     if a[i]<a[j] then
        swap(a[i],a[j]);
end; { init }
function dp(x,y    : Longint ):int64;
var
   i,j,k: longint;
begin
   if f[x,y]>=0 then exit(f[x,y]);
   dp:=0;
   for i:=1 to n do
      if 1<<(i-1) and x<>0 then
     if abs(a[y]-a[i])>m then
        dp:=dp+dp(x-1<<(y-1),i);
   f[x,y]:=dp;
   exit(dp);
end;
procedure print;
var
   ans : int64;
begin
   fillchar(f,sizeof(f),130);
   for i:=1 to n do
      f[1<<(i-1),i]:=1;
   ans:=0;
   for i:=1 to n do
      inc(ans,dp(1<<n-1,i));
   writeln(ans);
end; { print }
begin
   init;
   print;
end.