函数调用过程栈帧变化详解

函数调用另一个词语表示叫作 过程。一个过程调用包括将数据和控制从代码的一部分传递到另一部分。另外，它还必须在进入时为过程的局部变量分配空间，并在推出时释放这些空间。而数据传递，局部变量的分配和释放通过操纵程序栈来实现。在了解本文章之前，您需要先对程序的进程空间有所了解，即对进程如何使用内存？如果你知道这些，下面的内容将是很easy的事情了。为了您的回顾还是将简单的分布图贴出来，便于您的回顾。

我们先来了解一个概念，栈帧(stack frame)，机器用栈来传递过程参数，存储返回信息，保存寄存器用于以后恢复，以及本地存储。为单个过程(函数调用)分配的那部分栈称为栈帧。栈帧其实是两个指针寄存器，寄存器%ebp为帧指针，而寄存器%esp为栈指针，当程序运行时，栈指针可以移动(大多数的信息的访问都是通过帧指针的)。总之简单一句话，栈帧的主要作用是用来控制和保存一个过程的所有信息的。栈帧结构如下所示：

　　

如果你已经对这个图已经非常了解了，那么就没有必要再看下去了。因为下面的内容都是对这幅图的讲解。

　　假设过程P（调用者）调用过程Q（被调用者），则Q的参数放在P的栈帧中。另外，当P调用Q时，P中的返回地址被压入栈中，形成P的栈帧的末尾（返回地址就是当程序从Q返回时应该继续执行的地方）。Q的栈帧从保存的帧指针的值开始，后面到新的栈指针之间就是该过程的部分了。

　　过程实例讲解：

下面以这个程序为例进行简要说明函数调用的基本过程。

int swap_add(int* xp,int* yp) {
    int x = *xp;
    int y = *yp;
    *xp = y;
    *yp = x;
    return x+y;
}
int caller(){
    int arg1 = 534;
    int arg2 = 1057;
    int sum = swap_add(&arg1,&arg2);
    int diff = arg1 - arg2;
    
    return sum * diff;
}

经过汇编之后caller部分的代码如下：

caller:
    pushl %ebp   //保存%ebp
    movl %esp,%ebp    //设置新的帧指针为旧的栈指针
    subl $24,%esp  //分配24子节的栈空间
    movl $534,-4(%ebp) //设置arg1=534
    movl $1057,-8(%ebp) //设置arg2=1057
    leal -8(%ebp),%eax //计算&arg2
    movl %eax,4(%esp) //将&arg2存入栈中
    leal -4(%ebp),%eax //计算&arg1
    movl %eax,(%esp) //将&arg1存入栈中
    call swap_add //调用swap_add

这段代码先保存了%ebp的一个副本，将新的过程（该函数的ebp）的ebp设置为栈帧的开始位置。然后将栈指针减去24，从而在栈上分配了24字节的空间（你应该思考一下为什么是24字节），然后是初始化两个局部变量，计算两个局部变量的地址并存入栈中，形成了函数swap_add的参数。将这些参数存储到相对于栈指针偏移量为0和+4的地方，留待稍后的swap_add调用访问。然后调用swap_add.

接下的代码是swap_add的函数部分：

swap_add:
	pushl %ebp
	movl %esp,%ebp
	pushl %ebx
	
	movl 8(%ebp),%edx
	movl 12(%ebp),%ecx
	movl (%edx),%ebx
	movl (%ecx),%eax
	movl %eax,(%edx)
	movl %ebx,(%ecx)
	addl %ebx,%eax
	
	popl %ebx
	popl %ebp
	ret
	

代码分为3部分 建立部分：初始化栈帧；主体部分：执行过程的实体计算；结束部分：回复栈帧的状态，以及过程返回。这一部分的代码比较简单，就不在一一介绍，根据以上的3部分，划分的已经很清晰了。(说明一点程序在执行到swap_add的代码之前，也就是在执行call语句已经把返回地址压入栈中)值得注意的是最后一部分的popl %ebx   popl %ebp。它的作用是恢复了之前存储的栈帧指针的值，也就是调用程序的原始栈帧指针。从而程序就可以得到返回(有些细心的人会问那返回值咋么办？呵呵，返回值是存入了%eax中，在接下来的调用程序caller中直接访问该寄存器就可以了)。

下面就是返回之后继续执行的部分代码了：

movl -4(%ebp),%edx
subl -8(%ebp),%edx
imull %edx,%eax
leave
ret

为了计算diff，从栈中取出arg1,和arg2的值，并将寄存器%eax当做swap_add的返回值。

整个过程的栈变化如下所示：

 

推荐一篇对栈帧的讲解不错的文章：http://blog.csdn.net/yxysdcl/article/details/5569351

参考文献：《深入理解计算机系统》