Oracle数据库之PL/SQL程序基础设计

一、PL/SQL块结构

前边我们已经介绍了PL/SQL块的结构，再来回顾一下：

DECLARE
/*
 * 声明部分——定义常量、变量、复杂数据类型、游标、用户自定义异常
 */
BEGIN
/*
 * 执行部分——PL/SQL语句和SQL语句
 */
EXCEPTION
/*
 * 异常处理部分——处理运行异常
 */
END; 
/*块结束标记 */

要实现PL/SQL程序设计，先介绍如下的基本内容：

二、标识符

PL/SQL程序设计中的标识符定义与SQL的标识符定义的要求相同：

标识符名第一个字符必须为字母
标识符名不分大小写
标识符名不能超过30字符
不能用‘-’(减号)
不能是SQL保留字

注意: 一般不要把变量名声明与表中字段名完全一样，如果这样可能得到不正确的结果。

三、变量

1. 变量定义

声明：

variable_name Type;

示例：

my_var NUMBER(4);

赋值：

variable := expression ;

示例：

my_var := 32 * 8 + 79;

-- 声明并赋值
cnt NUMBER(2) := 3;

2. 变量作用域

在PL/SQL编程中，如果在变量的定义上没有做到统一的话，可能会隐藏一些危险的错误，这样的原因主要是变量的作用域所致。变量的作用域是指变量的有效作用范围，与其它高级语言类似，PL/SQL的变量作用范围特点是：

变量的作用范围是在你所引用的程序单元（块、子程序、包）内。即从声明变量开始到该块的结束。
一个变量（标识）只能在你所引用的块内是可见的。
当一个变量超出了作用范围，PL/SQL引擎就释放用来存放该变量的空间（因为它可能不用了）。
在子块中重新定义该变量后，它的作用仅在该子块内。

四、运算符

1. 关系运算符

运算符	说明
=	等于
<> , != , ~= , ^=	不等于
<	小于
>	大于
<=	小于等于
>=	大于等于

2. 逻辑运算符

运算符	说明
AND	逻辑与
OR	逻辑或
NOT	逻辑非，取反

3. 算术运算符

运算符	说明
+	加
-	减
*	乘
/	除

4. 其它运算符

运算符	说明
IS NULL	是空值
BETWEEN AND	介于两者之间
IN	在一列值中间
:=	赋值运算符
=>	关系号
..	范围运算符
\|\|	字符连接符

五、数据类型

前面已经介绍过Oracle中的基本数据类型，除了这些基本数据类型外，Oracle中还有其它的数据类型，我们一一来分析。

1. BOOLEAN

该数据用于定义布尔变量，其变量的值为TRUE、FALSE或NULL。注意此类型只能在PL/SQL中使用，表列是没有此类型的。

2. %TYPE

通常用于指定表的某个列的数据类型，可以理解为“的类型”(小技巧：%读“的”)。

示例：

emp_id employee.id%TYPE;

使用%TYPE特性的优点在于：

所引用的数据库列的数据类型可以不必知道。
所引用的数据库列的数据类型可以实时改变，容易保持一致，也不用修改PL/SQL程序。

3. %ROWTYPE

%ROWTYPE操作符，返回一个记录类型，其数据类型和数据库表的数据结构相一致。

示例：

rec employee%ROWTYPE;

使用%ROWTYPE特性的优点在于：

所引用的数据库中列的个数和数据类型可以不必知道。
所引用的数据库中列的个数和数据类型可以实时改变，容易保持一致，也不用修改PL/SQL程序。

4. 复合数据类型

4.1. 记录（Record）

记录类型类似于C语言中的结构数据类型，它把分离的、逻辑相关的、基本数据类型的变量组成一个整体存储起来，它必须包括至少一个标量型或RECORD数据类型的成员，称作PL/SQL RECORD的域(FIELD)，其作用是存放互不相同但逻辑相关的信息。

语法：

