兄弟不才，斗胆修正一下邹建大哥的一个算法。
原文的连接：http://blog.csdn.net/zjcxc/archive/2003/12/29/20075.aspx
原文中的最终方法3非常完美，但是我在调试时还是发现有点问题，会产生一个错误“Incorrect syntax near '+'”。
起因：不做任何修改可以正常执行。当我把“set @i=7800/@i”修改成了“set @i=260/@i”，只是随便试一下，想看看gid的不同变化（呵呵，挺无聊的想法），但是问题就出现了，产生了前面说的错误。经过一番调试，终于纠出了错误原因。
原因：关键就在while循环内的最后一句“ ,@sql4=@sql4+',@'+@ic”，不应该用逗号连接每个变量，这导致最后执行时无法把每个Case子句正确连接起来。
修正：要改2处：关键是应该用加号连接。
（1）“ ,@sql4=@sql4+',@'+@ic”，=>“ ,@sql4='@'+@ic+'+'+@sql4”，
（2）“ ,@sql4=substring(@sql4,2,8000)” =>“ ,@sql4=left(@sql4,len(@sql4)-1)”
其他的就不必多解释了，总的来说只是个小小的语法问题，应该是邹大哥疏忽造成的吧，感谢邹大哥分享这么好的算法！
下面是修正后的完美无瑕疵方法：
/*-- 数据测试环境 --*/
if exists (select * from dbo.sysobjects where id = object_id(N'[tb]') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
drop table [tb]
GO
create table tb(单位名称 varchar(10),日期 datetime,销售额 int)
insert into tb
select 'A单位','2001-01-01',100
union all select 'B单位','2001-01-02',101
union all select 'C单位','2001-01-03',102
union all select 'D单位','2001-01-04',103
union all select 'E单位','2001-01-05',104
union all select 'F单位','2001-01-06',105
union all select 'G单位','2001-01-07',106
union all select 'H单位','2001-01-08',107
union all select 'I单位','2001-01-09',108
union all select 'J单位','2001-01-11',109
--/*-- 方法3. 多个变量处理,综合了方法1及方法2的优点, 解决了方法1中需要人为判断的问题,自动根据要处理的数据量进行变量定义,同时又避免了方法2的繁琐
declare @sqlhead varchar(8000),@sqlend varchar(8000)
,@sql1 varchar(8000),@sql2 varchar(8000),@sql3 varchar(8000),@sql4 varchar(8000)
,@i int,@ic varchar(20)
--生成数据处理临时表
select id=identity(int,0,1),gid=0
,a=',['+单位名称 +']=sum(case 单位名称 when '''
+单位名称+''' then 销售额 else 0 end)'
into # from(select distinct 单位名称 from tb) a
--判断需要多少个变量来处理
select @i=max(len(a)) from #
print @i
set @i=7800/@i
--分组临时表
update # set gid=id/@i
select @i=max(gid) from #
--生成数据处理语句
select @sqlhead='''select 日期=convert(varchar(10),日期,120)'''
,@sqlend=''' from tb group by convert(varchar(10),日期,120)'''
,@sql1='',@sql2='select ',@sql3='',@sql4=''
while @i>=0
select @ic=cast(@i as varchar),@i=@i-1
,@sql1='@'+@ic+' varchar(8000),'+@sql1
,@sql2=@sql2+'@'+@ic+'='''','
,@sql3='select @'+@ic+'=@'+@ic+'+a from # where gid='+@ic
+char(13)+@sql3
,@sql4='@'+@ic+'+'+@sql4
select @sql1='declare '+left(@sql1,len(@sql1)-1)+char(13)
,@sql2=left(@sql2,len(@sql2)-1)+char(13)
,@sql3=left(@sql3,len(@sql3)-1)
,@sql4=left(@sql4,len(@sql4)-1)
--执行
exec( @sql1+@sql2+@sql3+'
exec('+@sqlhead+'+'+@sql4+'+'+@sqlend+')'
)
--删除临时表
drop table #
--*/
方法3中,关键要做修改的是下面两句,其他基本上不用做改变:
--生成数据处理临时表,修改a=后面的内容为相应的处理语句
select id=identity(int,0,1),gid=0
,a=',['+code+']=sum(case b.c_code when '''
+code+''' then b.value else 0 end)'
into # from #Class
--生成数据处理语句,将@sqlhead,@sqlend赋值为相应的处理语句头和尾
select @sqlhead='''select a.id,a.name,a.code'''
,@sqlend=''' from #Depart a,#Value b where a.Code=b.d_Code group by a.id,a.code,a.name'''
,@sql1='',@sql2='select ',@sql3='',@sql4=''
