使用as工具包解压zip文件

在一些请求静态资源较多的地方，如webgame中要请求很多数值相关的信息，为了减少请求数以及请求的文件大小，可以通过zip工具先将文件合并后进行压缩，得到一个zip包，然后请求这个zip包，客户端再使用工具包对zip包进行解压得到相关数据即可。

 

可以点击这个链接，在线体验一下这个功能。在线Demo地址>>

 

虽然会造成客户端cpu和内存的消耗，但总的来讲效率是略胜于单次、单个的请求文件。（哪些文件需要使用这种方式，哪些不需要，这个就需要自己去判定了，根据实际情况去衡量：文件更新次数、文件大小、文件使用的频率、文件使用的优先级等因素）

这里使用的是nochump.util.zip这个工具，里面的as文件也比较少，总共才8个文件。

假设目前有40个XML文件，如下图所示：

编码解析后得到的效果图：

两张图可以对比一下，文件信息没什么变化。

解析压缩文件的关键代码是，创建ZipFile实例，使用getInput获取压缩信息中数据(ByteArray)。

完整的示例代码(就一个mxml文件)：

 

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" minWidth="955" minHeight="600" creationComplete="inited()">


    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.formatters.DateFormatter;

            import nochump.util.zip.ZipEntry;
            import nochump.util.zip.ZipFile;

            private var fileUrl:String = "config2.zip";
            private var zipList:Array = [];

            private function inited():void {

            }

            private function loadZip(evt:MouseEvent=null):void {


                var urlStream:URLStream = new URLStream();

                loadProgress.source = urlStream;

                urlStream.addEventListener(Event.COMPLETE, completeHandler);
                urlStream.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
                urlStream.addEventListener(SecurityErrorEvent.SECURITY_ERROR, errorHandler);

                urlStream.load(new URLRequest(fileUrl));

                loadBtn.enabled = false;
            }

            private function completeHandler(evt:Event):void {
                loadBtn.enabled = true;

                var data:URLStream = URLStream(evt.target);

                var zipFile:ZipFile = new ZipFile(data);
                var entry:ZipEntry;
                var text:ByteArray;
                var list:Array = [];

                for(var i:int = 0; i < zipFile.entries.length; i++) {
                    entry = zipFile.entries[i];
                    text  = zipFile.getInput(entry);
                    zipList[entry.name] = String(text);
                }

                dgEntries.dataProvider = zipFile.entries;

                zipFileLabel.text = "文件: " + fileUrl + " (" + sizeFormatter.format(data.bytesAvailable) + " bytes)  文件总数：" + zipFile.entries.length;
            }

            private function errorHandler(errEvt:ErrorEvent):void {
                loadBtn.enabled = true;
                Alert.show("加载出错：" + errEvt.text);
            }

            private function itemClickEvent(evt:Event):void {
                var entry:ZipEntry = evt.currentTarget.selectedItem as ZipEntry;
                if(entry) taEntryData.text = zipList[entry.name];
            }

            private function labelSize(item:Object, column:DataGridColumn):String {
                return sizeFormatter.format(item[column.dataField]) + "KB";
            }

            private function labelModified(item:Object, column:DataGridColumn):String {
                var dateFormatter:DateFormatter = new DateFormatter();
                dateFormatter.formatString = "YYYY-MM-DD JJ:NN:SS";
                return dateFormatter.format(new Date(item.time));
            }

            private function labelCrc(item:Object, column:DataGridColumn):String {
                return item.crc.toString(16).toUpperCase();
            }

        ]]>
    </mx:Script>

    <mx:NumberFormatter id="sizeFormatter" useThousandsSeparator="true" />

    <mx:VBox horizontalCenter="0" verticalCenter="0" width="800" height="100%" paddingTop="50">
        <mx:Button label="点击加载zip文件" click="loadZip()" id="loadBtn" />

        <mx:ProgressBar id="loadProgress" width="100%" />

        <mx:Label id="zipFileLabel" />

        <mx:DataGrid id="dgEntries" width="100%" height="300" itemClick="itemClickEvent(event);">
            <mx:columns>
                <mx:DataGridColumn headerText="Name" dataField="name" width="300" />
                <mx:DataGridColumn headerText="Size" dataField="size" labelFunction="labelSize"  />
                <mx:DataGridColumn headerText="Packed" dataField="compressedSize" labelFunction="labelSize" />
                <mx:DataGridColumn headerText="Modified" labelFunction="labelModified" width="150" />
                <mx:DataGridColumn headerText="CRC32" labelFunction="labelCrc" />
            </mx:columns>
        </mx:DataGrid>
        <mx:TextArea id="taEntryData" width="100%" height="200" />
    </mx:VBox>

</mx:Application>

demo的下载地址>>   (不包含xml文件的压缩包~ ~，需要自己去整个zip包进行测试了…)