poj1935

给定起点和要经过的点，求最短路径
我发现，关于路径的treedp，设计的关键在于每个节点的状态怎么表示
对于这道题，有一种常见的方法是令f[i,1]表示经过这个点且还要回来的路径，
f[i,0]表示留在以i为根的子树的某个节点上不回到i的最短路径
然后方程就很好设计了，具体见程序

type node=record
       next,cost,point:longint;
     end;

var edge:array[0..100010] of node;
    need,v:array[0..50010] of boolean;
    p:array[0..50010] of longint;
    f:array[0..50010,0..1] of longint;
    len,n,m,root,x,y,z,i:longint;

procedure add(x,y,z:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].cost:=z;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure treedp(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    v[x]:=true;
    while i<>-1 do
    begin
      y:=edge[i].point;
      if not v[y] then
      begin
        treedp(y);
        if need[y] then
        begin
          f[x,0]:=min(f[y,0]+f[x,1]+edge[i].cost,f[x,0]+edge[i].cost*2+f[y,1]); 
          //在停在之前的最优点和停在当前点为根的子树上这两种情况选择一个较优的
          f[x,1]:=f[x,1]+f[y,1]+edge[i].cost*2;  //无需多说
          need[x]:=true;
        end;
      end;
      i:=edge[i].next;
    end;
  end;

begin
  readln(n,root);
  fillchar(p,sizeof(p),255);
  for i:=1 to n-1 do
  begin
    readln(x,y,z);
    add(x,y,z);
    add(y,x,z);
  end;
  readln(m);
  for i:=1 to m do
  begin
    read(x);
    need[x]:=true;
  end;
  treedp(root);
  writeln(f[root,0]);
end.