TYPE record_name IS RECORD(
    varable1 data_type1  [NOT NULL]  [:= default_value ],
    varable2 data_type2  [NOT NULL]  [:= default_value ],
    ......,
    varablen data_typen  [NOT NULL]  [:= default_value ] 
);

在使用记录数据类型变量时，需要先在声明部分先定义记录的组成、记录的变量，然后在执行部分引用该记录变量本身或其中的成员。

示例1：

DECLARE
   -- 定义记录类型
   TYPE TEST_REC IS RECORD(
         rec_name VARCHAR2(30) NOT NULL := '匿名',
         info VARCHAR2(100)
   );
   -- 声明记录变量
   rec_emp TEST_REC;
BEGIN
   rec_emp.rec_name :='刘强东';
   rec_emp.info :='谈京东的业务发展';
   DBMS_OUTPUT.PUT_LINE(rec_emp.rec_name||'  ' ||rec_emp.info);
END;

说明：我们可以使用DBMS_OUTPUT.PUT_LINE(outdata)或DBMS_OUTPUT.PUT(outdata)将处理结果输出到屏幕上。

运行结果：

刘强东  谈京东的业务发展

示例2（示例中所用到的表及数据见文末）：

DECLARE
   --定义与employee表中的几个列相同的记录数据类型
   TYPE RECORD_TYPE_EMPLOYEES IS RECORD(
        e_id employee.id%TYPE,
        e_name employee.name%TYPE,
        e_birth employee.birthday%TYPE,
        e_address employee.address%TYPE,
        e_did employee.did%TYPE
   );
   --声明一个该记录数据类型的记录变量
   emp_record RECORD_TYPE_EMPLOYEES;

BEGIN
   SELECT id, name, birthday, address, did INTO emp_record
   FROM employee
   WHERE id = &emp_id;

   DBMS_OUTPUT.PUT_LINE('雇员名称：'||emp_record.e_name
             ||'  出生日期：'||emp_record.e_birth
             ||'  地址：'||emp_record.e_address);
END;

说明：可以用SELECT语句对记录变量进行赋值，只要保证记录字段与查询结果列表中的字段相配即可。&emp_id表示接收用户的输入。

紧跟着&符号后面的变量被称为替换变量。替换变量对数据库引擎是“不可见的”。其实PL/SQL会用用户输入的文本内容来替换变量引用。

如果你想在代码的不同地方引用相同的替换变量，那就需要在第一个替换变量前面放两个&符号，这样才会为你保留这个值以便后续使用。

输入2，输出结果：

雇员名称：刘兰  出生日期：03-9月 -85  地址：四川成都

4.2. 表(TABLE)

4.2.1. 索引表

索引表也称为PL/SQL表，它是Oracle早期版本用于处理PL/SQL数组的数据类型。索引表的元素个数没有限制，并且下标可以为负值。

它与记录类型相似，但它是对记录类型的扩展。它可以处理多行记录，使得可以在PL/SQL中模仿数据库中的表。

注意，索引表只能作为PL/SQL复合数据类型使用，而不能作为表列的数据类型使用。

语法结构：

TYPE table_name IS TABLE OF element_type [NOT NULL]
INDEX BY [BINARY_INTEGER | PLS_INTEGER | VARCHAR2];

关键字INDEX BY表示创建一个主键索引，以便引用记录表变量中的特定行。

表是集合类型，集合类型常用方法有：

方法	说明
EXISTS(n)	如果集合的第n个成员存在，则返回true
COUNT	返回已经分配了存储空间即赋值了的成员数量
FIRST	返回成员的最低下标值
LAST	返回成员的最高下标值
PRIOR(n)	返回下标为n的成员的前一个成员的下标。如果没有则返回NULL
NEXT(N)	返回下标为n的成员的后一个成员的下标。如果没有则返回NULL
TRIM	TRIM：删除末尾一个成员。 TRIM(n) ：删除末尾n个成员
DELETE	DELETE：删除所有成员。 DELETE(n) ：删除第n个成员。DELETE(m, n) ：删除从n到m的成员。
EXTEND	EXTEND：添加一个null成员。 EXTEND(n)：添加n个null成员。 EXTEND(n,i)：添加n个成员，其值与第i个成员相同。
LIMIT	返回在varray类型变量中出现的最高下标值

