【BZOJ1030】[JSOI2007]文本生成器

...其实暑假的时候写过一次，不过那时候对这道题理解不是很深，所以重写了一遍....

尝试用新的模版去写，然后发现新的模版里面我把fail并到next，以省去多次的while取点，但是对于这道题，fail是必须用到的，因为要DP...所以不能并进去...于是只能乖乖滚回去写原来的方法，每次都去往回while fail节点...然后就是pd数组的传递，要和fail所连的点保持一直，因为是BFS下来的...

然后...代码如下

const maxn=6419;
 maxs=25;
 vv=10007;
var
 next:array[0..maxn,0..maxs] of longint;
 pd:array[0..maxn] of boolean;
 f:array[0..maxn] of longint;
 q:array[0..maxn] of longint;
 dp:array[0..maxn,0..105] of longint;
 s:string;
 head,tail,root,n,m,tot:longint;

procedure push(x:longint); begin inc(tail); q[tail]:=x; end;

function new:longint;
var i:longint;
begin
 pd[tot]:=false;
 for i:= 0 to maxs do next[tot,i]:=-1;
 inc(tot); exit(tot-1);
end;

procedure insert(s:string);
var c,i,v:longint;
begin
 v:=root;
 for i:= 1 to length(s) do
  begin
   c:=ord(s[i])-65;
   if next[v,c]=-1 then next[v,c]:=new;
   v:=next[v,c];
  end;
 pd[v]:=true;
end;

procedure build;
var v,tmp,i:longint;
begin
 f[root]:=root;
 head:=1; tail:=0;
 for i:= 0 to maxs do
  if next[root,i]<>-1 then
    begin f[next[root,i]]:=root; push(next[root,i]); end;
 while head<=tail do
  begin
   v:=q[head]; inc(head);
   for i:= 0 to maxs do
    if next[v,i]<>-1 then
     begin
      push(next[v,i]);
      tmp:=f[v];
      while (tmp<>root) and (next[tmp,i]=-1) do tmp:=f[tmp];
      if next[tmp,i]<>-1 then tmp:=next[tmp,i];
      if tmp=-1 then f[next[v,i]]:=root else f[next[v,i]]:=tmp;
      if not pd[next[v,i]] then pd[next[v,i]]:=pd[tmp];
     end;
  end;
end;

procedure solve;
var i,j,k,v,cnt,ans:longint;
begin
 dp[0,0]:=1;
 for i:= 1 to m do
  for j:= root to tot do
   if (not pd[j]) and (dp[j,i-1]>0) then
    for k:= 0 to maxs do
     begin
      v:=j;
      while (next[v,k]=-1) and (v<>root) do v:=f[v];
      if next[v,k]<>-1 then v:=next[v,k];
      if not pd[v] then dp[v,i]:=(dp[v,i]+dp[j,i-1]) mod vv;
     end;
 cnt:=0;
 for i:= 0 to tot do cnt:=(cnt+dp[i,m]) mod vv;
 ans:=1;
 for i:= 1 to m do ans:=(ans*26) mod vv;
 ans:=(((ans-cnt) mod vv+vv) mod vv);
 writeln(ans);
end;

procedure init;
var i:longint;
begin
 readln(n,m);
 root:=new;
 for i:= 1 to n do
  begin
   readln(s);
   insert(s);
  end;
 build;
end;

Begin
 init;
 solve
End.