Oracle 9i&10g编程艺术 学习笔记02

      汗，写上篇笔记已经是去年的事情了。时间过得真快啊，在这里已经工作了一年多了，感觉自己什么都没学到似的，或者说没有钻研过。从一开始用C，后来体验了下Linux，学了点内核和Shell的皮毛，正打算将以后的方向定在unix平台/c语言开发的时候，猛然发现，在目前的岗位上，根本得不到什么应用。遂弃之。如今选择了PL/SQL，就要精通业务逻辑，刚开始的这段时间尤其痛苦，这存储过程里的业务逻辑并不是那么容易看出的。加油吧。

      人生啊，虚度年华，荒废光阴了。

 

    上次配置好了环境，接下来，就要准备一个工具用来检测不同方法的性能差异。Tom大师建议我们开发人员都应该有个自己用来测试各种想法的测试数据库(test bed), 我在其他的工作中也遵循了这样的做法，专门建立一个SandBox目录，本着“小马过河”的精神，检验自己的千奇百怪的猜想。

RunStats工具

     作用是分析sql的实际性能，主要从三个方面来考查：

A. 墙上时钟(wall clock)/耗用时间（elapsed time）：消耗时间；

B. 系统统计结果： 显示每个方法执行各步骤时发生的次数；

C. 闩定(latching)：轻量级的锁，有点像多线程里的mutex，应用中应使内部闩越少越好，这样可以保证应用的可扩展性。

 

1. 创建视图

create or replace view stats
as select 'STAT...'|| a.name name, b.value 
	from v$statname a, v$mystat b
	where a.statistic# = b.statistic#
	union all
	select 'LATCH.' || name, gets
	from v$latch;

2. 创建临时表

create global temporary table run_stats
( runid 	varchar2(15),
  name 		varchar2(80),
  value 	int
)
on commit preserve rows;

 

3.  创建RunStats包；

--runstat统计测试包

create or replace package runstats_pkg
as
	procedure rs_start;
	procedure rs_middle;
	procedure rs_stop( p_difference_threshold in number default 0 );
end;
/
create or replace package body runstats_pkg
as
  g_start  number;
  g_run1  number;
  g_run2  number;
  
procedure rs_start
is
begin
    delete from run_stats;
    
    insert into run_stats
    select 'before', stats.* from stats;
    g_start := dbms_utility.get_time;
end;

procedure rs_middle
is
begin
    g_run1 :=  (dbms_utility.get_time - g_start);
    
    insert into run_stats
    select 'after 1', stats.* from stats;
    g_start :=  dbms_utility.get_time;
end;

procedure  rs_stop( p_difference_threshold in number default 0 )
is
begin
    g_run2 :=  (dbms_utility.get_time-g_start);
    
    dbms_output.put_line( 'Run1 ran in '|| g_run1 || 'hsecs' );
    dbms_output.put_line( 'Run2 ran in '|| g_run2 || 'hsecs' );
    dbms_output.put_line( 'run 1 ran in '|| round(g_run1/g_run2*100,2) || '% of the time' );
    dbms_output.put_line( chr(9) );

insert into run_stats
select 'after 2',stats.* from stats;

