SQL Server时间粒度系列----第5节小时、分钟时间粒度详解

本文目录列表：

1、SQL Server小时时间粒度
2、SQL Server分钟时间粒度

3、总结语

4、参考清单列表

 

SQL Server小时时间粒度

    

    这里说的时间粒度是指带有小时时间部分的日期时间，这个日期时间精确度是小时的。提供将带小时的日期时间和整数相互转换的功能，和以前日、周、旬、季、年那样。

 

    实现带小时的日期时间和整数相互转换的功能函数，T-SQL如下：

IF OBJECT_ID(N'dbo.ufn_Hours', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_Hours;
END
GO
 
--==================================
-- 功能: 获得指定的日期时间基于基准日期的总小时数(一个整数值）
-- 说明: 如果指定的日期时间为NULL或者小于基准日期“1900-01-01”时，则其值默认基准日期
--       结果值为非负整数，从0开始计数。
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SET @intHours = dbo.ufn_Hours('2008-01-14 17:45')  -- 947033
--==================================
CREATE FUNCTION dbo.ufn_Hours 
(
    @dtmDate DATETIME
) RETURNS INT
    --$Encode$--
AS
BEGIN
    SET @dtmDate = dbo.ufn_GetValidDate(@dtmDate);
 
    -- datepart参数也可以为hh
    RETURN DATEDIFF(HOUR, '1900-01-01', @dtmDate)
END
GO
 
IF OBJECT_ID(N'dbo.ufn_Hours2Date', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_Hours2Date;
END
GO
 
--==================================
-- 功能: 获得一个整数值基于基准日期对应的日期时间
-- 说明: 如果指定的整数值为NULL或为负整数时，则其值默认为0；
--       如果指定的整数值大于“9999-12-31 23:00:00”对应的整数值时，则其值默认设置为“9999-12-31 23:00:00”对应的整数值
--       结果值为从基准日期开始计数的日期
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SET @dtmDate = dbo.fn_Hours2Date(947033) -- '2008-01-14 17:00'
--==================================
CREATE FUNCTION dbo.ufn_Hours2Date 
(
    @intHours INT
) RETURNS DATETIME
AS
BEGIN
    SET @intHours = dbo.ufn_GetValidDateNum(@intHours);
 
    DECLARE @intHoursMax AS INT;
    SET @intHoursMax = dbo.ufn_Hours('9999-12-31 23:00:00');
 
    IF @intHours >= @intHoursMax
    BEGIN
        SET @intHours = @intHoursMax;
    END
 
    -- datepart参数也可以为hh
    RETURN DATEADD(hh, @intHours, '1900-01-01')
END
GO

 

    测试以上功能函数的效果，T-SQL如下：

DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2008-01-14 17:00:00';
 
SELECT @dtmDate AS 'The Current DateTime (Precision:Hour)'
    ,dbo.ufn_Hours(@dtmDate) AS 'The Total Of Hours Base-on Basedate "1900-01-01"'
    ,dbo.ufn_Hours2Date(dbo.ufn_Hours(@dtmDate))AS 'Hours Basedatetime Mapping';
GO

 

    执行后的查询结果如下图：

 

SQL Server分钟时间粒度

    

    同小时时间粒度相似，这个粒度是带有分钟时间部分的日期时间，其精确度是分钟的。不过使用datediff(minute, '1900-01-01', @dtmDateTime)时，@dtmDateTime最大只能为“5983-01-24 02:07:00”，也就是datediff(minute, @starddatetime, @enddatetime)的结果值超过int的最大值（2^15 - 1)，该函数就会错的。如下图所示的错误：

    实现带分钟的日期时间和整数相互转换的功能函数，T-SQL代码如下：

 

IF OBJECT_ID(N'dbo.ufn_Minutes', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_Minutes;
END
GO
 
--==================================
-- 功能: 获得指定的日期时间基于基准日期的总小时数(一个整数值）
-- 说明: 如果指定的日期时间为NULL或者小于基准日期“1900-01-01”时，则其值默认基准日期
--       结果值为非负整数，从0开始计数。
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SET @intMinutes = dbo.ufn_Minutes('2008-01-14 17:10:00');
--==================================
CREATE FUNCTION dbo.ufn_Minutes
(
    @dtmDate DATETIME
) RETURNS INT
AS
BEGIN
    SET @dtmDate = dbo.ufn_GetValidDate(@dtmDate);
 
    -- datepart参数也可以是mi或n
    RETURN DATEDIFF(MINUTE, '1900-01-01', @dtmDate)
END
GO
 
IF OBJECT_ID(N'dbo.ufn_Minutes2Date', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_Minutes2Date;
END
GO
 
--==================================
-- 功能: 获得一个整数值基于基准日期对应的日期时间
-- 说明: 如果指定的整数值为NULL或为负整数时，则其值默认为0；
--       如果指定的整数值大于“5983-01-24 02:07:00”对应的整数值时，则其值默认设置为“5983-01-24 02:07:00”对应的整数值
--       结果值为从基准日期开始计数的日期
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SET @dtmDate = dbo.ufn_Minutes2Date(56821990) -- '2008-01-14 17:10:00'
--==================================
CREATE FUNCTION dbo.ufn_Minutes2Date 
(
    @intMinutes INT
) RETURNS DATETIME
AS
BEGIN
    SET @intMinutes = dbo.ufn_GetValidDateNum(@intMinutes);
 
    DECLARE @intMinutesMax AS INT;
    SET @intMinutesMax = dbo.ufn_Minutes('5983-01-24 02:07:00');
 
    IF @intMinutes >= @intMinutesMax
    BEGIN
        SET @intMinutes = @intMinutesMax;
    END
 
    -- datepart参数也可以是mi或n
    RETURN DATEADD(MINUTE, @intMinutes, '1900-01-01')
END
GO

 

 

    测试以上功能函数的效果，T-SQL如下：

DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2008-01-14 17:10:00';
SELECT @dtmDate AS 'The Current DateTime (Precision:Minute)'
    ,dbo.ufn_Minutes(@dtmDate) AS 'The Total Of Minutes Base-on Basedate "1900-01-01"'
    ,dbo.ufn_Minutes2Date(dbo.ufn_Minutes(@dtmDate)) AS 'Minute Basedatetime Mapping'
GO

 

    

    执行后的查询结果如下图：

注意：分钟时间粒度仅仅提供的参考是实现，因为datediff(minute,@dtmStartDate,@dtmEndDate)返回结果值是int数据类型，受int最大值（2^15-1)的限制，建议谨慎使用。

 

总结语

 

    本文我们学习了带时间部分（小时、分钟）的日期时间和整数相互转换的功能函数，也指出了带分钟的转换为整数的限制。

参考清单列表

1、https://msdn.microsoft.com/zh-cn/library/ms186819(v=sql.90).aspx

2、https://msdn.microsoft.com/zh-cn/library/ms189794(v=sql.90).aspx