windows 下 gcc stm32f4
首先配置好 sourcery codebench 环境。
https://sourcery.mentor.com/GNUToolchain/subscription3053?lite=arm
然后建立如下目录：
Libraries下：
project 下：
00.Start下：
startup_stm32f4xx.s 来自 \Libraries\CMSIS\ST\STM32F4xx\Source\Templates\gcc_ride7
----------makefile 内容：
TARGET = main
Defines= -D USE_STDPERIPH_DRIVER -D STM32F4XX
LIB_INC= -I ../../Libraries/STM32F4xx_StdPeriph_Driver/inc \
-I ../../Libraries/CMSIS/ST/STM32F4xx/Include \
-I ../../Libraries/CMSIS/Include
LIB_SRC=
LIB_SRC += stm32f4xx_rcc.c
LIB_SRC += misc.c
LIB_SRC += stm32f4xx_gpio.c
LIB_OBJ=$(LIB_SRC:.c=.o)
LIB_SRC_Dir=../../Libraries/STM32F4xx_StdPeriph_Driver/src/
USR_SRC_Dir=src/
Obj_Dir=obj/
Bin_Dir=bin/
USR_SRC=main.c\
stm32f4xx_it.c\
system_stm32f4xx.c\
systick.c
USR_OBJ=$(USR_SRC:.c=.o)
INCLUDE_DIRS=-I $(USR_SRC_Dir) $(LIB_INC)
TARGET_OUT_ELF = $(TARGET).elf
TARGET_OUT_BIN = $(TARGET).bin
TCHAIN=arm-none-eabi
CC=$(TCHAIN)-gcc
CFLAGS = $(Defines) $(INCLUDE_DIRS) -g -O2 -Wall
LD = $(TCHAIN)-gcc
LDFLAGS = -T stm32_flash.ld
LDFLAGS += -mlittle-endian -mthumb -mcpu=cortex-m4 -mthumb-interwork
# softfp: 软件浮点。sourcery 似乎不支持硬件浮点
LDFLAGS += -mfloat-abi=softfp -mfpu=fpv4-sp-d16
Boot_Src=startup_stm32f4xx.s
Boot_Obj=$(Boot_Src:.s=.o)
OBJCP = $(TCHAIN)-objcopy
OBJCPFLAGS = -O binary
#OBJCPFLAGS = -O ihex
STR_DIV = ------------------------------------------------------------
all: start $(TARGET_OUT_ELF) $(TARGET_OUT_BIN) end
start:
@echo Start Compiling Target: $(TARGET)
@echo $(STR_DIV)
end:
@echo $(STR_DIV)
@echo bye!!
gcc-info:
@echo $(STR_DIV)
@echo gcc version is
@$(CC) --version
@echo $(STR_DIV)
USR_OBJ_WithPath=$(addprefix $(Obj_Dir),$(USR_OBJ))
LIB_OBJ_WithPath=$(addprefix $(Obj_Dir),$(LIB_OBJ))
Boot_OBJ_WithPath=$(addprefix $(Obj_Dir),$(Boot_Obj))
$(TARGET_OUT_ELF): $(USR_OBJ) $(LIB_OBJ) $(Boot_Obj)
$(LD) $(Defines) $(LDFLAGS) $(USR_OBJ_WithPath) $(LIB_OBJ_WithPath) $(Boot_OBJ_WithPath) --output $(Bin_Dir)$@
$(TARGET_OUT_BIN): $(TARGET_OUT_ELF)
$(OBJCP) $(OBJCPFLAGS) $(Bin_Dir)$< $(Bin_Dir)$@
vpath %.c $(USR_SRC_Dir)
vpath %.c $(LIB_SRC_Dir)
%.o : %.c
$(CC) $(CFLAGS) $(LDFLAGS) -c -o $(Obj_Dir)$@ $^
$(Boot_Obj):$(Boot_Src)
$(CC) $(CFLAGS) $(LDFLAGS) -c -o $(Obj_Dir)$@ $^
.PHONY:clean clean_all
clean:
del obj\*.o
clean_all:clean
del bin\$(TARGET_OUT_ELF)
del bin\$(TARGET_OUT_BIN)
-------stm32_flash.ld
/*
*****************************************************************************
**
** File : stm32_flash.ld
**
** Abstract : Linker script for STM32F407VG Device with
** 1024KByte FLASH, 192KByte RAM
**
** Set heap size, stack size and stack location according
** to application requirements.
**
** Set memory bank area and size if external memory is used.
**
** Target : STMicroelectronics STM32
**
** Environment : Atollic TrueSTUDIO(R)
**
** Distribution: The file is distributed “as is,” without any warranty
** of any kind.
**
** (c)Copyright Atollic AB.
** You may use this file as-is or modify it according to the needs of your
** project. Distribution of this file (unmodified or modified) is not
** permitted. Atollic AB permit registered Atollic TrueSTUDIO(R) users the
** rights to distribute the assembled, compiled & linked contents of this
** file as part of an application binary file, provided that it is built
** using the Atollic TrueSTUDIO(R) toolchain.
**
*****************************************************************************
*/
/* Entry Point */
ENTRY(Reset_Handler)
/* Highest address of the user mode stack */
_estack = 0x20020000; /* end of 128K RAM on AHB bus*/
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0; /* required amount of heap */
_Min_Stack_Size = 0x400; /* required amount of stack */
/* Specify the memory areas */
MEMORY
{
FLASH (rx) : ORIGIN = 0x08000000, LENGTH = 1024K
RAM (xrw) : ORIGIN = 0x20000000, LENGTH = 192K
MEMORY_B1 (rx) : ORIGIN = 0x60000000, LENGTH = 0K
}
/* Define output sections */
SECTIONS
{
/* The startup code goes first into FLASH */
.isr_vector :
{
. = ALIGN(4);
KEEP(*(.isr_vector)) /* Startup code */
. = ALIGN(4);
} >FLASH
/* The program code and other data goes into FLASH */
.text :
{
. = ALIGN(4);
*(.text) /* .text sections (code) */
*(.text*) /* .text* sections (code) */
*(.rodata) /* .rodata sections (constants, strings, etc.) */
*(.rodata*) /* .rodata* sections (constants, strings, etc.) */
*(.glue_7) /* glue arm to thumb code */
*(.glue_7t) /* glue thumb to arm code */
*(.eh_frame)
KEEP (*(.init))
KEEP (*(.fini))
. = ALIGN(4);
_etext = .; /* define a global symbols at end of code */
_exit = .;
} >FLASH
.ARM.extab : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
.ARM : {
__exidx_start = .;
*(.ARM.exidx*)
__exidx_end = .;
} >FLASH
.preinit_array :
{
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP (*(.preinit_array*))
PROVIDE_HIDDEN (__preinit_array_end = .);
} >FLASH
.init_array :
{
PROVIDE_HIDDEN (__init_array_start = .);
KEEP (*(SORT(.init_array.*)))
KEEP (*(.init_array*))
PROVIDE_HIDDEN (__init_array_end = .);
} >FLASH
.fini_array :
{
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP (*(.fini_array*))
KEEP (*(SORT(.fini_array.*)))
PROVIDE_HIDDEN (__fini_array_end = .);
} >FLASH
/* used by the startup to initialize data */
_sidata = .;
/* Initialized data sections goes into RAM, load LMA copy after code */
.data : AT ( _sidata )
{
. = ALIGN(4);
_sdata = .; /* create a global symbol at data start */
*(.data) /* .data sections */
*(.data*) /* .data* sections */
. = ALIGN(4);
_edata = .; /* define a global symbol at data end */
} >RAM
/* Uninitialized data section */
. = ALIGN(4);
.bss :
{
/* This is used by the startup in order to initialize the .bss secion */
_sbss = .; /* define a global symbol at bss start */
__bss_start__ = _sbss;
*(.bss)
*(.bss*)
*(COMMON)
. = ALIGN(4);
_ebss = .; /* define a global symbol at bss end */
__bss_end__ = _ebss;
} >RAM
/* User_heap_stack section, used to check that there is enough RAM left */
._user_heap_stack :
{
. = ALIGN(4);
PROVIDE ( end = . );
PROVIDE ( _end = . );
. = . + _Min_Heap_Size;
. = . + _Min_Stack_Size;
. = ALIGN(4);
} >RAM
/* MEMORY_bank1 section, code must be located here explicitly */
/* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
.memory_b1_text :
{
*(.mb1text) /* .mb1text sections (code) */
*(.mb1text*) /* .mb1text* sections (code) */
*(.mb1rodata) /* read-only data (constants) */
*(.mb1rodata*)
} >MEMORY_B1
/* Remove information from the standard libraries */
/DISCARD/ :
{
libc.a ( * )
libm.a ( * )
libgcc.a ( * )
}
.ARM.attributes 0 : { *(.ARM.attributes) }
}
------
然后， cs-make 就可以编译啦。
写了个点灯程序，用STM32 ST-Link Utility 下载测试 无误。
