bzoj1879: [Sdoi2009]Bill的挑战(codevs2308)(luoguP2167) 状压dp

唔...懒兔子来写博客了...

点我看题

这题的话...我想了很久但是都不是可行解

刚开始想预处理任意两个串是否可以匹配然后在乱搞，后来发现完全不会写...

然后按照惯例，我会看题解认真的思考...

唔...其实看完题解貌似这题还挺容易的？

我们可以预处理一个数组 g[i,j] 表示 在这 n 个串中前 i 个字符且第 i 个字符匹配为 j (j 是一个字符) 时的一个状态。

这个状态为一个长度为n的 2进制数转为10进制。比如 111 这个状态指 1 串和2 串和 3 串都是可以匹配的。

这个数组就是这个作用。

辣它可以干什么捏。

我萌进入dp部分。

设 f[i,j] 表示 每个串前 i 个字符 状态为 j 的方案数。

初始化就是 f[0,1 << n-1]=1

答案就是 sum(f[n,j]) 这里的 j 状态要满足 二进制1 的个数为 k。

j 这个状态指 n 个串中选了哪些串。

f[i,j & g[i,x]+=f[i-1,j]

 枚举一个 x 字符，对于 ‘a’-‘z’ 这些字符都可以是第 i 位的。

然后枚举前继状态 j  辣么 对于要更新的状态就是    j & g[i,x] 

为什么是&？  因为如果能转移到的必须要满足   g[i,x] 中能匹配这个串 同时前继状态也要有。

而 & 就是只有两个都是1 的时候才为 1 ，所以 & 后就是可以转移的一个状态。

这样打完之后捏，我兴高采烈的交了上去。TLE！！！

算了一下效率，似乎是卡着的呀QAQ 

怀疑兔生的我优化了常数，以为是常数的锅。

结果还是 TLE！ TLE！TLE！

然后怀疑兔生的又看了一次题解 开始思考原因

发现题解里加了优化的QAQ 但是并没有说...

所以要加一个优化咯。

这样考虑对于 f[i-1,j]=0 的情况 实际上可以不去转移，这样可以省掉很多时间。

const HR=1000003;
var s:string;
    i,j,x:longint;
    g:array[0..55,0..26]of longint;
    t,n,k:longint;
    f:array[0..55,0..35000]of longint;
    num:array[0..35000]of longint;
    len:longint;
    ans:longint;
function check(x:longint):longint;
var i,num:longint;
begin
  num:=0;
  for i:=1 to 15 do
  if (1 << (i-1))and x>0 then inc(num);
  exit(num);
end;
begin
  read(t);
  for i:=0 to (1 << 15)-1 do
  num[i]:=check(i);
  while t>0 do
  begin
    dec(t);
    ans:=0;
    readln(n,k);
    for i:=1 to n do
    begin
      readln(s);
      if i=1 then len:=length(s);
      for j:=1 to len do
        for x:=0 to 25 do
        if ((ord(s[j])-97)=x)or(s[j]='?') then
          g[j,x]:=g[j,x] or (1 << (i-1));
    end;
    f[0,(1 << n)-1]:=1;
    for i:=1 to len do
    begin
      for j:=0 to (1 << n)-1 do
      if f[i-1,j]<>0 then
      begin
        for x:=0 to 25 do
        begin
          inc(f[i,(g[i,x] and j)],f[i-1,j]);
          if f[i,(g[i,x] and j)]>=HR then
            f[i,(g[i,x] and j)]:=f[i,(g[i,x] and j)] mod HR;
        end;
        f[i-1,j]:=0;
      end;
      if i=len then
      begin
        for j:=0 to (1 << n)-1 do
        begin
          if num[j]=k then
          begin
            inc(ans,f[len,j]);
            if ans>=HR then ans:=ans mod HR;
          end;
          f[i,j]:=0;
        end;
      end;
    end;
    for i:=1 to len do
    for x:=0 to 25 do
    g[i,x]:=0;
    writeln(ans);
  end;
end.

代码巨丑...懒兔子懒得弄好看点了QAQ