bzoj1016[JSOI2008]最小生成树计数

Description

　　现在给出了一个简单无向加权图。你不满足于求出这个图的最小生成树，而希望知道这个图中有多少个不同的最小生成树。（如果两颗最小生成树中至少有一条边不同，则这两个最小生成树就是不同的）。由于不同的最小生成树可能很多，所以你只需要输出方案数对31011的模就可以了。

Input

　　第一行包含两个数，n和m，其中1<=n<=100; 1<=m<=1000; 表示该无向图的节点数和边数。每个节点用1~n的整数编号。接下来的m行，每行包含两个整数：a, b, c，表示节点a, b之间的边的权值为c，其中1<=c<=1,000,000,000。数据保证不会出现自回边和重边。注意：具有相同权值的边不会超过10条。

Output

　　输出不同的最小生成树有多少个。你只需要输出数量对31011的模就可以了。

Sample Input

4 6
1 2 1
1 3 1
1 4 1
2 3 2
2 4 1
3 4 1

Sample Output

8

 

 

 

诶这题不大好理解。

直接把题解复制上来啦：

 

发现最小生成树的形态是固定的。

即如果有一颗最小生成树，则所有最小生成树所使用的相同权值的边的数量是一样的，并且每次构出的点都是一样的。

就是说每次都是相同的点被相同权值的边给连接起来。这个简单的证明就是如果有不同权值的边连上的相同的点，那么一定会有更优的生成树。

 

于是知道了这两个性质这题就很好搞了，排序之后先做一遍最小生成树，得出了每种权值所用的边的数量，然后打一个大暴力，枚举相同权值的边，然后并查集暴力判环，得出某种边权值的边的选择方案，然后乘法原理统计答案，组合数效率，因为相同权值的边最多有10条，所以最坏效率是20个C(10,5)，发现效率是很OK的，如果不用并查集判环，复杂度就是满的，判环相当于大量剪枝，于是发现实际上暴力根本达不到满复杂度的效率，大量数据直接0.015s秒出。

 

P.S. 请注意判没有生成树的情况。

 

program award(input,output);
const
  cs=31011;
var
  father:array[0..110]of longint;
  a,b,w,l,r,num:array[0..1010]of longint;
  n,m,i,j,cnt,x,y,ans:longint;
procedure sort(q,h:longint);
var
  i,j,x,t:longint;
begin
   i:=q;j:=h;x:=w[(i+j)>>1];
  repeat
    while w[i]<x do inc(i);
    while x<w[j] do dec(j);
    if i<=j then
       begin
         t:=a[i];a[i]:=a[j];a[j]:=t;
         t:=b[i];b[i]:=b[j];b[j]:=t;
         t:=w[i];w[i]:=w[j];w[j]:=t;
         inc(i);dec(j);
       end;
   until i>j;
   if j>q then sort(q,j);
   if i<h then sort(i,h);
end;
function find(k:longint):longint;
begin
   if father[k]=k then exit(k) else exit(find(father[k]));
end;
procedure dfs(k,s:longint);
var
  x,y:longint;
begin
   if k=r[i]+1 then begin if s=num[i] then inc(j);exit; end;
   x:=find(a[k]);y:=find(b[k]);
   if x<>y then
      begin
         father[x]:=y;
         dfs(k+1,s+1);
         father[x]:=x;
      end;
   dfs(k+1,s);
end;
begin
   assign(input,'award.in');assign(output,'award.out');reset(input);rewrite(output);
   readln(n,m);
   for i:=1 to m do readln(a[i],b[i],w[i]);
   sort(1,m);
   for i:=1 to n do father[i]:=i;
   w[0]:=0;j:=0;cnt:=0;
   fillchar(num,sizeof(num),0);
   for i:=1 to m do
      begin
         if w[i]<>w[i-1] then begin r[cnt]:=i-1;inc(cnt);l[cnt]:=i; end;
         x:=find(a[i]);y:=find(b[i]);
         if x<>y then begin father[x]:=y;inc(num[cnt]);inc(j); end;
      end;
   r[cnt]:=m;
   if j<n-1 then begin write(0);close(input);close(output);halt; end;
   ans:=1;
   for i:=1 to n do father[i]:=i;
   for i:=1 to cnt do
      begin
         j:=0;
         dfs(l[i],0);
         ans:=ans*j mod cs;
         for j:=l[i] to r[i] do
            begin
               x:=find(a[j]);y:=find(b[j]);
               if x<>y then father[x]:=y;
            end;
      end;
   write(ans);
   close(input);close(output);
end.