动态规划练习题（2）

1、完全背包(knapsack.pas)

AYYZOJ p1473

program p1473;
const
  maxm=200; maxn=30;
var
  i,j,n,m:integer;
  w,u:array[1..maxn] of integer;
  f:array[0..maxn,0..maxm] of integer;
begin
  fillchar(w,sizeof(w),0);
  fillchar(u,sizeof(u),0);
  readln(m,n);
  for i:=1 to n do readln(w[i],u[i]);
  for i:=1 to n do
   begin
     for j:=1 to w[i]-1 do
      f[i,j]:=f[i-1,j];
     for j:=w[i] to m do
      if f[i-1,j]>f[i,j-w[i]]+u[i] then f[i,j]:=f[i-1,j]
          else f[i,j]:=f[i,j-w[i]]+u[i];
   end;
  writeln(f[n,m]);
end.

2、货币系统(money.pas)

AYYZOJ p1133

COGS p698

统计完全背包方案数

const
  maxv=25;
var
  v,n,i,j,k,t:longint;
  a:array[1..maxv] of longint;
  f:array[0..maxv,0..10000] of int64;
begin
  assign(input,'moneysys.in'); reset(input);
  assign(output,'moneysys.out'); rewrite(output);
  readln(v,n);
  for i:=1 to v do
    read(a[i]);
  for i:=0 to v do f[i,0]:=1;
  for i:=1 to v do
    for j:=1 to n do
    begin
          f[i,j]:=f[i-1,j];
      if j>=a[i] then
        f[i,j]:=f[i,j]+f[i,j-a[i]];
    end;
  writeln(f[v,n]);
  close(input); close(output);
end.

var
v,n,i,j:longint;
m:array[0..26] of longint;
f:array[0..26,0..10000] of int64;
begin
  assign(input,'moneysys.in');reset(input);
  assign(output,'moneysys.out');rewrite(output);
  readln(v,n);
  for i:=1 to v do begin read(m[i]);f[i,0]:=1;end;
  for i:=1 to v do
    for j:=1 to n do
      begin
        f[i,j]:=f[i,j]+f[i-1,j];
        if j-m[i]>=0 then f[i,j]:=f[i,j]+f[i,j-m[i]];
      end;
  writeln(f[v,n]);
  close(input);
  close(output);
end.

{设f[i,j]表示用前i种硬币能表示j面额货币的方法数：则f[i,j]=f[i-1,j]+f[i-1,j-a[i]];即前i种硬币能表示j货币的种类=不用第i种硬币能表示的j货币的种类+用上第i种货币能表示j货币的种类。当然这个方程在空间上还可以简化为一维的
}
program money;
var
    n,v:integer;
    cash:array[1.. 25] of integer;
    f:array[0..10000] of qword;
procedure init;
var
    i:integer;
begin
    readln(v,n);
    for i:=1 to v do read(cash[i]);
    readln;
    end;
procedure dp;
var
    i,j,k,l:integer;
begin
    fillchar(f,sizeof(f),0);
    f[0]:=1;
    for i:=1 to v do
        for j:=cash[i] to n do
            inc(f[j],f[j-cash[i]]);
    writeln(f[n]);
end;
begin
    init;
    dp;
end.

[分析]

题意：已知v种货币，求用这v种货币构成面值n的种数。
解题思路：
用一维数组f[i]表示循环到当前构成面值i的种数
则f[i]为组成当前面值i的种数+组成I-a[j]面值的种数之和
例如：当前循环的货币为2元，构成面值8元共有a种，构成面值6元共有b种，则构成6元的每种方案加2元都能构成8元，f[8]:=f[8]+f[6]=a+b
动态转移方程为f[i]:=f[i]+f[I-a[j]]，目标状态为f[n]
程序如下：
program p_1133;
var
  f:array[0..10000]of int64;
  a:array[0..30]of int64;
  i,j,v,n:longint;
begin
  read(v,n);
  for i:=1 to v do
