Delphi 根据字符串创建对象

我们可以通过ClassRegistry单元的TClassRegistry类很轻松的根据字符串创建出对象。

下面是该类几个主要函数的说明:

// 获取TClassRegistry自身的单例引用
class function GetClassRegistry: TClassRegistry;
// 注册需要动态创建的类
procedure RegisterClass(ClassName: UnicodeString; ObjectClass: TClass); overload;
// 判断给定的类名是否注册
function HasClass(ClassName: UnicodeString): Boolean;
// 根据类名创建对象实例
function CreateInstance(ClassName: UnicodeString): TObject;

 

当使用工厂模式或者抽象工厂模式创建产品的时候，如果我们要扩展新的具体产品，在创建方法中添加分支结构

需要改动原有的工厂类。如果能够根据字符串实现动态创建那么只要添加新的具体产品单元就可以了。

 

以下是一个用delphi简单实现的Demo:

UnitCar单元代码:

 1unit UnitCar;
 2
 3interface
 4
 5type
 6
 7  TCar = class abstract
 8    function Run: string; virtual; abstract;
 9  end;

  TRedCar = class(TCar)
    function Run: string; override;
  end;

  TBlueCar = class(TCar)
    function Run: string; override;
  end;

  TBlackCar = class(TCar)
    function Run: string; override;
  end;

implementation

uses
  ClassRegistry;

{ TBlackCar }

function TBlackCar.Run: string;
begin
  Result := 'BlackCar Ready to run!'
end;

{ TBlueCar }

function TBlueCar.Run: string;
begin
  Result := 'BlueCar Ready to run!'
end;

{ TRedCar }

function TRedCar.Run: string;
begin
  Result := 'RedCar Ready to run!'
end;

initialization
  TClassRegistry.GetClassRegistry.RegisterClass(TRedCar.ClassName, TRedCar);
  TClassRegistry.GetClassRegistry.RegisterClass(TBlueCar.ClassName, TBlueCar);
  TClassRegistry.GetClassRegistry.RegisterClass(TBlackCar.ClassName, TBlackCar);
end.

 

在这里我们声明了一个抽象的基类TCar和继承自TCar的三个具体的类。

在单元初始化处用RegisterClass方法注册了这三个子类。

 

UnitMain调用处代码:

 1procedure TDemoForm.CreateClick(Sender: TObject);
 2var
 3  ClassRegistry: TClassRegistry;
 4  Car: TCar;
 5begin
 6  ClassRegistry := TClassRegistry.GetClassRegistry;
 7  if ClassRegistry.HasClass(Name.Text) then
 8  begin
 9    Car := ClassRegistry.CreateInstance(Name.Text) as TCar;
    Memo.Lines.Add(Car.Run);
    Car.Free;
  end else
    Memo.Lines.Add(Format('Class %s has not registerd!', [Name.Text]));
end;

 

效果图:

 

如果我们需要扩展个TYellowCar那么我们只要添加个继承自TCar的TYellowCar类并且注册该类就可以了。

Demo下载: CreateObjectByString.rar