dbms_output.put_line( rpad('Name', 30) || lpad('Run1',10) || lpad('Run2', 10) || lpad('Diff', 10);

for x in
(  select rpad(a.name, 30) ||
          to_char( b.value - a.value, '9,999,999') ||
          to_char( c.value - b.value, '9,999,999') ||
          to_char( ((c.value - b.value) - ( b.value - a.value)), '9,999,999') data
   from   run_stats a, run_stats b, run_stats c
   where  a.name = b.name
   and    a.name = b.name
   and    a.runid = 'before'
   and    b.runid = 'after 1'
   and    c.runid = 'after 2'
   and    (c.value - a.value) > 0
   and    abs( (c.value - b.value) - (b.value - a.value) ) > p_difference_threshold
   order by abs( (c.value - b.value) - (b.value - a.value) )
) loop
  dbms_output.put_line(x.data);
  end loop;
  
      dbms_output.put_line(chr(9));
  dbms_output.put_line('Run1 latches total versus runs -- difference and pct');
  dbms_output.put_line( lpad('Run1',10) || lpad('Run2',10) ||
                        lpad('Diff',10) || lpad('Pct',8);
                        
for x in
(   select to_char( run1, '9,999,999') || 
           to_char( run2, '9,999,999') ||
           to_char( diff, '9,999,999') ||
           to_char( round( run1/run2*100,2), '999.99') || '%' data
    from   (select sum(b.value - a.value) run1, sum(c.value - b.value) run2,
                   sum((c.value - b.value) - (b.value - a.value)) diff
            from   run_stats a, run_stats b, run_stats c
            where  a.name = b.name
            and    b.name = c.name
            and    a.runid = 'before'
            and    b.runid = 'after 1'
            and    c.runid = 'after 2'
            and    a.name like 'LATCH%'
           )
) loop
  dbms_output.put_line( x.data );
  end loop;
  
end;

end;
/

 

4. 创建完毕无误之后，可以使用big_table来试验一下，需事先建立一个big_table，以及同结构的t1,t2两张表。保证bigtable中有1 million条以上记录，这样比较的结果更显著。运行：

truncate table t1;
truncate table t2;

exec runstats_pkg.rs_start;

insert  into t1 select * from big_table;
commit;

exec runstats_pkg.rs_middle;

begin
	for x in( select * from big_table )
	loop
		insert into t2 values x;
	end loop;
	commit;
end;
/

exec runstats_pkg.rs_stop;

 

结果很明显，t1的插入速度快很多。

 

Show_Space例程

    有了这个，可以查看数据库段空间的利用率的详细结果，如 exec show_space(‘BIG_TABLE’);  <BIG_TABLE必须大写>；

代码如下：

create or replace procedure show_space
( p_segname in varchar2,
  p_owner   in varchar2 default user,
  p_type    in varchar2 default 'TABLE',
  p_partition in varchar2 default NULL )
-- this procedure uses authid current user so it can query DBA_*
-- views using privileges from a ROLE and so it can be installed
-- once per database, instead of once per user that wanted to use it
authid current_user
as
    l_free_blks                 number;
    l_total_blocks              number;
    l_total_bytes               number;
    l_unused_blocks             number;
    l_unused_bytes              number;
    l_LastUsedExtFileId         number;
    l_LastUsedExtBlockId        number;
    l_LAST_USED_BLOCK           number;
    l_segment_space_mgmt        varchar2(255);
    l_unformatted_blocks number;
    l_unformatted_bytes number;
    l_fs1_blocks number; l_fs1_bytes number;
    l_fs2_blocks number; l_fs2_bytes number;
    l_fs3_blocks number; l_fs3_bytes number;
    l_fs4_blocks number; l_fs4_bytes number;
    l_full_blocks number; l_full_bytes number;

        -- inline procedure to print out numbers nicely formatted
        -- with a simple label
    procedure p( p_label in varchar2, p_num in number )
    is
    begin
        dbms_output.put_line( rpad(p_label,40,'.') ||
                              to_char(p_num,'999,999,999,999') );
    end;
begin
   -- this query is executed dynamically in order to allow this procedure
   -- to be created by a user who has access to DBA_SEGMENTS/TABLESPACES
   -- via a role as is customary.
   -- NOTE: at runtime, the invoker MUST have access to these two
   -- views!
   -- this query determines if the object is a ASSM object or not
   begin
      execute immediate
          'select ts.segment_space_management
             from dba_segments seg, dba_tablespaces ts
            where seg.segment_name      = :p_segname
              and (:p_partition is null or
                  seg.partition_name = :p_partition)
              and seg.owner = :p_owner
              and seg.tablespace_name = ts.tablespace_name'
             into l_segment_space_mgmt
            using p_segname, p_partition, p_partition, p_owner;
   exception
       when too_many_rows then
          dbms_output.put_line
          ( 'This must be a partitioned table, use p_partition => ');
          return;
   end;


   -- if the object is in an ASSM tablespace, we must use this API
   -- call to get space information, else we use the FREE_BLOCKS
   -- API for the user managed segments
   if l_segment_space_mgmt = 'AUTO'
   then
     dbms_space.space_usage
     ( p_owner, p_segname, p_type, l_unformatted_blocks,
       l_unformatted_bytes, l_fs1_blocks, l_fs1_bytes,
       l_fs2_blocks, l_fs2_bytes, l_fs3_blocks, l_fs3_bytes,
       l_fs4_blocks, l_fs4_bytes, l_full_blocks, l_full_bytes, p_partition);

     p( 'Unformatted Blocks ', l_unformatted_blocks );
     p( 'FS1 Blocks (0-25)  ', l_fs1_blocks );
     p( 'FS2 Blocks (25-50) ', l_fs2_blocks );
     p( 'FS3 Blocks (50-75) ', l_fs3_blocks );
     p( 'FS4 Blocks (75-100)', l_fs4_blocks );
     p( 'Full Blocks        ', l_full_blocks );
  else
     dbms_space.free_blocks(
       segment_owner     => p_owner,
       segment_name      => p_segname,
       segment_type      => p_type,
       freelist_group_id => 0,
       free_blks         => l_free_blks);

     p( 'Free Blocks', l_free_blks );
  end if;

  -- and then the unused space API call to get the rest of the
  -- information
  dbms_space.unused_space
  ( segment_owner     => p_owner,
    segment_name      => p_segname,
    segment_type      => p_type,
    partition_name    => p_partition,
    total_blocks      => l_total_blocks,
    total_bytes       => l_total_bytes,
    unused_blocks     => l_unused_blocks,
    unused_bytes      => l_unused_bytes,
    LAST_USED_EXTENT_FILE_ID => l_LastUsedExtFileId,
    LAST_USED_EXTENT_BLOCK_ID => l_LastUsedExtBlockId,
    LAST_USED_BLOCK => l_LAST_USED_BLOCK );

    p( 'Total Blocks', l_total_blocks );
    p( 'Total Bytes', l_total_bytes );
    p( 'Total MBytes', trunc(l_total_bytes/1024/1024) );
    p( 'Unused Blocks', l_unused_blocks );
    p( 'Unused Bytes', l_unused_bytes );
    p( 'Last Used Ext FileId', l_LastUsedExtFileId );
    p( 'Last Used Ext BlockId', l_LastUsedExtBlockId );
    p( 'Last Used Block', l_LAST_USED_BLOCK );
end;
/

 

最后的准备部分：代码约定

    一般稍微正规点的项目的命名都很规范或者有规则。Tom在书中采用的命名规则为：

g_variable --全局变量

l_variable  --局部变量

p_variable --过程形参

我的命名规则是：

g_variable   --全局变量

l_variable    --局部变量

i_variable    --输入型形参

io_variable  --输入输出型形参

……

相比微软的匈牙利命名法，PL/SQL里倒是简化了许多。总之风格统一，简明易懂就行。

没啥了，这篇也是N周之后的回忆，又温习了一次。已经看到第三章了，笔记得继续跟上啊，come on!