read(a[i]);
f[0]:=1; // 初始化，构成面值0共一种方案，即每种货币0张
  for j:=1 to v do  // 循环v种货币
    for i:=1 to n do  // 循环面值1..n
      if  i>=a[j] then
        f[i]:=f[i-a[j]]+f[i];
   writeln(f[n]);
end.

3、质数和分解（prime.pas）

与第二题同类型

program p1474;
const maxp=200;
var
  f:array[1..maxp] of boolean;
  p:array[0..maxp] of longint;
  n,i,j:longint;
  dp:array[0..maxp,0..maxp] of longint;
procedure shai(maxp:longint);
var i,j:longint;
begin
for i:=2 to maxp do
    if not f[i] then
     begin
       inc(p[0]);
       p[p[0]]:=i;
       for j:=2 to maxp div i do
        f[i*j]:=true;
       {j:=i;
       while i+j<=maxp do begin
                            j:=j+i; f[j]:=true;
                          end;  }
     end;
end;
begin
  readln(n);
  shai(n);
  {for i:=1 to n do
   dp[0,i]:=1; }
  for i:=1 to p[0] do
   dp[i,0]:=1;
   for i:=1 to p[0] do
    for j:=1 to n do
     begin
       dp[i,j]:=dp[i-1,j];
       if j>=p[i] then dp[i,j]:=dp[i,j]+dp[i,j-p[i]];
     end;
  writeln(dp[p[0],n]);
end.

 1 program prime; {完全背包}
 2  var i,j,k,n,m:longint;
 3      f,a:array[0..1000000]of longint;
 4 begin
 5  readln(n);
 6  k:=1;
 7  a[k]:=2;
 8  for i:=3 to n do  {求n以内的质数}
 9   begin
10   for j:=2 to  i-1 do
11     if i mod j=0 then
12   break;
13   if i mod j<>0 then begin inc(k);a[k]:=i;end;
14   end;
15  f[0]:=1; {初始化，不能分解时为一种方案}
16  for i:=1 to k do
17  begin
18   for j:=1 to n do
19    if a[i]<=j then
20     f[j]:=f[j]+f[j-a[i]];
21  end;
22  writeln(f[n]);
23 end.

{方法一：
用F[J]表示j的质数和分解的个数
  j=(j-i)+I   如果此处的I是质数 那么f[j-i]中的所有和分解情况在f[j]中也同样成立，即inc（f[j],f[j-i]）
  数据弱到200，f开longint足够用，判断质数直接写成200的布尔数组
 P.S. 注意数组的清空和f[0]的初值为1
}

const
 m=46;
 sushu:array[1..m] of integer=(2,3,5,7,11,13,17,19,23,29,31,37,41,43,47,53,59,61,67,71,73,
79,83,89,97,101,103,107,109,113,127,131,137,139,149,151,157,163,167,173,179,
181,191,193,197,199);
var
 su:array[1..200] of boolean;
 f:array[0..200] of int64;
 i,j,n:integer;
begin
 readln(n);
 fillchar(f,sizeof(f),0);
 fillchar(su,sizeof(su),0);
 for i:=1 to 46 do
  su[sushu[i]]:=true;
 f[0]:=1;
 for i:=2 to n do
   if su[i] then for j:=i to n do inc(f[j],f[j-i]);
 writeln(f[n]);
end.


//方法二：
program prime; {完全背包（每个质数所用次数没有限制）}
 var i,j,k,n,m:longint;
     f,a:array[0..1000000]of longint;
begin
 readln(n);
 k:=1;
 a[k]:=2;
 for i:=3 to n do  {求n以内的质数}
  begin
  for j:=2 to  i-1 do
    if i mod j=0 then
  break;
  if i mod j<>0 then begin inc(k);a[k]:=i;end;
  end;
 f[0]:=1; {初始化，不能分解时为一种方案}
 for i:=1 to k do
 begin
  for j:=1 to n do
   if a[i]<=j then
    f[j]:=f[j]+f[j-a[i]];
 end;
 writeln(f[n]);
