开始学习二叉查找树

目标：在两个半月内基本掌握相关基本查询，以及Splay、SBT、Trie这三种特殊树的形式。

 

千里之行，始于足下。

 

program bst;

Type
 node=^rec;
 rec=record
   lch,rch:node;
   d,pos:longint;
 end;

Var
 h,u:node;
 i,o,n:longint;
Procedure init(var p:node;k,po:longint);
  begin
  p^.lch:=nil;
  p^.rch:=nil;
  p^.d:=k;
  p^.pos:=po;
end;

Procedure ins(var p:node;q,po:longint);
var
 p1:node;
  begin
  if p=nil then
    begin
    new(p);
    init(p,q,po);
    exit;
  end;
  if q<=p^.d then ins(p^.lch,q,po) else ins(p^.rch,q,po);
end;

Function find(p:node;q:longint):node;
  begin
  if p=nil then exit(nil);
  if p^.d=q then exit(p);
  if q<=p^.d then exit(find(p^.lch,q)) else
    exit(find(p^.rch,q));
end;

Procedure delete(var p:node);
var
 t,s,q:node;
  begin
  if p^.lch=nil then
    begin
    q:=p;
    p:=p^.rch;
    dispose(q);
  end else
  if p^.rch=nil then
    begin
    q:=p;
    p:=p^.lch;
    dispose(q);
  end else
    begin
    t:=p;
    s:=p^.lch;
    while s^.rch<>nil do
      begin
      t:=s;
      s:=s^.rch;
    end;
    p^.d:=s^.d;
    p^.pos:=s^.pos;
    if t<>p then
      t^.rch:=s^.lch
    else
      t^.lch:=s^.lch;
    dispose(s);
  end;
end;

Procedure delBST(var p:node;q:longint);
  begin
  if p=nil then exit;
  if p^.d=q then delete(p) else
  if q<p^.d then delbst(p^.lch,q) else
  delbst(p^.rch,q);
end;

  begin
  readln(n);
  for i:=1 to n do
    begin
    readln(o);
    ins(h,o,i);
  end;
  delbst(h,5);
  while true do
    begin
    readln(o);
    if find(h,o)=nil then writeln('Not found!') else writeln(find(h,o)^.pos);
  end;
end.