集合方法调用语法为：

collection_name.method_name[(parameters)]

示例1：

DECLARE
    /* 定义索引表类型 */
    TYPE name_index IS TABLE OF employee.name%type INDEX BY binary_integer;
    TYPE charindex is table of employee.name%type index by varchar2(10);
    /* 声明变量 */
    names name_index;
    names2 charindex;
BEGIN
    names(1) := 'love';
    names(2) := 'lily';
    names2('girl') := 'Lucy';
    names2('boy') := 'Tom';
    dbms_output.put_line(names(1));
    dbms_output.put_line(names(2));
    dbms_output.put_line(names2('girl'));
    dbms_output.put_line(names2('boy'));
END;

输出结果：

love
lily
Lucy
Tom

示例2：

DECLARE
    /* 定义索引表类型 */
    TYPE name_index IS TABLE OF employee.name%type INDEX BY binary_integer;
    TYPE charindex is table of employee.name%type index by varchar2(10);
    /* 声明变量 */
    names name_index;
    names2 charindex;
BEGIN
    SELECT name INTO names(1) FROM employee WHERE id=3;  
    SELECT empname INTO names2('name') FROM employee WHERE id=5;
    dbms_output.put_line(names(1));  
    dbms_output.put_line(names2('name'));
END;

输出结果：

张强
向小梅

示例3：

DECLARE
  TYPE DEPT_TABLE_TYPE IS TABLE OF DEPT%ROWTYPE INDEX BY BINARY_INTEGER;
  dept_table DEPT_TABLE_TYPE;
  cnt number(2) :=4;
BEGIN
  FOR i IN 1 .. cnt LOOP
    SELECT * INTO dept_table(i) FROM DEPT WHERE id=i;
  END LOOP;
  FOR i IN 1 .. cnt LOOP
  DBMS_OUTPUT.PUT_LINE('Department id: '||dept_table(i).id);
  DBMS_OUTPUT.PUT_LINE('Department name: '|| dept_table(i).name);
  END LOOP;
END;

输出结果：

Department id: 1
Department name: 财务部
Department id: 2
Department name: 市场部
Department id: 3
Department name: 综合部
Department id: 4
Department name: 研发部

4.2.2 嵌套表

嵌套表的元素下标从1开始，并且元素个数没有限制。嵌套表数组元素值可以是稀疏的。

注意：索引表类型不能作为表列的数据类型使用，但嵌套表类型可以作为表列的数据类型。

语法结构：

TYPE type_name IS TABLE OF element_type;

示例1：

DECLARE
    TYPE EMP_TABLE_TYPE IS TABLE OF employee.name%TYPE;
    emp_table EMP_TABLE_TYPE;
BEGIN
    emp_table := EMP_TABLE_TYPE(' ',' ',' ');--这里必须使用构造方法初始化嵌套表变量。
    SELECT name INTO emp_table(2) FROM employee
    WHERE id=&emp_id;
    DBMS_OUTPUT.PUT_LINE('姓名：'||emp_table(2));
END;

输入2，输出结果：

姓名：刘兰

在表列中也可以使用嵌套表。

在表列中使用嵌套表类型，必须首先使用CREATE TYPE命令建立嵌套表类型。另外注意，必须要为嵌套表列指定专门的存储表。

示例2：

CREATE TYPE phone_type IS TABLE OF varchar2(20);

CREATE TABLE employee(
    id number(4),
    name varchar2(10),
    sal number(6,2),
    phone phone_type
)nested table phone store as phone_table;

-- 在嵌套表中插入数据 
BEGIN
    INSERT INTO employee VALUES(1, 'TOM', 800, phone_type('028-90909800', '13913001300'));
END;

-- 在嵌套表中检索数据
DECLARE
    phone_table phone_type;