end.

4、最小乘车费用(buses.pas)

AYYZOJ p1515

COGS p192

COGS p961（重复了）

类似于完全背包

分析：
    本题是一道典型的完全背包问题。物品数已知，即可供选择的1-10km 的行驶路程；而题中的费用则相当于背包问题中的“价值”，题中的所走的里程数，即是背包问题中的“费用”。这样，这道题就完全转化为了我们所熟悉的完全背包。所以这道题也可以这样问：已知有10件物品，及每件物品的价值，和选择该物品的费用，每件物品可以选择多次，用一个固定的费用（即要行驶的里程），购买这10件物品，使它们的价值总和（即乘车费用）最小，输出可以达到的最小价值。这样该问题和能装满的完全背包就只有“max”和“min”的差别了。因为其中有行驶1km（费用为1）这种物品，所以要求的费用可以达到，这个背包也一定能够装满。
    本题的关键是将题目转化为我们熟悉的问题——完全背包，另外初始化的问题也应该注意。

代码：
var
  i,j,n:longint;
  w,c:array[1..10] of longint;
  dp:array[0..100] of longint;
  function min(x,y:longint):longint;
  begin if x<y then min:=x else min:=y; end;
begin
  for i:=1 to 10 do
begin read(c[i]); w[i]:=i; end;     
{读入这10件物品的“费用”和“价值”}
  readln(n);
for i:=1 to n do dp[i]:=maxlongint;        
{初始化，因为需要求的是最小费用，所以在比较时用的是min函数，若不初始化，则默认数组里的数都为0，将不能正常比较，也可以用fillchar(dp,sizeof(dp),$7F);dp[0]:=0}
  for i:=1 to 10 do                                //依次枚举这10件物品
    for j:=w[i] to n do
      dp[j]:=min(dp[j],dp[j-w[i]]+c[i]);
  writeln(dp[n]);
end.

program p1515;
var
  n,i,j:longint;
  w,v:array[1..10] of longint;
  f:array[0..500] of longint;
function min(x,y:longint):longint;
begin
  if x<y then exit(x) else exit(y);
end;
begin
  for i:=1 to 10 do begin read(v[i]); w[i]:=i; end;
  readln(n);
  for i:=1 to n do f[i]:=100000;
  f[0]:=0;
  for i:=1 to 10 do
   for j:=w[i] to n do
     f[j]:=min(f[j],f[j-w[i]]+v[i]);
  writeln(f[n]);
end.

var
i,j,k,n,m:longint;
    f:array[0..500]of longint;
    c:array[0..10]of longint;
begin
  fillchar(f,sizeof(f),$7f);
  f[0]:=0;
  for i:=1 to 10 do read(c[i]);
  readln(m);
  for i:=1 to m do
    for j:=1 to 10 do
      if (i-j>=0) and (f[i-j]+c[j]<f[i]) then f[i]:=f[i-j]+c[j];
  writeln(f[m]);
end.

循环顺序不同。。省去一个数组

program busses;
var
  f:array [1..10] of byte;
  dp:array [1..320000] of dword;
  n,i:word;
procedure go(n:dword);
var
  i:dword;
  tmp:dword;
begin
  if n<>1 then begin
    tmp:=maxint;
    for i:=1 to (n-1) div 2+1 do begin
      if dp[i]=0 then go(i);
      if dp[n-i]=0 then go(n-i);
      if dp[i]+dp[n-i]<tmp then tmp:=dp[i]+dp[n-i];
    end;
    if n<=10 then if tmp>f[n] then tmp:=f[n];
    dp[n]:=tmp;
  end;
end;
begin
  fillchar (dp,sizeof(dp),0);
  assign (input,'busses.in');
  reset (input);
  for i:=1 to 10 do read (f[i]);
  readln (n);
  close (input);
  assign (output,'busses.out');
  rewrite (output);
  dp[1]:=f[1];go(n);
  writeln (dp[n]);
  close (output);
end.

08年的，作者maxiem，侵删。