一个统计服务器网络流量的小程序

因为工作需要，要统计一下服务器的网络吞吐量，并且出一个图表。在搜索网络吞吐量软件时候，看到这篇文章，于是决定用脚本来实现这个功能。bigtall在原文的启发下，做了一些修改，去掉了对unix工具的依赖，把它变成了一个纯的批处理文件。希望能给有需要的人帮助。

 1 @echo off
 2 :args
 3 rem 处理参数
 4 if "%1" == "" goto help
 5 
 6 set stopfile="%temp%\netflow.stop"
 7 if "%1" == "stop" goto stop
 8 if "%1" == "start" goto start
 9 goto help
 
 :start
 rem 继续分析start参数
 set outfile=
 set outcon=1
 if "%2" == "" goto main
 set outcon=
 if "%2" == "console" set outcon=1
 if not "%2" == "console" set outfile=%2
 if "%3" == "console" set outcon=1
 if "%outfile%" == "" if not "%3" == "console" set outfile=%3
 
 :main
 echo 本程序每5秒统计一下网卡的流量, ctrl+c退出
 
 rem 删除stop记录
 if exist %stopfile% del /q /f %stopfile%
 rem 首次流量记录，初始化
 echo WScript.Sleep(5000); > sleep.js
 set curdate1=%date%
 set curdate=%curdate1:~0,10%
 set curdate1=
 
 if "%outfile%" == "" goto label2
 if not exist %outfile% echo 日期,时间,接收总字节,发送总字节,本次接收字节,本次发送字节>>%outfile%
 :label2
 rem 其中字段内容为：日期，时间，接受总字节，发送总字节，本次接受字节，本次发送字节
 for /f "tokens=1,2,3" %%i in ('netstat -e ^| findstr 字节') do set prevrecv=%%j&&set prevsend=%%k
 :begin
 if exist %stopfile% goto mainexit
 for /f "tokens=1,2,3" %%i in ('netstat -e ^| findstr 字节') do set recv=%%j&&set send=%%k
 set /a nrecv=%recv:~-9% - %prevrecv:~-9%
 set /a nsend=%send:~-9% - %prevsend:~-9%
 set prevrecv=%recv%
 set prevsend=%send%
 if "%outfile%" == "" goto label3
 echo %curdate%,%time%,%recv%,%send%,%nrecv%,%nsend% >> %outfile%
 :label3
 if "%outcon%" == "1" echo %curdate%,%time%,%recv%,%send%,%nrecv%,%nsend%
 cscript //b //nologo sleep.js
 goto begin
 :mainexit
 if exist %stopfile% del /q /f %stopfile%
 if exist sleep.js del /q /f sleep.js
 goto end
 
 :stop
 echo 通知发送完成
 echo . > %stopfile%
 goto end
 
 :help
 echo 网络流量统计
 echo usage: netflow [start^|stop] [console] [logfile]
 echo        start   开始运行，并输出到指定文件
 echo        stop    停止统计
 echo        console 运行输出时，输出一份到控制台
 echo        logfile 运行输出时，输出一份到指定文件
 goto end
 
 :end