20130515-Grails In Action-3、建模(04小节)

上一节建立了一个1:1的对象关系，这一节来建立一个1:m的对象关系

一个用户在一个论坛上或消息发布平台上可以发布多个消息，这个场景就是一个经典的1:m关系

1、建立一个Post对象

grails create-domain-class com.grailsinaction.Post

2、给Post对象增加属性

package com.grailsinaction

class Post {
    static belongsTo = [ user : User ]
    
    String content
    Date dateCreated

    static constraints = {
        content(blank: false)
    }
}

这里的级联关系和1:1是一样的，如果User对象的实体删除了，那么User实体对应的Post也将一并删除。这个动作是单向的，如果某个Post对象的实体删除了，User对象是不会删除的。

我们这里已经告诉Post对象和User对象的关系了，同样也要告诉User对象和Post对象的关系

3、修改User对象属性

package com.grailsinaction

class User {
    static hasMany = [ posts : Post ]
    ......
}

加入这个关系后，告诉User，可以拥有多个Post，现在就可以用User.addToPosts()给User的实体增加Post实体，或者用User.removeFromPosts()删除Post实体，下面增加测试方法验证这个关系

4、增加一个Post集成测试类

grails create-integration-test com.grailsinaction.PostIntegration

5、增加一个测试方法

package com.grailsinaction

import static org.junit.Assert.*
import org.junit.*

class PostIntegrationTests {

    @Before
    void setUp() {
        // Setup logic here
    }

    @After
    void tearDown() {
        // Tear down logic here
    }

    @Test
    void testFirstPost() {
        def user = new User(userId: 'joe', password: 'secret').save()
        def post1 = new Post(content: "First post... W00t!")
        user.addToPosts(post1)
        
        def post2 = new Post(content: "Second post...")
        user.addToPosts(post2)
        
        def post3 = new Post(content: "Third post...")
        user.addToPosts(post3)
        
        assertEquals 3, User.get(user.id).posts.size()
    }
}

这里要注意，必须要调用User对象的save()方法，User对象才能将User持久化到数据库。一旦User对象保存了，并调用user.addToPosts()方法，Post对象会自动保持

6、运行命令测试结果

grails test-app -integration

当我们的帖子保存到数据库了，怎么能检索出来呢？

应该是先找到需要检索帖子的user对象，再将这个对象的所有post遍历出来，再建立一个集成测试看看结果

7、测试查询post实例

    @Test
    void testAccessingPosts() {
        def user = new User(userId: 'joe', password: 'secret').save()
        user.addToPosts(new Post(content: "First"))
        user.addToPosts(new Post(content: "Second"))
        user.addToPosts(new Post(content: "Third"))
        
        def foundUser = User.get(user.id)
        def postNames = foundUser.posts.collect { it.content }
        assertEquals(['First', 'Second', 'Third'], postNames.sort())
    }

新建了一个user对象joe，并给这个对象增加了3个post，使用User.get(id)方法获取到user对象，使用user.posts.collect{}闭包遍历user的post。对比时使用了sort()方法对遍历出来的posts排序。

这时会有个问题，一般显示post都会根据创建的时间降序排列，意思是最晚发布的帖子放在最前面，我们可以修改Post对象，让获取到post信息时就将序列排好，拿出来就是我们想要的结果

8、修改Post对象

......
    static mapping = {
        sort dateCreated:"desc"
    }
}

这样post返回的结果就是按照创建日期降序排列的了

假如我们是通过用户，再找某用户的帖子时，例如:user.posts.each，这样的场景就需要对用户下的帖子进行排序了，所以需要修改User对象，增加对用户下帖子的排序功能

......
    static mapping = {
        profile lazy:false
        posts sort:'dateCreated'
    }
}

这种方式告诉我们，当我们根据用户去检索用户下的帖子信息时，按照这种方式排序