BEGIN
    SELECT phone INTO phone_table FROM employee WHERE id=1;
    FOR i IN 1..phone_table.COUNT LOOP
        dbms_output.put_line('电话号码：'||phone_table(i));
    END LOOP;
END;

-- 在嵌套表中更新数据
DECLARE
    phone_table phone_type:=phone_type('028-10001000', '139800900100');
BEGIN
    UPDATE employee SET phone=phone_table WHERE id=1;
END;

4.3. 数组（VARRAY）

数组是具有相同数据类型的一组成员的集合。每个成员都有一个唯一的下标，它取决于成员在数组中的位置。

语法结构：

TYPE varray_name IS VARRAY(size) OF element_type [NOT NULL];

示例：

DECLARE
   --定义一个最多保存5个VARCHAR(25)数据类型成员的VARRAY数据类型
   TYPE ARRAY_TYPE IS VARRAY(5) OF VARCHAR(25);
   --声明一个该VARRAY数据类型的变量
   my_array ARRAY_TYPE;

BEGIN
   --用构造函数语法赋予初值
   my_array := ARRAY_TYPE
         ('中国', '美国', '英国', '日本', NULL);

   DBMS_OUTPUT.PUT_LINE('地区名称：'||my_array(1)||'、'
                                    ||my_array(2)||'、'
                                    ||my_array(3)||'、'
                                    ||my_array(4));
   DBMS_OUTPUT.PUT_LINE('赋予初值NULL的第5个成员的值：'||my_array(5));
   --也可以这样对成员赋值
   my_array(5) := '法国';
   DBMS_OUTPUT.PUT_LINE('第5个成员的值：'||my_array(5));
END;

输出结果：

地区名称：中国、美国、英国、日本
赋予初值NULL的第5个成员的值：
第5个成员的值：法国

5. 绑定变量

绑定变量是在主机环境中定义的变量。在PL/SQL 程序中可以使用绑定变量作为他们将要使用的其它变量。为了在PL/SQL 环境中声明绑定变量，使用命令VAR或VARIABLE。

当在SQL*Plus中与PL/SQL块之间进行数据交互时，需要使用SQL*Plus绑定变量来完成。

当在PL/SQL中引用非PL/SQL变量时，必须要在非PL/SQL变量前加冒号(“:”)。

示例：

VARIABLE name varchar2(10);
/
BEGIN
    SELECT name INTO :name FROM employee
    WHERE id = 1;
end;
/
print name;

输出结果：

name
---------
李飞

六、常用类型转换函数

CHAR 转换为 NUMBER：

使用 TO_NUMBER 函数来完成字符到数字的转换，如：

v_total := TO_NUMBER('100.0') + 25.5;

NUMBER 转换为CHAR：

使用 TO_CHAR 函数可以实现数字到字符的转换，如：

v_comm := TO_CHAR('12.34') || '元' ;

字符转换为日期：

使用 TO_DATE 函数可以实现字符到日期的转换，如：

v_date := TO_DATE('2015.06.11','yyyy.mm.dd');

日期转换为字符：

使用 TO_CHAR 函数可以实现日期到字符的转换，如：

v_to_day := TO_CHAR(SYSDATE, 'yyyy.mm.dd hh24:mi:ss') ;

七、RETURNNING的使用

示例1：

DECLARE
   row_id ROWID;
   info    VARCHAR2(40);
BEGIN
  INSERT INTO dept VALUES (10, '外交部')
  RETURNING rowid, name||':'||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

数据类型ROWID用于存放数据的行号。

RETURNING子句作用：用于检索INSERT语句中所影响的数据行数，当INSERT语句使用VALUES子句插入数据时，RETURNING 字句还可将列表达式、ROWID和REF值返回到输出变量中。使用RETURNING子句是应注意以下几点限制：

不能与DML语句和远程对象一起使用；
不能检索LONG类型信息；
当通过视图向基表中插入数据时，只能与单基表视图一起使用。

示例2：

DECLARE
   row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  UPDATE dept SET id=20 WHERE name='外交部'
  RETURNING rowid, name||':'||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

RETURNING子句用于检索被修改行的信息。当UPDATE语句修改单行数据时，RETURNING子句可以检索被修改行的ROWID和REF值，以及行中被修改列的列表达式，并可将他们存储到PL/SQL变量或复合变量中；当UPDATE语句修改多行数据时，RETURNING子句可以将被修改行的ROWID和REF值，以及列表达式值返回到复合变量数组中。在UPDATE中使用RETURNING 子句的限制与INSERT语句中对RETURNING子句的限制相同。

示例3：

DECLARE
   row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  DELETE dept WHERE id=20
  RETURNING rowid, name||':'||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE('ROWID:'||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

RETURNING子句用于检索被删除行的信息：当DELETE语句删除单行数据时，RETURNING子句可以检索被删除行的ROWID和REF值，以及被删除列的列表达式，并可将他们存储到PL/SQL变量或复合变量中；当DELETE语句删除多行数据时，RETURNING子句可以将被删除行的ROWID和REF值，以及列表达式值返回到复合变量数组中。在DELETE中使用RETURNING子句的限制与INSERT语句中对RETURNING子句的限制相同。

八、注释

在PL/SQL里，有两种注释：

使用’–-’(双减号)注释，它的作用范围是只能在一行有效。
使用’/* */’注释，这是多行注释，可注释一行，也可注释多行。

示例：

DECLARE
  --定义v_sal变量
  v_sal NUMBER(6，2);
BEGIN
  /*
   给变量赋值，
   然后打印此变量
  */
  v_sal := 1000;
  dbms_output.put_line(v_sal);
END;

各示例中所涉及的表及测试数据

-- 创建表
create table DEPT -- 部门
(
  id   NUMBER(4) not null constraint PK_DEPT_ID primary key,
  name VARCHAR2(20)
);

create table EMPLOYEE -- 员工
(
  id       NUMBER(4) not null constraint PK_EMP_ID primary key,
  name     VARCHAR2(20) not null,
  birthday DATE,
  address  VARCHAR2(100),
  did      NUMBER(4),
  constraint FK_EMP_DEPT foreign key (DID) references DEPT (ID)
);

-- 添加测试数据
INSERT INTO DEPT VALUES(1, '财务部');
INSERT INTO DEPT VALUES(2, '市场部');
INSERT INTO DEPT VALUES(3, '综合部');
INSERT INTO DEPT VALUES(4, '研发部');
INSERT INTO DEPT VALUES(5, '网络部');

INSERT INTO EMPLOYEE VALUES(1, '李飞', TO_DATE('1975.07.03','yyyy.mm.dd'), '四川成都', 1);
INSERT INTO EMPLOYEE VALUES(2, '刘兰', TO_DATE('1985.09.03','yyyy.mm.dd'), '四川成都', 1);
INSERT INTO EMPLOYEE VALUES(3, '张强', TO_DATE('1987.11.22','yyyy.mm.dd'), '广东广州', 2);
INSERT INTO EMPLOYEE VALUES(4, '刘武龙', TO_DATE('1979.07.18','yyyy.mm.dd'), '陕西西安', 2);
INSERT INTO EMPLOYEE VALUES(5, '向小梅', TO_DATE('1982.03.03','yyyy.mm.dd'), '四川成都', 2);
INSERT INTO EMPLOYEE VALUES(6, '周斌', TO_DATE('1985.11.08','yyyy.mm.dd'), '四川成都', 4);
INSERT INTO EMPLOYEE VALUES(7, '王强', TO_DATE('1985.01.25','yyyy.mm.dd'), '四川成都', 4);

posted @ 2015-06-13 07:44 NAYNEHC 阅读(2105) 评论(8) 编辑收藏举报

刷新页面返回顶部

笔记

简简单单过自己的生活

Oracle数据库之PL/SQL程序基础设计

公告